Change background color in enter-query mode

Question

Hi everyone,
I am trying to Change background color in enter-query mode in forms10g. I am using this
Set_Item_property('org.branch_code', BACKGROUND_COLOR, 'Green' );
Thanks

Answer 1

This is the code that allows to colorise items in enter_query mode, then de-colorize them after execute_query.
Assume that you have created a VA_QUERY visual atribute in your module.
-- Colorise in enter-query mode --
PROCEDURE Start_query IS
  LC$Block      Varchar2(30) := Name_in('system.trigger_block') ;
  LC$item       varchar2(60);
  LC$itemdeb    varchar2(60);
  LN$len        pls_integer ;
BEGIN
  lc$itemdeb := get_block_property(LC$BLOCK, FIRST_ITEM) ;
  lc$item := LC$BLOCK || '.' || lc$itemdeb ;
  while lc$itemdeb is not null Loop
    IF GET_ITEM_PROPERTY(LC$Item , ITEM_TYPE) NOT IN ('BUTTON','RADIO GROUP','DISPLAY ITEM') Then
      IF GET_ITEM_PROPERTY(LC$Item , QUERYABLE ) = 'TRUE' Then
        set_item_property(LC$item, CURRENT_RECORD_ATTRIBUTE, 'VA_QUERY');
      End if ;
    End if ;
    lc$itemdeb := get_item_property( lc$item, NEXT_NAVIGATION_ITEM );
    lc$item := LC$BLOCK || '.' || lc$itemdeb ;
  end loop ;
END;
-- Unclororize after execute_query --
PROCEDURE End_query IS
  LC$Block     Varchar2(30) := Name_in('system.trigger_block') ;
  LC$item     varchar2(60);
  LC$itemdeb     varchar2(60);
  LN$len          pls_integer ;
  LN$Multi  pls_integer ;
BEGIN
  lc$itemdeb := get_block_property(LC$BLOCK, FIRST_ITEM) ;
  lc$item := LC$BLOCK || '.' || lc$itemdeb ;
  LN$Multi := GET_BLOCK_PROPERTY(LC$Block , RECORDS_DISPLAYED ) ;
  while lc$itemdeb is not null Loop
    IF GET_ITEM_PROPERTY(LC$Item , ITEM_TYPE) NOT IN ('BUTTON','RADIO GROUP','DISPLAY ITEM') Then
      IF GET_ITEM_PROPERTY(LC$Item , QUERYABLE ) = 'TRUE' Then
         If LN$Multi > 1 Then
            set_item_property(LC$item, CURRENT_RECORD_ATTRIBUTE, 'VA_CURRENT_RECORD');
         Else
            set_item_property(LC$item, CURRENT_RECORD_ATTRIBUTE, '');
         End if ;
      End if ;
    End if ;
    lc$itemdeb := get_item_property( lc$item, NEXT_NAVIGATION_ITEM );
    lc$item := LC$BLOCK || '.' || lc$itemdeb ;
  end loop ;
END;Francois