How to fire a Alert Message in a table format

Question

Hi friends,
Currently im performing an Alert. My requirement is i need to display the alert message to the user in the mail in a table format.
But i couldnt perform that, as the alert is not displaying in a properly aligned table format.
Can you friends propose me a right way to bring the alert in a table format with two columns.
Thanks in Advance..
Regards,
Saro

Answer 1

I agree w 936671, do this in PL/SQL. Much, much easier.
However, I will recommend a different approach using PL/SQL.
1) Create a package to send the emails. Sample code:
create or replace package cust_fnd_utilities as
procedure send_email(     p_sender     in     varchar2,
               p_recipient      in      varchar2,
               p_subject     in     varchar2,
               p_message     in     varchar2);
end cust_fnd_utilities;
create or replace package body cust_fnd_utilities as
procedure send_email(     p_sender     in     varchar2,
               p_recipient      in      varchar2,
               p_subject     in     varchar2,
               p_message     in     varchar2)
is
v_mail_host     varchar2(30);
v_crlf      constant varchar2(2):= chr(13)||chr(10);
v_message     varchar2(10000);
v_mail_conn     utl_smtp.connection;
begin
v_mail_host := 'localhost';
v_mail_conn := utl_smtp.open_connection(v_mail_host, 25);
v_message :=      'Date: ' ||
     to_char(sysdate, 'dd Mon yy hh24:mi:ss') || v_crlf ||
     'From: <'|| p_sender ||'>' || v_crlf ||
     'Subject: '|| p_subject || v_crlf ||
     'To: '||p_recipient || v_crlf || '' || v_crlf || p_message;
utl_smtp.ehlo(v_mail_conn, v_mail_host);
utl_smtp.mail(v_mail_conn, p_sender);
utl_smtp.rcpt(v_mail_conn, p_recipient);
utl_smtp.data(v_mail_conn, v_message);
utl_smtp.quit(v_mail_conn);
exception
when others then
     utl_smtp.close_connection(v_mail_conn);
end send_email;
end cust_fnd_utilities;
2) Build the email, then call the package from step #1. Sample code:
create or replace package cust_fnd_monitoring as
procedure profile_options_build_email (     p_errbuf     out     varchar2,
                         p_retcode     out     varchar2,
                         p_sender     in     varchar2,
                         p_recipient     in     varchar2);                         
end cust_fnd_monitoring;
create or replace package body cust_fnd_monitoring as
procedure profile_options_build_email (     p_errbuf     out     varchar2,
                         p_retcode     out     varchar2,
                         p_sender     in     varchar2,
                         p_recipient     in     varchar2)
is
v_subject          varchar2(100) := 'erpgamd1 - Recent Profile Option Changes';
v_mime_type          varchar2(100) := 'Content-Type: text/html';
v_body               varchar2(10000);
v_line_feed          varchar2(1):=chr(10);
cursor profile_cur is
select     p.user_profile_option_name,
     u.user_name,
     u.description,
     r.responsibility_name,
     v.last_update_date
from     fnd_profile_option_values v,
     fnd_profile_options_vl p,
     fnd_user u,
     fnd_responsibility_vl r
where     p.application_id = v.application_id
and     p.profile_option_id = v.profile_option_id
and     v.last_updated_by = u.user_id
and     v.level_id = 10003
and     v.level_value = r.responsibility_id
and      v.level_value_application_id = r.application_id
and     r.creation_date <= '01-NOV-2010'
and     v.last_update_date >= sysdate-7
and     u.user_name != '204020779'
union all
select     p.user_profile_option_name,
     u.user_name,
     u.description,
     'Site' responsibility_name,
     v.last_update_date
from     fnd_profile_option_values v,
     fnd_profile_options_vl p,
     fnd_user u
where     p.application_id = v.application_id
and     p.profile_option_id = v.profile_option_id
and     v.last_updated_by = u.user_id
and     v.level_id = 10001
and     v.last_update_date >= sysdate-7
and     u.user_name != '204020779'
order by 5 desc,4;
profile_rec     profile_cur%rowtype;
begin
open profile_cur;
<<profile_loop>>
loop
     fetch profile_cur into profile_rec;
     exit when profile_cur%notfound;
     if profile_cur%rowcount = 1 then
     -- We need to confirm that we fetch at least one row. Once we have confirmed, we want to generate
     -- the email body heading only during the first pass through the loop.
          v_body := '<html>' || v_line_feed;
          v_body := v_body || '<body style="font-family:arial;font-size:10pt">' || v_line_feed || v_line_feed;
          v_body := v_body || '<table cellspacing="5">' || v_line_feed;
          -- table heading
          v_body := v_body || '<tr>' || v_line_feed;
          v_body := v_body || '<td align="left"><u>profile option name</u></td>' || v_line_feed;
          v_body := v_body || '<td align="left"><u>responsibility name</u></td>' || v_line_feed;
          v_body := v_body || '<td align="left"><u>last update date</u></td>' || v_line_feed;
          v_body := v_body || '<td align="left"><u>SSO #</u></td>' || v_line_feed;
          v_body := v_body || '<td align="left"><u>user name</u></td>' || v_line_feed;
          v_body := v_body || '</tr>' || v_line_feed;
     end if;
     -- table detail
     v_body := v_body || '<tr>' || v_line_feed;
     v_body := v_body || '<td>' || profile_rec.user_profile_option_name      || '</td>' || v_line_feed;
     v_body := v_body || '<td>' || profile_rec.responsibility_name          || '</td>' || v_line_feed;
     v_body := v_body || '<td>' || profile_rec.last_update_date          || '</td>' || v_line_feed;
     v_body := v_body || '<td>' || profile_rec.user_name                || '</td>' || v_line_feed;
     v_body := v_body || '<td>' || profile_rec.description               || '</td>' || v_line_feed;
     v_body := v_body || '</tr>'|| v_line_feed;
end loop profile_loop;
if profile_cur%rowcount =0 then
     -- The cursor fetched no rows.
     -- send email using utl_smtp
     cust_fnd_utilities.send_email(p_sender,p_recipient,v_subject || '. No exceptions found.','No exceptions found.');
else
     -- Generate the end of the email body if we fetched at least one row.
     v_body := v_body || '<table>' || v_line_feed || v_line_feed;
     v_body := v_body || v_line_feed || '</body>' || v_line_feed;
     v_body := v_body || '</html>' || v_line_feed;
     -- send email using utl_smtp
     cust_fnd_utilities.send_email(p_sender,p_recipient,v_subject || v_line_feed || v_mime_type,v_body);
end if;
close profile_cur;
end profile_options_build_email;
end cust_fnd_monitoring;
3) In your alert, do not use an email action. Rather, your action should be a SQL*Plus script that calls the package from step #2.