Applescript for recognizing hard drive names (Chronosync)

Question

I'm looking for a reliable, flexible and "idiot proof" backup system and am currently considering Chronosync for the job.
By "idiot proofing" the system I basically mean that the setup should keep track of source/destination drives in a multiple drive setup (I have a 4-bay Firewire enclosure and several removable hard drives each with a unique name) so I don't risk backing up to the wrong drives etc.
I've asked customer support at Chronosync if their software can detect hard drive names and was told it can't, but I could create an AppleScript that would prompt me to connect a drive, and set that as a pre-sync script in the Options Panel of ChronoSync, in the Scripts section.
Unfortunately I don't know much about Chronosync, nor do I have any knowledge of Applescripting. Does anyone here know of a readily available solution or have other suggestions?

Answer 1

I gave that script a short test... should work. =)
Remember to check (cancel on script error) because the script creates an error when you select "Cancel Backup" in it's dialogs:
-- 24.05.2011 hubionmac.com
-- can be added as as a pref-sync script to a  ChronoSync-Job to ask the user
-- to connect a missing source/destination volume if needed
--https://discussions.apple.com/thread/3075920
tell application "ChronoSync"
set mysource to leftTargetPath of document 1
set mydesti to rightTargetPath of document 1
if mysource starts with "/Volumes/" then
set mydelimiter to AppleScript's text item delimiters
set AppleScript's text item delimiters to "/"
set sourceName to text item 3 of mysource
set AppleScript's text item delimiters to mydelimiter
else
tell application "Finder" to set sourceName to name of startup disk
end if
if mydesti starts with "/Volumes/" then
set mydelimiter to AppleScript's text item delimiters
set AppleScript's text item delimiters to "/"
set destiName to text item 3 of mydesti
set AppleScript's text item delimiters to mydelimiter
else
tell application "Finder" to set destiName to name of startup disk
end if
tell application "Finder" to set drivenames to name of every disk
set cancelbackup to false
if sourceName is not in drivenames then
repeat until 1 = 0
set myaction to button returned of (display dialog "Source disk (" & sourceName & ") is not mountet!" buttons {"Check again!", "Cancel Backup"} default button 1 giving up after 30)
if myaction = "Check again!" then
tell application "Finder" to set drivenames to name of every disk
if sourceName is in drivenames then
exit repeat
end if
else
set cancelbackup to true
exit repeat
end if
end repeat
end if
if cancelbackup is false then
if destiName is not in drivenames then
repeat until 1 = 0
set myaction to button returned of (display dialog "Destination disk (" & destiName & ") is not mountet!" buttons {"Check again!", "Cancel Backup"} default button 1 giving up after 30)
if myaction = "Check again!" then
tell application "Finder" to set drivenames to name of every disk
if destiName is in drivenames then
exit repeat
end if
else
set cancelbackup to true
exit repeat
end if
end repeat
end if
end if
if cancelbackup is true then error "Canceling"
end tell