AppleScript Additions...Huh?

Question

I'm trying to learn AppleScript. I have the script below, that's supposed to generate prime numbers. It comes with an "AppleScript Addition" called "Math Commands".
Is there something I'm supposed to do with the AppleScript addition in order to get the Primes script to run?
Thanks,
Bob
local min, max, neverZero, maxDiv, divTry, res
-- Here you can set any range that suits you
set {min, max} to {1, 100}
set res to {}
-- By some people's opinion, 1 is not considered a prime
if min = 1 then set min to 2
-- 2 is special, so it has to be handled in its own way
if min = 2 then set {res, min} to {{2}, 3}
-- We can't use even numbers, because they are never primes, except for 2
if min mod 2 = 0 then set min to min + 1
repeat until min > max
set maxDiv to («event Måthfloo» («event Måthsqrt» min)) as integer
set {neverZero, divTry} to {true, 3}
repeat until divTry > maxDiv
if min mod divTry = 0 then
set neverZero to false
exit repeat
end if
set divTry to divTry + 2
end repeat
if neverZero then set res to res & min
set min to min + 2
end repeat
{Numberofprimes:length of res, Listofprimes:res}

Answer 1

Hi Bob,
Is it the Math Commands mentioned here?
http://osaxen.com/files/mathcommands1.0.html
If so I think it is written for OS9 and won't work in OSX.
This script doesn't need an OXAN in OSX. Try this:
local min, max, neverZero, maxDiv, divTry, res
-- Here you can set any range that suits you
set {min, max} to {1, 100}
set res to {}
-- By some people's opinion, 1 is not considered a prime
if min = 1 then set min to 2
-- 2 is special, so it has to be handled in its own way
if min = 2 then set {res, min} to {{2}, 3}
-- We can't use even numbers, because they are never primes, except for 2
if min mod 2 = 0 then set min to min + 1
repeat until min > max
set maxDiv to round (min ^ (1 / 2)) rounding down
set {neverZero, divTry} to {true, 3}
repeat until divTry > maxDiv
if min mod divTry = 0 then
set neverZero to false
exit repeat
end if
set divTry to divTry + 2
end repeat
if neverZero then set res to res & min
set min to min + 2
end repeat
{Numberofprimes:length of res, Listofprimes:res}
Best wishes
John M