Using Applescript and Automator to manage files and folders

Question

Hi all.
I need to make a simple action via applescript and-or automator to take the file it's been applied to (via the services) create a folder around it with the same name as the file.
So far, I've searched the web, found some solutions but none are really working.
Here's the script I found :
set myFolder to findFolder()
tell application "Finder" to set myFiles to files of myFolder as alias list
repeat with aFile in myFiles
  set bName to my baseName(aFile)
  tell application "Finder"
  set folderExists to exists folder bName of myFolder
  if not folderExists then make new folder at myFolder with properties {name:bName}
  move aFile to folder bName of myFolder
  end tell
end repeat
---------------- HANDLERS ----------------
on baseName(myFile)
  tell application "System Events" to set {fileName, fileExt} to {name, name extension} of myFile
  return text 1 thru ((get offset of "." & fileExt in fileName) - 1) of fileName
end baseName
on findFolder()
  activate application "SystemUIServer"
  -- Bug pointed out by Lauri Ranta http://www.openradar.me/9406282
  tell application "Finder"
  activate
  set mySelection to (get selection)
  if mySelection ≠ {} then
  set mySelection to first item of (get selection)
  if mySelection's class = folder then
  set currentFolder to mySelection
  else if mySelection's class = document file then
  set currentFolder to parent of mySelection
  else if mySelection's class = alias file then
  set currentFolder to original item of mySelection
  end if
  else
  set currentFolder to target of front Finder window
  end if
  end tell
  return (currentFolder as alias)
end findFolder
And here's a page where they explain how to use automator and the Services to do what I <allmost> want, with some adaptation.
But it still doesn't work.
http://hbase.net/2011/08/17/move-selected-files-into-a-new-folder-using-applescr ipt-and-automator/
So if anybody has an idea n how I could do this ?
It It could either be a folder action (I drag and drop the files into a folder and boom, they get their folder around them)that I would set on a folder on a network drive, or locally, it doesn't matter, or a service (right clic on the file and boom folder around it.
So if anyone could help with this I'd be grateful...

Answer 1

Hi,
Make an Automator Service (Service receives selected "Files or Folders"  in the "Finder.app").
Use this script in the "Run AppleScript" action:
on run {input, parameters}
    tell application "Finder"
        repeat with aFile in input
            if class of (item aFile) is not folder then
                set {tName, fileExt} to {name, name extension} of aFile
                if fileExt is not missing value and fileExt is not "" then
                    set tName to text 1 thru -((count fileExt) + 2) of tName
                    tell (get container of aFile)
                        if not (exists folder tName) then make new folder at it with properties {name:tName}
                        move aFile to folder tName
                    end tell
                end if
            end if
        end repeat
    end tell
end run
This script work on files with a name extension.