ALV GRID DISPLAY and a Parameter entry in the same screen how ?

Question

Hi,
I am newbie to ABAP and I am trying to figure out ways to display an ALV grid along with the parameter field into which the user enters his/ her values in the same screen.To be clear,  when I have a parameter type specified, my screen just lets me display that one field into which the user is asked to enter a value but I want to display the table as well as the user input field in the same screen.
Any help would be appreciated.
Thanks a lot. I appreciate that.
-V

Answer 1

Hi,
I think the easiest way to do that is by means of docking container . I will assume you are using selection-screen, but you can also achieve that with normal screen.
- first you need to place your field in selection screen which I believe you already have
- now during AT SELECTION-SCREEN OUTPUT you check if something is entred to that field
- if so you create instance of docking container (docking it at left hand side) then inside you place you alv with selected data for that field value
So the code which fulfils that would be
PARAMETERS pa_carr TYPE scarr-carrid.
DATA: gr_dock_cont TYPE REF TO cl_gui_docking_container,
      gr_alv       TYPE REF TO cl_gui_alv_grid.
DATA: it_spfli     TYPE TABLE OF spfli.
AT SELECTION-SCREEN OUTPUT.
  IF pa_carr IS NOT INITIAL.
    SELECT * FROM spfli INTO TABLE it_spfli UP TO 10 ROWS
                                            WHERE carrid = pa_carr .
    IF gr_dock_cont IS NOT BOUND.
      CREATE OBJECT gr_dock_cont
        EXPORTING
          side                        = cl_gui_docking_container=>dock_at_left
          extension                   = 500.
      CREATE OBJECT gr_alv
        EXPORTING
          i_parent          = gr_dock_cont.
      CALL METHOD gr_alv->set_table_for_first_display
        EXPORTING
          i_structure_name = 'SPFLI'
        CHANGING
          it_outtab        = it_spfli.
    ELSE.
      CALL METHOD gr_alv->refresh_table_display.
    ENDIF.
  ENDIF.
Regards
Marcin