Add-on development start

Question

Hi,
For developing one add-on,
1. Create user tables
2. Create fields for them
3. Create UDO
then how to proceed stepwise?

Answer 1

Actually I am trying to build the Blanket solution given in SDK help by my own. I have created the form. and writing code as described. But i am getting errors. Please help. I am pasting the code for Blanket.vb class
Public Class Blanket
    Private WithEvents SBO_Application As SAPbouiCOM.Application ' UI application
    Private oCompany As SAPbobsCOM.Company      ' DI application
    'Declaring an Event Filters container and an Event Filter object
    Public oFilters As SAPbouiCOM.EventFilters
    Public oFilter As SAPbouiCOM.EventFilter
    Private oMatrix As SAPbouiCOM.Matrix        ' Global variable to handle matrixes
    ' Variables for Blanket Agreement UI form
    Private cmbBPCode As SAPbouiCOM.ComboBox    ' Global variable for the BP Code
    Private txtBPName As SAPbouiCOM.EditText    ' Global variable for the BP Code
    Private colItemCode As SAPbouiCOM.Column    ' Global variable for the Item Code
    Private colItemName As SAPbouiCOM.Column    ' Global variable for the Item Name
    Private colItemPrice As SAPbouiCOM.Column   ' Global variable for the Item Price
    Private colItemQuan As SAPbouiCOM.Column    ' Global variable for the Item Quantity
    Private colInitQuan As SAPbouiCOM.Column    ' Global variable for the Item Initial Quantity
    Private colItemTotal As SAPbouiCOM.Column   ' Global variable for the Item Total
    Private oDocTotal As SAPbouiCOM.EditText    ' Global variable for the Blanket Total
    Private AddStarted As Boolean                ' Flag that indicates "Add" process started
    Private RedFlag As Boolean                   ' RedFlag when true indicates an error during "Add" process
    Private InvOk As Boolean                     ' Indicates that an invoice can be withdrawn from blanket agreement
    Private RowNum As Integer                    ' Row Number in a matrix
    Private ItemCodes() As String                ' Array to render Item Codes
    Private ItemQuantities() As Double           ' Array to render Item Quantities
    Private oEditBPCode As SAPbouiCOM.EditText   ' Global variable for the BP code edit text
    Private oEditPostDate As SAPbouiCOM.EditText ' Global variable for the Post Date edit text
    Private strEditBPCode As String              ' Global variable for the BP code edit text string value
    Private strEditPostDate As String            ' Global variable for the Post Date edit text string value
    Private IsNewItem As Boolean                 ' Indicates if you added a new item to invoice/quotation/order
#Region "Single Sign On"
    Private Sub SetApplication()
        AddStarted = False
        RedFlag = False
        '// Use an SboGuiApi object to establish connection
        '// with the SAP Business One application and return an
        '// initialized application object
        Dim SboGuiApi As SAPbouiCOM.SboGuiApi
        Dim sConnectionString As String
        SboGuiApi = New SAPbouiCOM.SboGuiApi
        '// by following the steps specified above, the following
        '// statement should be sufficient for either development or run mode
        sConnectionString = Environment.GetCommandLineArgs.GetValue(1)
        '// connect to a running SBO Application
        SboGuiApi.Connect(sConnectionString)
        '// get an initialized application object
        SBO_Application = SboGuiApi.GetApplication()
    End Sub
    Private Function SetConnectionContext() As Integer
        Dim sCookie As String
        Dim sConnectionContext As String
        Dim lRetCode As Integer
        Try
            '// First initialize the Company object
            oCompany = New SAPbobsCOM.Company
            '// Acquire the connection context cookie from the DI API.
            sCookie = oCompany.GetContextCookie
            '// Retrieve the connection context string from the UI API using the
            '// acquired cookie.
            sConnectionContext = SBO_Application.Company.GetConnectionContext(sCookie)
            '// before setting the SBO Login Context make sure the company is not
            '// connected
            If oCompany.Connected = True Then
                oCompany.Disconnect()
            End If
            '// Set the connection context information to the DI API.
            SetConnectionContext = oCompany.SetSboLoginContext(sConnectionContext)
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Function
    Private Function ConnectToCompany() As Integer
        '// Establish the connection to the company database.
        ConnectToCompany = oCompany.Connect
    End Function
    Private Sub Class_Init()
        '// set SBO_Application with an initialized application object
        SetApplication()
        '// Set The Connection Context
        If Not SetConnectionContext() = 0 Then
            SBO_Application.MessageBox("Failed setting a connection to DI API")
            End ' Terminating the Add-On Application
        End If
        '// Connect To The Company Data Base
        If Not ConnectToCompany() = 0 Then
            SBO_Application.MessageBox("Failed connecting to the company's Data Base")
            End ' Terminating the Add-On Application
        End If
        '// send an "hello world" message
        SBO_Application.MessageBox("DI Connected To: " & oCompany.CompanyName & vbNewLine & "Add-on is loaded")
    End Sub
