Get count of nodes

Question

Hi all - I'm pretty new to manipulating XML.
I have the following test code:
declare -- Data
p_xpath            varchar2(1000) := '/TEST/SUBNODE/COUNTME/EXTRASTUFF';
  w_xmlbuffer        varchar2(4000) :=
  '<TEST>
     <SUBNODE>
        <COUNTME>
           <EXTRASTUFF>value</EXTRASTUFF>
        </COUNTME>
        <COUNTME>
           <EXTRASTUFF>value2</EXTRASTUFF>
        </COUNTME>
    </SUBNODE>
  </TEST>';
  -- XMLDom variables
  w_doc xmldom.domdocument;
  w_parser           xmlParser.Parser;
  w_root_nl          xmldom.domnodelist;
  w_reqd_elem_nl     xmldom.domnodelist;
  w_src_elem_nl      xmldom.domnodelist;
  w_src_val          varchar2(100);
  w_deriv_val        varchar2(100);
  w_elem             xmldom.domelement;
  w_text             xmldom.domtext;
  w_node             xmldom.domnode;
  w_node2            xmldom.domnode;
  w_elem_text        varchar2(100);
  -- Function to check for null or zero-length nodelists
  function CHECK_EMPTY_NODE_LIST(p_nl     xmldom.domnodelist)
    return  boolean
  is
    w_ret   boolean := true;
  begin
    if (not xmldom.isNull(p_nl)) then
      if xmldom.getLength(p_nl) > 0 then
        w_ret := false;
      end if;
    end if;
    return w_ret;
  end CHECK_EMPTY_NODE_LIST;
begin
  -- Prepare the DOM document
  w_parser := xmlParser.newParser;
  xmlParser.parseBuffer(w_parser, w_xmlbuffer);
  w_doc := xmlParser.getDocument(w_parser);
  -- Get all instances of the root element
  w_root_nl := xslprocessor.selectNodes(xmldom.makenode(w_doc), p_xpath);
  if (not CHECK_EMPTY_NODE_LIST(w_root_nl)) then
    for n in 0 .. xmldom.getlength(w_root_nl) -1
    loop
       w_node := xmldom.item(w_root_nl, n);
       w_elem_text := to_char(n) || ':' || xmldom.getnodename(w_node) || ': ' || xmldom.getnodevalue(w_node);
       w_node2 := xmldom.getfirstchild(w_node);
       if not xmldom.isnull(w_node2) then
        if xmldom.getnodetype(w_node2) = xmldom.text_node then
          w_elem_text := w_elem_text || ' ' || xmldom.getnodevalue(w_node2);
        end if;
      end if;
      dbms_output.put_line(w_elem_text);
    end loop;
  end if;
  dbms_output.put_line('*** END ***');
end;this returns:
0:EXTRASTUFF:  value
1:EXTRASTUFF:  value2
*** END ***now I want to change the XPATH to return the count of the COUNTME nodes.
I have tried numerous combinations. this seems to parse:
p_xpath            varchar2(1000) := '/TEST/SUBNODE[count(COUNTME)]'; but it displays nothing.
what do I need to do to get the count appearing? preferably I'd like to only change the xpath.
any thoughts?

Answer 1

Your xpath is: give me the Nth SUBNODE element where N = # of COUNTME elements.
If you want the count of COUNTME elements why not
p_xpath            varchar2(1000) := '/TEST/SUBNODE/COUNTME';
  -- Get all instances of the root element
  w_root_nl := xslprocessor.selectNodes(xmldom.makenode(w_doc), p_xpath);
  dbms_output.put_line(p_xpath || ' count: ' || xmldom.getlength(w_root_nl));