Applescript to shift focus from sheet's pane to the table

Question

Cmd + Option + return shifts focus from the table to the sheet's pane. However, I haven't found a key that shifts focus back to the table. Therefore, I would appreciate an applescript that selects column A of the last row of the table, no matter which sheet has focus in the shift's pane.
Thanks
Fred

Answer 1

Hello
The script below will select the cell in the first table if only the sheet is selected.
Also I noticed the name main is somehow reserved in Automator and so replaced main() with _main() for use with it.
Hope this helps,
H
_main()
on _main()
    tell application "Numbers"
        activate
        set obj to my get_selected_container(document 1)
        tell obj
            if its class = table then
                set selection range to row -1's cell 1
            else
                tell table 1
                    set selection range to row -1's cell 1
                end tell
            end if
        end tell
    end tell
end _main
on get_selected_container(doc)
        reference doc : source Numbers document
    tell application "System Events"
        tell process "Numbers"
            -- bring Numbers to front
            set frontmost to true
            -- bring target document window to front
            tell (window 1 whose title = doc's name) -- only based on window title (not so reliable)
                perform action "AXRaise"
            end tell
            -- open new inspector window
            tell menu bar 1's menu bar item 9 -- view
                if menu 1's menu item 11's enabled then
                    tell menu 1's menu item 11 -- new inspector
                        click
                    end tell
                else
                    tell menu 1's menu item 10 --  inspector
                        click
                    end tell
                end if
            end tell
            -- get sheet name and table name
            tell (window 1 whose subrole = "AXFloatingWindow") -- front inspector window
                tell radio group 1
                    tell radio button 2 -- sheet
                        click
                    end tell
                end tell
                tell group 1
                    tell text field 2 -- name
                        set sheet_ to value
                    end tell
                end tell
                tell radio group 1
                    tell radio button 3 -- table
                        click
                    end tell
                end tell
                tell group 1
                    tell text field 4 -- name
                        set table_ to value
                    end tell
                end tell
                tell (button 1 whose subrole = "AXCloseButton") -- close
                    click
                end tell
            end tell
            --return {sheet_, table_}
        end tell
    end tell
    -- return object specifier of table or sheet if table_ is ""
    tell application "Numbers"
        tell doc
            if table_ = "" then
                return sheet sheet_
            else
                return sheet sheet_'s table table_
            end if
        end tell
    end tell
end get_selected_container