Urgent clearing data in container for free text

Question

I HAVE A CONTAINER FOR FREE TEXT.
I HAVE A CREATE BUTTON IN MY SCREEN EWHEN I PRESS CREATE IT ASKD FOR ID AND FREE TEXT THEN I SAVE  AND IT GETS SAVED IN A ZTALE TABLE.
WHEN AFTER SAVING IT I GO TO INITIAL SCREEN AND PRESS CREATE AGAIN THEN IT ASKS FOR ID AND IN THE CONTAINER I SEE THE FPREVIOUS TEXT.
CAN YOU GUYS LET ME KNOW AS TO WHAT I NEED TO DO.
I TREID CLEARING AND REFRESHING MYTABLE WHICH I HAVE USED IN THE FOLLOWING CODE.
pbo
if editor is initial.
CREATE OBJECT TEXTEDIT_CUSTOM_CONTAINER
EXPORTING
CONTAINER_NAME = 'TEXTEDITOR1'
EXCEPTIONS
CNTL_ERROR = 1
CNTL_SYSTEM_ERROR = 2
CREATE_ERROR = 3
LIFETIME_ERROR = 4
LIFETIME_DYNPRO_DYNPRO_LINK = 5.
IF SY-SUBRC NE 0.
add your handling
ENDIF.
CREATE OBJECT EDITOR
EXPORTING
PARENT = TEXTEDIT_CUSTOM_CONTAINER
WORDWRAP_MODE = CL_GUI_TEXTEDIT=>WORDWRAP_AT_FIXED_POSITION
WORDWRAP_TO_LINEBREAK_MODE = CL_GUI_TEXTEDIT=>FALSE
EXCEPTIONS
OTHERS = 1.
refresh mytable.
call METHOD editor->SET_TOOLBAR_MODE
EXPORTING TOOLBAR_MODE = 0.
*call METHOD editor->SET_ENABLE
*EXPORTING ENABLE = ' '.
CALL METHOD editor->set_readonly_mode
EXPORTING
readonly_mode = 1.
ENDIF.
CLEAR MYTABLE.
FREE MYTABLE.
endif.
IF SY-SUBRC NE 0.
CALL FUNCTION 'POPUP_TO_INFORM'
EXPORTING
TITEL = V_REPID "--> program name
TXT2 = SPACE
TXT1 = 'Error in flush'.
ENDIF.
tHANKS
let me know
swathi

Answer 1

For example, this program works really well with saving long text using the SAVE_TEXT function.  Here you need to create the object/id in SE75.  For this program you enter the id on the right like 999999 and enter the text on the left, execute and the text is saved, now change the id to 999998 and hit enter, notice the text is blank, now enter 999999 again, notice the text for this id has come back,  this is because the program uses READ_TEXT to retrieve the text.
report zrich_0001.
data:
      dockingleft  type ref to cl_gui_docking_container,
      text_editor    type ref to cl_gui_textedit,
      repid type syrepid.
data: begin of header.
        include structure thead.
data: end of header.
data: begin of lines occurs 0.
        include structure tline.
data: end of lines.
data: textlines type table of tline-tdline,
      wa_text type tline-tdline.
data: xthead type thead.
parameters: p_id(10) type c.
at selection-screen.
  if p_id is initial.
    message e001(00) with 'Enter an ID'.
  endif.
at selection-screen output.
  repid = sy-repid.
  if dockingleft is initial.
    create object dockingleft
                exporting repid     = repid
                          dynnr     = sy-dynnr
                          side      = dockingleft->dock_at_left
                          extension = 300.
    create object text_editor
                exporting
                     parent     = dockingleft.
  endif.
  if p_id <> space.
    xthead-tdobject = 'ZPT_DET'.
    xthead-tdid     = 'Z001'.
    xthead-tdname = p_id.
    clear lines. refresh lines.
    call function 'READ_TEXT'
      exporting
        id                            = xthead-tdid
        language                      = sy-langu
        name                          = xthead-tdname
        object                        = xthead-tdobject
      tables
        lines                         = lines
     exceptions
       id                            = 1
       language                      = 2
       name                          = 3
       not_found                     = 4
       object                        = 5
       reference_check               = 6
       wrong_access_to_archive       = 7
       others                        = 8.
    clear textlines.
    loop at lines.
      wa_text = lines-tdline.
      append wa_text to textlines.
    endloop.
  endif.
  call method text_editor->set_text_as_r3table
     exporting
           table              = textlines
     exceptions
           others             = 1.
start-of-selection.
  call method text_editor->get_text_as_r3table
     importing
           table              = textlines
     exceptions
           others             = 1.
* Set SAPscript Header
  clear header.
  header-tdname =  p_id .         "Name
  header-tdobject = 'ZPT_DET'.       "Object
  header-tdid = 'Z001'.              "Id
  header-tdspras = sy-langu.
* Move text from container to function module table
  clear  lines.  refresh lines.
  loop at textlines into wa_text .
    lines-tdline = wa_text.
    append lines .
  endloop.
  call function 'SAVE_TEXT'
       exporting
            client   = sy-mandt
            header   = header
       tables
            lines    = lines
       exceptions
            id       = 1
            language = 2
            name     = 3
            object   = 4
            others   = 5.
Yes, this is implemented using a selection screen, but the same principals apply and this can  be easily converted to a dynpro application.
Regards,
Rich Heilman