Applescript won't function as folder action

Question

Hello There,
Not long ago I discovered a script created by Matt Broughton that printed a file as RAW to a lpr printer. It solved a huge problem for me. It works well as a droplet, but I can't get it to function as a folder action. Here is the script:
on open printJobs
set trapFile to quoted form of POSIX path of (printJobs as string)
do shell script "lp -d printerqueuename -o raw " & trapFile
end open
The goal is to be able to print multiple files. Either a droplet that can handle several items or a functioning folder script.
After fooling around with this for a few months, I've discovered that I am a worthless scripter and can't manage to accomplish the goal.
I will be blunt: I need the script written for me.
Thanks for the help.

Answer 1

Folder Action scripts need to include a very specific handler since that's what the OS will call when the action is invoked.
So all you need to do is edit your script to put it in the appropriate handler.
Right now it's using the 'open' handler, so will run based on files that are dropped on the script. That's not what you need here. As a folder action you need a 'on adding folder items to' handler since that's what's called when items are added to your folder, e.g:
on adding folder items to the_folder after receiving the_files
  repeat with each_file in the_files
    set trapFile to quoted form of POSIX path of (each_file as text)
    do shell script "lp -d printerqueuename -o raw " & trapFile
  end repeat
end adding folder items to
Note the addition of a repeat loop which is needed since there may be multiple files added to the folder at once.