AppleScript: Change an order of texts and HTML file in the body of Mail

Question

I would like to know how to insert a HTML file below the Signature in the body of Email.
This is my code,,,,
set the clipboard to (read (choose file) as «class RTF »)
set theBody to "Hello"
tell application "Mail"
activate
  set theMessage to make new outgoing message with properties {content:theBody, visible:true, subject:"mysubject"}
end tell
tell application "System Events"
  tell process "Mail"
  set focused of UI element 1 of scroll area 1 of window 1 to true
  keystroke "v" using command down
  end tell
end tell
What I would like to do is an order of body going like
From the top:
Body
Signature
HTML rtf file
Please teach me how to do!
Cheers,

Answer 1

Hi,
murrayshimada wrote:
Wondering how about inserting a HTML between body and signature? If you have a free time, please give me a tip again. Anyway, thank you for your help. Cheers,
You can set the order like this:
set the clipboard to (read (choose file) as «class RTF »)
set theBody to "Hello" & return & return -- need two return character to paste the clipboard after the body
tell application "Mail"
    activate
    set theMessage to make new outgoing message with properties {content:theBody, visible:true, subject:"mysubject"}
    my pasteToEnd()
    delay 0.6 -- need a delay to not remove the pasted text.
    set message signature of theMessage to signature 1 -- this put the signature after the text
end tell
on pasteToEnd()
    tell application "System Events"
        tell process "Mail"
            set focused of UI element 1 of scroll area 1 of window 1 to true
            key code 125 using command down -- (arrow down + command down) to set the insertion point to the end of text 
            keystroke "v" using command down
        end tell
    end tell
end pasteToEnd
Here's another example, the order =  the HTML, the body and the signature:
set the clipboard to (read (choose file) as «class RTF »)
set theBody to "Hello"
tell application "Mail"
    activate
    set theMessage to make new outgoing message with properties {content:"theBody", visible:true, subject:"mysubject"}
    my pasteAtBeginning() -- at beginning
    delay 0.6 -- need a delay to not remove the pasted text.
    set message signature of theMessage to signature 1 -- this put the signature after the text
end tell
on pasteAtBeginning()
    tell application "System Events"
        tell process "Mail"
            set focused of UI element 1 of scroll area 1 of window 1 to true -- this set the insertion point at beginning
            keystroke "v" using command down
            keystroke return & return -- to put a blank line between the RTF and the body
        end tell
    end tell
end pasteAtBeginning