Applescript MS Word move cursor

Question

Hi -- how do I use applescript to move the cursor
a few characters (left, right, down) in a word doc?
Thanks!

Answer 1

Hi,
You can also move the cursor without using the GUI Scripting.
Here are some examples :
tell application "Microsoft Word"
         -- count : The number of units by which you want to move
      move range text object of selection by a character item count 1 --move the cursor right
      move range text object of selection by a character item count -1 --move the cursor left
      end key selection move unit a line extend by moving -- move cursor to the end of line
      home key selection move unit a line extend by moving -- move cursor to the beginning of line
      move range text object of selection by a paragraph item count 1 -- move cursor to the beginning of next paragraph
      --** move the cursor after the last character in the next paragraph, error if no (next paragraph)
      set x to (get selection information selection information type first character line number) as integer
      try -- try block to not display the error
            move end of range (text object of paragraph (x + 1) of document 1) by a character item count -1
      end try
end tell
Here is a list a (the unit by which to move the collapsed range) that you can use with the move range  command : (a character item, a word item, a sentence item, a paragraph item, a line item, a story item, a screen, a section, a column, a row, a window, a cell, a character formatting, a paragraph formatting, a table, a item unit)
Also, there are other commands to move cursor, like move range end until, go to next , navigate, ...