Help please! Another Finder Error

Question

Hi,
The script below is designed to backup files from the source area to the backup area preserving the folder hierarchy. While I’m sure it could be written better, it seems to work until it encounters a particular folder containing a file, when I get the following Finder error shown below. At this point it has already done approximately 60 files in about 10 folders. If I remove the file from the folder the script will continue processing a further 300 files and sub-folders before getting the same error on another folder/file.
Can someone explain what the error means? Any comments or suggestions to improve the script would be welcome.
tell application "Finder"
get every item of folder (alias "Macintosh HD:Users:andy:Documents:NetXxx II:Customers:Lxxxx Bxxxxxh Cxxxxxl:")
{alias "Macintosh HD:Users:andy:Documents:NetXxx II:Customers:Lxxxx Bxxxxxh Cxxxxxl:Pen Testing Brief 2005.doc"}
"Can't make alias \"Macintosh HD:Users:andy:Documents:NetXxx II:Customers:Lxxxx Bxxxxxh Cxxxxxl::Pen Testing Brief 2005.doc\" into type «class alst»."
-- Backup Script.
-- This script will attempt to backup the specified folder(s) and all sub-folders to the external disk
-- drive. It duplicates the folder sub-folder hierarchy in the backup area.
-- If a previous backup of the file exists in the backup directory it is renamed to
-- 'filename-yy-mm-dd (hhmmss).extension' where yy-mm-dd and hhmmss are taken from
-- the modification date of the file in the backup directory.
on run
-- Get the path to the desktop for the log file.
set desktopPath to (path to desktop from user domain) as string
-- Get the current date and time formatted.
set thisDateAndTime to get current date
tell me
formatDateAndTime(thisDateAndTime)
set thatDateAndTime to result
end tell
-- Compile the name for the log file.
set backupLogPath to desktopPath & "Backup Log" & thatDateAndTime & ".txt"
-- Create and open the log file.
try
set backupLogFile to (open for access file backupLogPath with write permission)
end try
set backupLog to backupLogFile
-- Write a starting message to the log file.
set logMsg to "Backup Starting..." as string
append2BackupLog(logMsg)
-- Define the global variables.
global backupLog -- The file specification of the backup log file.
global backupPath -- Top level folder for the backup.
global topSourceFolder -- The top level source folder name without the proceeding path.
global sourceFileName -- Source file name but not the path.
global sourceFileExtension -- Get the file extension.
-- Define the backup folder to receive the backups.
set backupPath to "ANDY:Business:Backups:" as text
-- Define the folder to be backed up (the source folder).
set sourceFolder to (path to home folder from user domain) as text
set sourceFolder to (sourceFolder & "Documents:NetXxx II:")
set topSourceFolder to "NetXxx II" as text
-- Process the folder.
processAFolder(sourceFolder)
-- All done so write a final entry, close the log file and return.
set logMsg to "Backup Ending..."
append2BackupLog(logMsg)
close access backupLogFile
end run
-- This routine process each file in the specified folder.
on processAFolder(theFolder)
-- Declare the global variables we reference.
global sourceFileName -- Source file name but not the path.
global sourceFileExtension -- Get the file extension.
-- Write a message to the log file that we are processing the folder.
set logMsg to "Processing folder " & theFolder
append2BackupLog(logMsg)
tell application "Finder"
-- Get a list of everything in the specified folder.
set allItems to every item of folder theFolder as alias list
repeat with eachItem in allItems
-- Check if this is a folder file.
set fileInfo to info for eachItem
set thisClass to kind of fileInfo as text
if thisClass is equal to "Folder" then
-- We have a another folder so do a recursive call.
tell me
processAFolder(eachItem)
end tell
else
-- Store the file information we will need in processAFile() in the global variables.
set fileName to eachItem as text
set sourceFileName to name of fileInfo as text -- Get the file name but not the path.
set sourceFileExtension to name extension of fileInfo as text -- Get the file extension.
-- Now process the file.
tell me
processAFile(fileName)
end tell
end if
end repeat
end tell
end processAFolder
-- This routine processes the specified file.
on processAFile(fileName)
-- Define the global variables referenced in this script.
global topSourceFolder -- The top folder to be backed up.
global backupPath -- The top folder in the backup area.
global sourceFileName -- Source file name but not the path.
global sourceFileExtension -- Get the file extension.
-- Get the folder paths from topSourceFolder downwards to the current folder.
set currentBackupFolderPath to ""
set folderTree to ""
set addFolder to false
set savedTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to {":"}
tell application "Finder"
repeat with iFolder in text items of fileName
set thisFolder to iFolder as text
if (thisFolder is equal to topSourceFolder) then
set addFolder to true -- We are now at the top of the tree so start adding the folder names to the folder tree.
end if
if thisFolder is equal to sourceFileName then
set addFolder to false -- As its the current file name we don't want it in the folder tree.
end if
if addFolder is true then
-- While were at it check that the folder exists in the backup area.
set backupFolder to backupPath & folderTree & thisFolder
set backupFolderExists to (folder backupFolder exists)
if backupFolderExists is equal to false then
-- It does not exist so create the folder in the backup area.
set backupFolderPath to backupPath & folderTree as file specification
make new folder at folder backupFolderPath with properties {name:thisFolder}
end if
-- Add the folder to the folder tree.
set folderTree to folderTree & thisFolder & ":"
end if
end repeat
set AppleScript's text item delimiters to savedTID
-- Set the backup folder path.
set backupFolder to (backupPath & folderTree)
-- check if the files exist
set sourceFileExists to (file fileName exists)
set backupFileExists to (file sourceFileName of folder backupFolder exists)
-- Backup the file to the required backup folder.
if sourceFileExists and not backupFileExists then
-- File did not exist in the backup directory so copy it there.
duplicate file fileName to folder backupFolder
-- Write a log file entry for the file.
set logMsg to "Backup of " & fileName
tell me
append2BackupLog(logMsg)
end tell
else
-- Both files exist, so check if the file in the source folder is newer.
if (modification date of file fileName) > (modification date of file sourceFileName of folder backupFolder) then
-- We need to rename the old backup file before we make a backup copy of the newer file.
set thisDateAndTime to modification date of file sourceFileName of folder backupFolder
-- Get the current date and time formatted.
tell me
formatDateAndTime(thisDateAndTime)
set thatDateAndTime to result
end tell
-- We need to get the file name minus the extension.
set oldTID to AppleScript's text item delimiters -- Get the current text item delimiters (TIDs).
set AppleScript's text item delimiters to {"."} -- Set them to ".".
set justFileName to first text item of sourceFileName -- Get the filename before the "."
set AppleScript's text item delimiters to oldTID -- Restore the TIDs to what they were.
-- Build the new file name for the old backup file.
set newFileName to justFileName & thatDateAndTime & "." & sourceFileExtension
-- Rename the file in the backup area and take a copy of the newer file.
set name of file (sourceFileName as text) of folder backupFolder to newFileName
duplicate file fileName to folder backupFolder
-- Write the log file entry's for the file rename and the file backup.
tell me
set logMsg to "Renamed old backup file to " & newFileName
append2BackupLog(logMsg)
set logMsg to "Backup of " & fileName
append2BackupLog(logMsg)
end tell
end if
end if
end tell
end processAFile
-- Format the specified date & time into a string of the form "dd-mm-yy (hhmmss)".
on formatDateAndTime(thisDateAndTime)
set dateString to short date string of thisDateAndTime
set timeString to time string of thisDateAndTime
set fileDateString to "" as text
repeat with iWord in words of dateString
set fileDateString to fileDateString & "-"
if length of iWord is 2 then
set fileDateString to fileDateString & iWord as text
end if
if length of iWord is 1 then
-- Pad single digits out with a leading zero.
set fileDateString to fileDateString & "0" & iWord as text
end if
end repeat
-- Format the time into "(hhmmss)".
set fileTimeString to " (" as text
repeat with iTime in words of timeString
set fileTimeString to fileTimeString & iTime as text
end repeat
set fileTimeString to fileTimeString & ")" as text
-- Set the return parameter to the result and return.
set thatDateAndTime to fileDateString & fileTimeString
end formatDateAndTime
-- This routine writes the specified message to the end of the log file.
-- NOTE - the log file is assumed to be already open with write access.
on append2BackupLog(logMsg)
global backupLog -- Global variable that defines the path to the log file.
-- Get the current date and time formatted.
set dateString to short date string of (get current date) & space & time string of (get current date)
try
write (dateString & " " & logMsg & return as text) to backupLog starting at eof
end try
end append2BackupLog
15" MacBook Pro 2.16GHz, 2GB Ram   Mac OS X (10.4.8)  

