Applescript and ditto

Question

Hey all at the moment I am using this script to invoke the ditto command
I use this method because I can at least see the progress
but I would like something a bit better
like a display dialog at least that counts the amount of files and starts from 1 to what ever it is or some sort of percentage.
the bottom script does not open terminal and I would like to use the display dialog in the bottom script. is this possible.
I tried using 3rd party progress bars with no luck.
I am not very smart on coding. I only no a bit of applescript and unix.
Have been playing with xcode and interface builder but can never get the progress indicator to actually work for me.
set source to (choose folder with prompt "Select the Source folder")
set destination to (choose folder with prompt "Select the Destination folder")
set source_unix to quoted form of POSIX path of source
set destination_unix to quoted form of POSIX path of destination
tell application "Terminal"
activate
delay 2
do script ("ditto -V -rsrc " & (source_unix) & space & (destination_unix))
end tell
But.......
I rather use
set source to choose folder
set destination to choose folder
set source_unix to quoted form of POSIX path of source
set destination_unix to quoted form of POSIX path of destination
do shell script "ditto -V -rsrc " & source_unix & space & destination_unix
any help on this would be great
like I said I would like a loading bar but a display dialog giving me some indication on time -- percentage -- or file count would be great

Answer 1

the bottom script does not open terminal and I would like to use the display dialog in the bottom script. is this possible.
It can be done, but it takes a bit of extra work.
The issue is that when you invoke do shell script, AppleScript hands control over to the script and does not do anything else until that script returns control back to AppleScript. Therefore there's no way to display your progress dialog - AppleScript doesn't get a look-in until the script completes.
That's largely because in most cases you want your script to react to the results of the shell command and you can't do that if the command hasn't finished.
The exception to this rule is that you can tell the shell command to return control immediately to your script. This will let you run other AppleScript commands while the shell command executes in the background.
You do this by appending " > /dev/null 2>&1 &" to the end of the command. This redirects the output of the command to /dev/null and sends it to the background so that AppleScript can continue.
The trick now is in getting AppleScript to know the shell command's status.
For that the typical solution involves outputting the shell command's result to a temporary file (rather than /dev/null) which you can then read in via AppleScript. What you need now is knowing when the shell command is done which relies on another shell trick (hack?) that tells you the PID of the most recently launched command - you can use that to query if the process is still running.
So your command should end up like:
-- do your shell command:
do shell script "ditto -V -rsrc " & source_unix & space & destination_unix & " > /var/tmp/my.log 2>&1 & echo $!"
  -- 'echo $!' allows you to capture the PID of that process
set thePID to the result
try
  repeat
    -- does the PID exist?
    do shell script "ps -p" & thePID
    -- so show progress
    display dialog (do shell script "tail -1 /var/tmp/my.log") giving up after 2
  end repeat
on error
  -- we're done, so clean up
  do shell script "rm /var/tmp/my.log
end try
The revised do shell script command writes ditto's output to /var/tmp/my.log and returns the PID of that process. The repeat loop then repeatedly checks that PID's status (via ps -p). If the process is running that command succeeds so the script progresses to the 'display dialog' command where it shows you the last line of the log file (you can change this to show anything you like).
If the ps -p command fails because the process is no longer running, that trips the on error clause in the try block which cleans up the temp file.