AppleScript: Add a HTML file in the body of Email by the clipboard

Question

I would like to insert a HTML file into the body of Email by the clipboard action.
This is my cord below:
set the clipboard to (read (choose file) as «class RTF »)
set theBody to "Hello"
tell application "Mail"
activate
  set theMessage to make new outgoing message with properties {content:theBody, visible:true, subject:"mysubject"}
end tell
tell application "System Events"
  tell process "Mail"
  set focused of UI element 1 of scroll area 1 of window 1 to true
  keystroke "v" using command down
  end tell
end tell
This code enables only rtf file rather than HTML.
Also I don't want to use the html content by the function of Mail.
Because if using it, you won't insert both  a html file and body at the same time.
So what I would like to is to insert a HTML file by the clipboard action into a body.
Thank you!

Answer 1

Hi,
One solution is to use Safari to copy the document:
set x to choose file -- a HTML file
tell application "Safari"
    open x
    delay 2
    repeat while source of document 1 does not contain "</html>"
        delay 1.5
    end repeat
    activate
end tell
tell application "System Events"
    tell process "Safari"
        set frontmost to true
        keystroke "a" using command down -- select all
        delay 0.3
        keystroke "c" using command down -- copy to clipboard
    end tell
end tell
set theBody to "Hello"
tell application "Mail"
    activate
    set theMessage to make new outgoing message with properties {content:theBody, visible:true, subject:"mysubject"}
end tell
tell application "System Events"
    tell process "Mail"
        set focused of UI element 1 of scroll area 1 of window 1 to true
        keystroke "v" using command down
    end tell
end tell
Also try this:
set the clipboard to (read (choose file) as «class HTML») -- a HTML file