Answer 1

Hello
I was forced to stop my running script so I was able to look at your script/
Here is a modified version. I didn't check it.
-- Backup Script.
-- This script will attempt to backup the specified folder(s) and all sub-folders to the external disk
-- drive. It duplicates the folder sub-folder hierarchy in the backup area.
-- If a previous backup of the file exists in the backup directory it is renamed to
-- 'filename-yy-mm-dd (hhmmss).extension' where yy-mm-dd and hhmmss are taken from
-- the modification date of the file in the backup directory.
on run
-- Get the path to the desktop for the log file.
set desktopPath to (path to desktop from user domain) as string
-- Get the current date and time formatted.
set thisDateAndTime to get current date
set thatDateAndTime to my formatDateAndTime(thisDateAndTime)
-- Create and open the log file.
try
set backupLogFile to (open for access file (desktopPath & "Backup Log" & thatDateAndTime & ".txt") with write permission)
on error
display dialog "something failed !"
end try
set backupLog to backupLogFile
-- Write a starting message to the log file.
my append2BackupLog("Backup Starting..." as string)
-- Define the global variables.
global backupLog -- The file specification of the backup log file. -- Is it correct to define backupLog as global AFTER setting its value ???
global backupPath -- Top level folder for the backup.
global topSourceFolder -- The top level source folder name without the proceeding path.
global sourceFileName -- Source file name but not the path.
global sourceFileExtension -- Get the file extension.
-- Define the backup folder to receive the backups.
set backupPath to "ANDY:Business:Backups:" as text
-- Define the folder to be backed up (the source folder).
set topSourceFolder to "NetXxx II" as text
-- Process the folder.
my processAFolder(((path to home folder from user domain) as text) & "Documents:" & topSourceFolder & ":")
-- All done so write a final entry, close the log file and return.
my append2BackupLog("Backup Ending...")
close access backupLogFile
end run
-- This routine process each file in the specified folder.
on processAFolder(theFolder)
-- Declare the global variables we reference.
global sourceFileName -- Source file name but not the path.
global sourceFileExtension -- Get the file extension.
-- Write a message to the log file that we are processing the folder.
my append2BackupLog("Processing folder " & theFolder)
tell application "Finder"
-- Get a list of everything in the specified folder.
set allItems to every item of folder theFolder as alias list
repeat with eachItem in allItems
-- Check if this is a folder file.
if (class of item eachItem) is folder then
-- We have a another folder so do a recursive call.
my processAFolder(eachItem as text)
else
-- Store the file information we will need in processAFile() in the global variables.
set eachItem to eachItem as alias
set sourceFileName to name of eachItem -- Get the file name but not the path.
set sourceFileExtension to name extension of eachItem -- Get the file extension.
-- Now process the file.
my processAFile(eachItem as text)
end if
end repeat
end tell
end processAFolder
-- This routine processes the specified file.
on processAFile(fileName)
-- Define the global variables referenced in this script.
global topSourceFolder -- The top folder to be backed up.
global backupPath -- The top folder in the backup area.
global sourceFileName -- Source file name but not the path.
global sourceFileExtension -- Get the file extension.
-- Get the folder paths from topSourceFolder downwards to the current folder.
set currentBackupFolderPath to ""
set folderTree to ""
set addFolder to false
set savedTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to {":"}
tell application "Finder"
repeat with iFolder in text items of fileName
set thisFolder to iFolder as text
if (thisFolder is equal to topSourceFolder) then set addFolder to true -- We are now at the top of the tree so start adding the folder names to the folder tree.
if thisFolder is equal to sourceFileName then set addFolder to false -- As its the current file name we don't want it in the folder tree.
if addFolder is true then
-- While were at it check that the folder exists in the backup area.
set backupFolder to backupPath & folderTree & thisFolder
set backupFolderExists to (folder backupFolder exists)
if backupFolderExists is equal to false then
-- It does not exist so create the folder in the backup area.
set backupFolderPath to backupPath & folderTree as file specification
make new folder at folder backupFolderPath with properties {name:thisFolder}
end if
-- Add the folder to the folder tree.
set folderTree to folderTree & thisFolder & ":"
end if
end repeat
set AppleScript's text item delimiters to savedTID
-- Set the backup folder path.
set backupFolder to (backupPath & folderTree)
-- check if the files exist
set sourceFileExists to (file fileName exists)
set backupFileExists to (file sourceFileName of folder backupFolder exists)
-- Backup the file to the required backup folder.
if sourceFileExists and not backupFileExists then
-- File did not exist in the backup directory so copy it there.
duplicate file fileName to folder backupFolder
-- Write a log file entry for the file.
my append2BackupLog("Backup of " & fileName)
else
-- Both files exist, so check if the file in the source folder is newer.
if (modification date of file fileName) > (modification date of file sourceFileName of folder backupFolder) then
-- We need to rename the old backup file before we make a backup copy of the newer file.
set thisDateAndTime to modification date of file sourceFileName of folder backupFolder
-- Get the current date and time formatted.
set thatDateAndTime to my formatDateAndTime(thisDateAndTime)
-- We need to get the file name minus the extension.
set oldTID to AppleScript's text item delimiters -- Get the current text item delimiters (TIDs).
set AppleScript's text item delimiters to {"."} -- Set them to ".".
set justFileName to first text item of sourceFileName -- Get the filename before the "."
set AppleScript's text item delimiters to oldTID -- Restore the TIDs to what they were.
-- Build the new file name for the old backup file.
set newFileName to justFileName & thatDateAndTime & "." & sourceFileExtension
-- Rename the file in the backup area and take a copy of the newer file.
set name of file (sourceFileName as text) of folder backupFolder to newFileName
duplicate file fileName to folder backupFolder
-- Write the log file entry's for the file rename and the file backup.
my append2BackupLog("Renamed old backup file to " & newFileName)
my append2BackupLog("Backup of " & fileName)
end if
end if
end tell
end processAFile
-- Format the specified date & time into a string of the form "dd-mm-yy (hhmmss)".
on formatDateAndTime(thisDateAndTime)
set dateString to short date string of thisDateAndTime
set timeString to time string of thisDateAndTime
set fileDateString to "" as text
repeat with iWord in words of dateString
set fileDateString to fileDateString & "-" & text -2 thru -1 of ("0" & iWord)
end repeat
-- Format the time into "(hhmmss)".
set fileTimeString to " (" as text
repeat with iTime in words of timeString
set fileTimeString to fileTimeString & iTime as text
end repeat
set fileTimeString to fileTimeString & ")" as text
-- Set the return parameter to the result and return.
return fileDateString & fileTimeString
end formatDateAndTime
-- This routine writes the specified message to the end of the log file.
-- NOTE - the log file is assumed to be already open with write access.
on append2BackupLog(logMsg)
global backupLog -- Global variable that defines the path to the log file.
-- Get the current date and time formatted.
set dateString to short date string of (get current date) & space & time string of (get current date)
try
write (dateString & " " & logMsg & return as text) to backupLog starting at eof
end try
end append2BackupLog
Yvan KOENIG (from FRANCE samedi 3 mars 2007 21:23:33)