AQXmlNotification no payload

Question

Hi,
db v9.0.1.3
os solaris 5.6
I've created a queue and registered a PLSQL callback procedure. This procedure sends a notification email (setup using dbms_aqelm). I'm not using the AQ servlet, just PLSQL.
Couple of questions:
As i understand it, the payload is only included in the (email) XML if the message queue is non-persistent. Is there any way of including the payload for a message from a persistent queue in the mail notification?
Assuming the payload is included in the notification....
Is it possible to specify an XSL stylesheet to be applied to the mail notification before sending (to do XSL transformation of message into html email) so that the recipient has something more intuitive to look at? And if so, any pointers how i can apply the transformation stylesheet from within db? (from PLSQL using XDK for instance?)
Many thanks
James

Answer 1

Here is an example from Oracle XDK samples of how to apply XSL stylesheet to an XML document.
This example uses files present on the Operating System to apply the XSL Transformation.
You could change it to use a CLOB or a VARCHAR2 string depending upon your queue payload type.
-- This file demonstates a simple use of XSLT transformation capabilities.
-- The XML and XSL files that are given to the application are parsed,
-- the transformation specified is applied and the transformed document is
-- written to a specified result file.
-- The use of setting the parser options is demonstrated.
set serveroutput on;
create or replace procedure xslsample(dir varchar2, xmlfile varchar2,
xslfile varchar2, resfile varchar2,
errfile varchar2) is
p xmlparser.Parser;
xmldoc xmldom.DOMDocument;
xmldocnode xmldom.DOMNode;
proc xslprocessor.Processor;
ss xslprocessor.Stylesheet;
xsldoc xmldom.DOMDocument;
docfrag xmldom.DOMDocumentFragment;
docfragnode xmldom.DOMNode;
xslelem xmldom.DOMElement;
nspace varchar2(50);
xslcmds xmldom.DOMNodeList;
begin
-- new parser
p := xmlparser.newParser;
-- set some characteristics
xmlparser.setValidationMode(p, FALSE);
xmlparser.setErrorLog(p, dir || '/' || errfile);
xmlparser.setPreserveWhiteSpace(p, TRUE);
xmlparser.setBaseDir(p, dir);
-- parse xml file
dbms_output.put_line('Parsing XML document ' || dir || '/' || xmlfile);
xmlparser.parse(p, dir || '/' || xmlfile);
-- get document
xmldoc := xmlparser.getDocument(p);
-- parse xsl file
dbms_output.put_line('Parsing XSL document ' || dir || '/' || xslfile);
xmlparser.parse(p, dir || '/' || xslfile);
-- get document
xsldoc := xmlparser.getDocument(p);
xslelem := xmldom.getDocumentElement(xsldoc);
nspace := xmldom.getNamespace(xslelem);
-- print out some information about the stylesheet
dbms_output.put_line('XSL Root element information');
dbms_output.put_line('Qualified Name: ' ||
xmldom.getQualifiedName(xslelem));
dbms_output.put_line('Local Name: ' ||
xmldom.getLocalName(xslelem));
dbms_output.put_line('Namespace: ' || nspace);
dbms_output.put_line('Expanded Name: ' ||
xmldom.getExpandedName(xslelem));
xslcmds := xmldom.getChildrenByTagName(xslelem, '*', nspace);
dbms_output.put_line('A total of ' || xmldom.getLength(xslcmds) ||
' XSL instructions were found in the stylesheet');
-- make stylesheet
ss := xslprocessor.newStylesheet(xsldoc, dir || '/' || xslfile);
-- process xsl
proc := xslprocessor.newProcessor;
xslprocessor.showWarnings(proc, true);
xslprocessor.setErrorLog(proc, dir || '/' || errfile);
dbms_output.put_line('Processing XSL stylesheet');
docfrag := xslprocessor.processXSL(proc, ss, xmldoc);
docfragnode := xmldom.makeNode(docfrag);
dbms_output.put_line('Writing transformed document');
xmldom.writeToFile(docfragnode, dir || '/' || resfile);
-- Free XML Documents
xmldom.freeDocument(xmldoc);
xmldom.freeDocument(xsldoc);
-- Free XSL Stylesheet and Processor
xslprocessor.freeProcessor(proc);
xslprocessor.freeStylesheet(ss);
-- Free the xmlparser
xmlparser.freeParser(p);
-- deal with exceptions
exception
when xmldom.INDEX_SIZE_ERR then
raise_application_error(-20120, 'Index Size error');
when xmldom.DOMSTRING_SIZE_ERR then
raise_application_error(-20120, 'String Size error');
when xmldom.HIERARCHY_REQUEST_ERR then
raise_application_error(-20120, 'Hierarchy request error');
when xmldom.WRONG_DOCUMENT_ERR then
raise_application_error(-20120, 'Wrong doc error');
when xmldom.INVALID_CHARACTER_ERR then
raise_application_error(-20120, 'Invalid Char error');
when xmldom.NO_DATA_ALLOWED_ERR then
raise_application_error(-20120, 'Nod data allowed error');
when xmldom.NO_MODIFICATION_ALLOWED_ERR then
raise_application_error(-20120, 'No mod allowed error');
when xmldom.NOT_FOUND_ERR then
raise_application_error(-20120, 'Not found error');
when xmldom.NOT_SUPPORTED_ERR then
raise_application_error(-20120, 'Not supported error');
when xmldom.INUSE_ATTRIBUTE_ERR then
raise_application_error(-20120, 'In use attr error');
end xslsample;
show errors;