Are ref cursors supported in APEX??

Question

Apex version 3.2
ORacle 10G

Answer 1

Tony,
Please see http://apex.oracle.com/pls/apex/f?p=34598:1
This is a demo illustrating ApEx consuming a REF CURSOR for processing, and consuming the same REF CURSOR for a report.
Behind the scenes code:
-- defines the cursor type
create or replace PACKAGE emp_ref_cursor_pkg AS
   TYPE emp_ref_cursor IS REF CURSOR
      RETURN emp%ROWTYPE;
END emp_ref_cursor_pkg;
-- procedure returning a REF CURSOR of emp rows for specified department - pretend this is one of the original
-- poster's legacy REF CURSOR routines
create or replace PROCEDURE test_ref_cursor(
   p_deptno IN     NUMBER,
   p_cursor    OUT emp_ref_cursor_pkg.emp_ref_cursor
) IS
BEGIN
   OPEN p_cursor FOR
      SELECT *
        FROM emp
       WHERE deptno = p_deptno;
END test_ref_cursor;
-- table type to support pipelined function
create or replace package emp_pkg
is
  type emp_tbl is table of emp%rowtype;
end;
-- pipelined function wrapping the test_ref_cursor procedure, pipes rows for specified department
create or replace FUNCTION showit(p_deptno IN NUMBER)
   RETURN emp_pkg.emp_tbl
   PIPELINED IS
   c_cursor   emp_ref_cursor_pkg.emp_ref_cursor;
   r_emp      c_cursor%ROWTYPE;
BEGIN
   test_ref_cursor(p_deptno, c_cursor);
   LOOP
      FETCH c_cursor
      INTO r_emp;
      EXIT WHEN c_cursor%NOTFOUND;
      PIPE ROW (r_emp);
   END LOOP;
   CLOSE c_cursor;
   RETURN;
END;Source of PL/SQL Region in ApEx application showing consumption of REF CURSOR:
DECLARE
   c_cursor   emp_ref_cursor_pkg.emp_ref_cursor;
   r_emp      c_cursor%ROWTYPE;
BEGIN
   test_ref_cursor(10, c_cursor);
   LOOP
      FETCH c_cursor
      INTO r_emp;
      EXIT WHEN c_cursor%NOTFOUND;
      -- just output emp name - but could be any sort of processing going on here
      HTP.p(r_emp.ename || '<br />');
   END LOOP;
   CLOSE c_cursor;
END;Source of Report Region in ApEx application showing consumption of REF CURSOR via pipelined function from above:
SELECT *
  FROM table(showit(10))Does that answer the question sufficiently enough for you? Again, Tony, I NEVER said that ApEx can process a REF CURSOR - I simply said that, via PL/SQL, the original poster CAN still use his/her previously defined REF CURSORS in an ApEx application.
Please try to concentrate on helping the new users get up to speed on one of the best web-database RAD tools out there and not so much on trying to one-up the people that are just trying to help.
Regards,
John