Applescript to add a note to multiple contacts

Question

Hi
I wonder if someone well versed in Applescript could help me with this?
For each contact, I need to add their group names to the existing notes field, something like this:
Groups: Work, Christmas card
Why do I want to? Because I am moving to Kerio Mail Server but it has an unfortunate issue that it loses group memberships when syncing address book. I can work round this for now if I store the group memberships in the notes field - but I need to update all my existing contacts.
Can anyone help?
TIA

Answer 1

Try this:tell application "Address Book"
set r to display dialog "Do you want to change all people or just the selected people?" buttons {"All", "Selected"} default button "Selected"
if the button returned of r is "Selected" then
set thePeople to selection
else
set thePeople to people
end if
repeat with aPerson in thePeople
set oldNotes to note of aPerson
set theGroups to {}
repeat with aGroup in (groups whose people contains aPerson)
set theGroups to theGroups & (name of aGroup)
end repeat
if theGroups is not {} then
set AppleScript's text item delimiters to ", "
if oldNotes is not missing value then
set note of aPerson to oldNotes & return & "Groups: " & (theGroups as string)
else
set note of aPerson to "Groups: " & (text items of theGroups as string)
end if
set AppleScript's text item delimiters to " "
end if
end repeat
save addressbook
end tell
It will ask if you want to do all or just selected contacts.
I don't know how long it will take to go through each contact. I only tested the "Selected" part as I didn't want to have to fix my entire address book.
Now, if you export them all to vCards, Address Book adds the groups to "CATEGORIES:" on the vCard. I don't know if you can make use of that, instead. Can you define anything on the import, like map Categories to some field in Kerio?