Applescript: Make iCal entry from Numbers spreadsheet

Question

I use a spreadsheet to book all my photography shoots. The columns (name, phone, email, job date, job time, job address, job city, services, notes) are inputted each time a client calls to book a shoot.Once they are booked, I create a new iCal entry for the "job date" with the title name being a slimmed down version of the services (ie, the client might have wanted photos, virtual tours, and prints, but for on site work, given that I will not be printing anything, I leave out the print from the title). So the final title might look like this: "photos, virtual tours @ 3pm". I also add the full address including the city into the iCal "location" field (just below the title field). Then I'll make sure that the date and time correspond to the spreadsheet. Next, I'll set it to a calendar I have made for these bookings. Finally, I'll add the services and notes to the "note" field at the very bottom of the iCal entry. Then click DONE.
Can someone help me write a simple script that would read a preselected row in the numbers spreadsheet and, once initiated, would create a new iCal entry? Thank you.

Answer 1

Thanks John. Yes, so I edited it a bit and made a few minor changes (basically adding some info to the notes section in the iCal entry). I've posted the code below. A couple minor tweaks would make this perfect: First, I'd prefer to simply selected one of the cells on a given row and then run the script--at that point the script would know to copy that entire row. I know this is possible because I have a script that does this... I'm just not sure how to integrate that part of the script with yours. I've posted the script below yours.
Second, I'd like iCal to open the newly added entry so I can have a quick review of it. Currently there's no indication that it's been added and, which iCal does appear to initiate (if it was closed down), it does however remain in the background.
Your script (with some mods):
set myCal to "TEST" -- calendar name
set myLength to 2 -- hours
set myItems to my cjmTIDs(the clipboard, tab)
if (count of myItems) is less than 12 then return
set jobDate to date (item 4 of myItems)
set timeArray to my numberFromHourText(item 5 of myItems)
set hours of jobDate to (item 1 of timeArray)
set minutes of jobDate to (item 2 of timeArray)
set jobEnd to jobDate + (myLength * hours)
set myTitle to (item 1 of my cjmTIDs((item 11 of myItems), "prints"))
set myNotes to "Client: " & (item 1 of myItems) & return & return & "Tel: " & (item 2 of myItems) & return & return & "Services: " & (item 11 of myItems) & return & return & "Notes: " & (item 12 of myItems)
set myURL to (item 3 of myItems)
set theAddress to (item 6 of myItems) & ", " & (item 7 of myItems) & ", " & (item 8 of myItems)
tell application "iCal"
          set myNewEvent to make new event at the end of events of calendar myCal with properties {start date:jobDate, end date:jobEnd, summary:myTitle, location:theAddress, url:myURL, description:myNotes}
end tell
on cjmTIDs(theText, theDelim)
          set my text item delimiters to theDelim
          set myList to text items of theText
          set my text item delimiters to {""}
          return myList
end cjmTIDs
on numberFromHourText(theText)
          set theParts to my cjmTIDs(theText, ":")
          if (count of theParts) is 2 then
                    set myHours to item 1 of theParts as number
                    set myMins to ((characters 1 thru -4 of item 2 of theParts) as text) as number
          else
                    set myHours to ((characters 1 thru -4 of theText) as text) as number
                    set myMins to 0
          end if
          if character -2 of theText is "p" then set myHours to myHours + 12
          return {myHours, myMins}
end numberFromHourText
The other script that I mentioned (the one that knows to copy the entire row by just selecting a cell):
set theTemplate to POSIX file "/Users/Peter/Library/Application Support/iWork/Numbers/Templates/My Templates/TEST.nmbtemplate"
tell application "Numbers 09"
          tell table 1 of sheet 1 of front document
                    set theValues to value of cells of row 1 of selection range
          end tell
  open theTemplate
          tell table 1 of sheet 1 of front document
                    set value of cell "A1" to item 1 of theValues
                    set value of cell "A2" to item 2 of theValues
                    set value of cell "A3" to item 3 of theValues
          end tell
          tell table 2 of sheet 1 of front document
                    set value of cell "B1" to item 6 of theValues
                    set value of cell "B2" to item 7 of theValues
                    set value of cell "B3" to item 4 of theValues
                    set value of cell "B4" to item 11 of theValues
                    set value of cell "D1" to item 38 of theValues
          end tell
          tell table 3 of sheet 1 of front document
                    set value of cell "A2" to item 11 of theValues
                    set value of cell "B2" to item 13 of theValues
          end tell
          tell table 5 of sheet 1 of front document
                    set value of cell "B2" to item 34 of theValues
                    set value of cell "B3" to item 14 of theValues
          end tell
          tell table 7 of sheet 1 of front document
                    set value of cell "B3" to item 30 of theValues
          end tell
          set R to display dialog "Save a PDF version of the invoice?" buttons {"No", "Yes"} default button 2 with icon 1
          if button returned of R is "Yes" then -- GUI Scripting:
                    tell application "System Events" to tell process "Numbers"
  click menu item "Print…" of menu 1 of menu bar item "File" of menu bar 1
                              set theWindowName to name of window 1 whose subrole is "AXStandardWindow"
                              tell sheet 1 of window theWindowName
                                        if value of checkbox -1 is 0 then click checkbox -1 -- to show all the settings
                                        set value of text field 3 to "1" -- number of copies = 1
  click radio button "From:" of radio group 2 -- button “From:”
                                        set value of text field 2 to "1" -- from page 1
                                        set value of text field 1 to "1" -- to page 1
  click radio button 2 of radio group 1 -- current sheet
                                        if value of checkbox 2 is 1 then click checkbox 2 -- to not include a list of all formulas
  click menu button "PDF"
                                        click menu item "Save as PDF…" of menu 1 of menu button "PDF"
                              end tell
  keystroke "Invoice" -- document name
  keystroke "d" using command down -- save to desktop
                              set value of text field 3 of group 1 of window 1 to "Invoice" -- title
                              set value of text field 4 of group 1 of window 1 to "Stone Home Photo & Video" -- author
                              tell window "Save"
                                        click button "Save"
                                        if sheet 1 exists then click button "Replace" of sheet 1
                              end tell
                    end tell
          end if
  close front document saving yes
end tell