#End Region
    Public Sub New()
        MyBase.New()
        Class_Init()
        AddMenuItems()
        SetFilters()
    End Sub
    Private Sub DrawForm()
        Dim oForm As SAPbouiCOM.Form               ' The new form
        Dim oItem As SAPbouiCOM.Item               ' An item on the new form
        Dim oCombo As SAPbouiCOM.ComboBox          ' Combo box item for the BP code and Item code
        Dim oColumns As SAPbouiCOM.Columns         ' The Columns collection on the matrix
        Try
            LoadFromXML("blanket.srf")
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
        oForm = SBO_Application.Forms.Item("FBLK")
        ' Add Edit Items
        ' BP Code
        oItem = oForm.Items.Item("txtCode")
        cmbBPCode = oItem.Specific
        AddBPCodeCombo(cmbBPCode)
        ' BP Name
        oItem = oForm.Items.Item("txtName")
        txtBPName = oItem.Specific
        ' Doc Total
        oItem = oForm.Items.Item("txtTotal")
        oDocTotal = oItem.Specific
        ' Add a matrix
        oItem = oForm.Items.Item("mat")
        oMatrix = oItem.Specific
        oColumns = oMatrix.Columns
        ' Item Code
        colItemCode = oColumns.Item("ItemCode")
        colItemName = oColumns.Item("ItemName")
        colItemPrice = oColumns.Item("ItemPrice")
        colItemQuan = oColumns.Item("ItemQuan")
        colInitQuan = oColumns.Item("InitQuan")
        colItemTotal = oColumns.Item("ItemTotal")
        'Add Valid Values
        AddItemsToCombo(colItemCode)
        oMatrix.AddRow()
    End Sub
    Private Sub AddItemsToCombo(ByVal oColumn As SAPbouiCOM.Column)
        Dim RS As SAPbobsCOM.Recordset
        Dim Bob As SAPbobsCOM.SBObob
        RS = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.BoRecordset)
        Bob = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.BoBridge)
        RS = Bob.GetItemList
        RS.MoveFirst()
        While RS.EoF = False
            oColumn.ValidValues.Add(RS.Fields.Item("ItemCode").Value, RS.Fields.Item("ItemName").Value)
            RS.MoveNext()
        End While
    End Sub
    Private Sub AddBPCodeCombo(ByVal oCombo As SAPbouiCOM.ComboBox)
        Dim RS As SAPbobsCOM.Recordset
        Dim Bob As SAPbobsCOM.SBObob
        RS = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.BoRecordset)
        RS.DoQuery("SELECT CardCode,CardName FROM OCRD WHERE CardType='C' ORDER BY CardCode")
        RS.MoveFirst()
        While RS.EoF = False
            oCombo.ValidValues.Add(RS.Fields.Item("CardCode").Value, RS.Fields.Item("CardName").Value)
            RS.MoveNext()
        End While
    End Sub
    Private Sub AddMenuItems()
        Dim oMenus As SAPbouiCOM.Menus          ' The menus collection
        Dim oMenuItem As SAPbouiCOM.MenuItem    ' The new menu item
        ' Get the menus collection from the application
        oMenus = SBO_Application.Menus
        Dim oCreationPackage As SAPbouiCOM.MenuCreationParams
        oCreationPackage = SBO_Application.CreateObject(SAPbouiCOM.BoCreatableObjectType.cot_MenuCreationParams)
        oMenuItem = SBO_Application.Menus.Item("2048") ' Sales menu ID
        oMenus = oMenuItem.SubMenus
        ' New menu parameters
        oCreationPackage.Type = SAPbouiCOM.BoMenuType.mt_STRING
        oCreationPackage.UniqueID = "mnuBlanket"
        oCreationPackage.String = "Blanket Agreement"
        oCreationPackage.Enabled = True
        oCreationPackage.Position = 15
        Try ' If the manu already exists this code will fail
            oMenus.AddEx(oCreationPackage)
        Catch er As Exception ' Menu already exists
            SBO_Application.MessageBox("Menu Already Exists")
        End Try
    End Sub
    Public Function CheckBlanketPrice(ByVal BPCode As String, ByVal ItemCode As String, ByVal PostDate As String, ByVal Quantity As Double) As Double
        CheckBlanketPrice = -1
        'Find if there's a blanket agreement for this BP on this item in this date
        Dim sSQL As String
        sSQL = "SELECT U_ItemCode,DocEntry,U_Price,U_Quan FROM [@SM_BLK1] WHERE U_ItemCode = '" & ItemCode & "'"
        Dim oLineRec As SAPbobsCOM.Recordset
        Dim oDocRec As SAPbobsCOM.Recordset
        Dim DocNum As String
        oLineRec = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.BoRecordset)
        oDocRec = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.BoRecordset)
        Try
            oLineRec.DoQuery(sSQL)
            'SBO_Application.MessageBox("Line: " & sSQL)
        Catch ex As Exception
            MessageBox.Show(sSQL)
            'MessageBox.Show(ex.Message)
        End Try
        If oLineRec.RecordCount > 0 Then
            oLineRec.MoveFirst()
            DocNum = CStr(oLineRec.Fields.Item(1).Value)
            sSQL = "SELECT U_BPCode,DocEntry,U_StartDT,U_EndDT,U_Status FROM [@SM_OBLK] WHERE (DocEntry = " & DocNum & ") AND (U_BPCode = '" & BPCode & "')"
            'SBO_Application.MessageBox(sSQL)
            Try
                oDocRec.DoQuery(sSQL)
                'SBO_Application.MessageBox(oDocRec.RecordCount)
            Catch ex As Exception
                MessageBox.Show(ex.Message)
            End Try
            While ((oDocRec.RecordCount <= 0) And (oLineRec.EoF = False))
                'SBO_Application.MessageBox("In While")
                oLineRec.MoveNext()
                DocNum = CStr(oLineRec.Fields.Item(1).Value)
                sSQL = "SELECT U_BPCode,DocEntry,U_StartDT,U_EndDT,U_Status FROM [@SM_OBLK] WHERE (DocEntry = " & DocNum & ") AND (U_BPCode = '" & BPCode & "')"
                'SBO_Application.MessageBox(sSQL)
                Try
                    oDocRec.DoQuery(sSQL)
                    'SBO_Application.MessageBox(oDocRec.RecordCount)
                Catch ex As Exception
                    MessageBox.Show(ex.Message)
                End Try
                'SBO_Application.MessageBox("out While")
            End While
            If oDocRec.RecordCount > 0 Then
                oDocRec.MoveFirst()
                Dim DStart As Date
                Dim DEnd As Date
                Dim DPost As Date
                Dim SPost As String
                Dim Quan As Double
                Dim Status As String
                DStart = oDocRec.Fields.Item("U_StartDT").Value
                DEnd = oDocRec.Fields.Item("U_EndDT").Value
                Status = oDocRec.Fields.Item("U_Status").Value
                Quan = oLineRec.Fields.Item("U_Quan").Value
                SPost = PostDate.Substring(4, 2) & "/"
                SPost += PostDate.Substring(2, 2) & "/"
                SPost += PostDate.Substring(0, 4)
                DPost = SPost
                'Check that the blanket agreement date is valid
                If Status = "Active" Then
                    If (DStart <= DPost) And (DEnd >= DPost) Then
                        If Quan >= Quantity Then
                            CheckBlanketPrice = oLineRec.Fields.Item(2).Value
                        Else
                            SBO_Application.MessageBox("Item " & ItemCode & " Max quantity can be " & Quan)
                        End If
                    End If
                End If
            End If
        End If
    End Function