AppleScript to save AppleWorks as Word .doc documents

Question

I'd like to start converting all my legacy .cwk documents into .doc files for reasons I'm sure everyone understands.
I wonder if anyone has already created an AppleScript to do this?
I have found on script for converting .cwk to .rtf - I wonder how I can modify that to save as .doc? See http://dmgsoftware.com/applescript/index.html
Thanks!

Answer 1

Hello
Here is an enhanced version. Read the comments first
Copy paste in the Script Editor
Save as an application (or an application bundle)
Store it in:
<bootVolume>:Users:<yourAccount>:Library:Scripts:Applications:Pages:
Maybe you will have to create the folder "Pages" or even the folder "Applications"
After that, when Pages is running, the script will be available in the System's Scripts menu.
Clicking the item "pages2Doc" will save the front document as a doc file
in the folder containing the original pages document.
If the document was never saved, according to current date_time it will be saved
as #YYYYMMDDThhmm.pages and #YYYYMMDDThhmm.doc in the default save folder.
If you change the property withSeconds from false to true,
the fileNames will be #YYYYMMDDThhmmss.pages and #YYYYMMDDThhmmss.doc
--(SCRIPT pages2Doc.app]
property theApp : "Pages"
property types : {{"doc", "SLDocumentTypeMSWord"}, {"pdf", "SLDocumentTypePDF"}, {"txt", "SLDocumentTypePlainText"}, {"rtf", "SLDocumentTypeRichText"}, {"rtfd", "SLDocumentTypeRichTextBundle"}}
property withSeconds : false
set {newExt, newType} to item 1 of types (*
item 1 = doc
item 2 = pdf
item 3 = txt
item 4 = rtf
item 5 = rtfd *)
tell application "Pages"
set theName to name of document 1
set thePath to path of document 1
end tell -- Pages
try
(* Pages returns UNIX pathnames *)
set thePath to POSIX file thePath
tell application "Finder" to set theCont to container of thePath as Unicode text
set newName to (text 1 thru -6 of theName) & newExt (* Replace the "pages" extension by the newExt one *)
on error (*
the doc was never saved *)
set unique to my serialize() (* build a unique name *)
set theCont to my getDefaultSave() (* grab the DefaultSave folder *)
tell application "Pages" to save front document in (theCont & unique & ".pages") (* save once as Pages document *)
set newName to unique & "." & newExt (* prepare for save as newType document *)
end try
set newPath to theCont & newName
(* CAUTION, When saving, Pages doesn't take care of an existing document.
It replaces it by the new one. *)
tell application "Pages" to save front document as newType in newPath (* save as newType document *)
-- =============
on getPlistValue(valName, default)
local thePlist, u
set thePlist to (path to preferences folder as Unicode text) & "com.apple.iWork." & theApp & ".plist"
tell application "System Events"
if exists file thePlist then
tell contents of property list file thePlist
try
set u to (value of property list item valName) (* Unicode Text *)
on error (*
On est là si Numbers n'a rien enregistré avec des préférences neuves
• Here if Numbers never saved with the new preferences file. *)
set u to default
end try
end tell -- to contents of…
else (*
On est là s'il n'y a pas de fichier de préférences
• Here if there is no preferences file. *)
set u to default
end if
end tell -- to system events
return u
end getPlistValue
-- =============
on getDefaultSave()
local thePlist, u
set u to my getPlistValue("LSDocumentDefaultSaveDirectory", "~/Documents")
if u = "~/Documents" then
set u to path to documents folder
else if u = "~/Desktop" then
set u to path to desktop
else
set u to ((POSIX file u) as Unicode text) & ":" (* indispensable *)
end if
return u as Unicode text
end getDefaultSave
-- =============
on serialize()
local cd, serial
set cd to current date
set serial to (year of cd as text) & text -2 thru -1 of ("0" & (month of cd as number)) & text -2 thru -1 of ("0" & day of cd) & "T" & text -2 thru -1 of ("0" & hours of cd) & text -2 thru -1 of ("0" & minutes of cd)
if withSeconds then
return "#" & serial & text -2 thru -1 of ("0" & seconds of cd)
else
return "#" & serial
end if
end serialize
-- =============
--[/SCRIPT]
I'm waiting for your comments before installing it on my iDisk.
Yvan KOENIG (from FRANCE samedi 9 février 2008 21:00:00)