Automator for PDF merge with variable

Question

Hi - very new to automator, but now very motivated to find a solution to this annoying problem.
I have to scan expense receipts each week and upload them 1 by 1 into a client time & expense system. I don't think Automator can help me with this one.
A second system requires all the expense receipts to be merged into a PDF and a 3rd copy emailed to an approver.
This is what I would like automator to do:
From my Expenses folder, where all my individual PDF's are located
I select all my distinct PDF's for a particular week
Using an automator service, right click style
Using 'Ask for Text', I would enter the "Week of"
My selected PDF's are merged into 1 PDF, with the name = "Week of <VAR>"
Mail starts (can't figure out how to use Gmail in a browser in Automator)
Creates a message to the approver guy with the merged attachment from #5 above
Sends the message
Quits Mail
I can get the automator to run without the variables trick...but it really would save a lot of time if I could just key it in once (instead of #filename, #email subject, #body of the message).
I also tried looking up the UUID for the variable and inserting it into the email body and subject line - but it didn't take.
Can anyone help with this?
Many thanks
bforeste

Answer 1

Can't help you with automator, but you can create an app with the applescript below that will do what you want.
Procedure:
1. Open the Applescript Editor by typing Apples in the spotlight search field and hitting 'return' on your keyboard.
2. Copy the entire script below and paste it into the Editor window.
3. Hit 'Command-K' on the keyboard and ensure there are no compiler errors. If there are, please look at the script and see if one part of it was highlighted. Report back what part of the script was highlighted and any error messages.
If the compile didn't produce an error, then:
4. Hit 'Command-S' on the keyboard, choose a snazzy name ("PDF merger" or something...) and a location to save it in (your Apps or Desktop folders).  Be sure to change the 'File Format:' to Application at the bottom of the Save screen before hitting 'Save'.
5. The first time you run the app (you run it by double-clicking on it, like any other App), you'll be asked to put in the details manually. On subsequent runs, it will fill in the defaults for you. I haven't set up the default locations for looking and searching for the files as I'm not sure where they would be on your system. I can do that if you tell me the path from your 'home' or user directory.
Also note, I've written the script so that it doesn't send the message until you've reviewed it. i.e., you might want to double check you've attached the correct file, or add a message. If you want it to send automatically without review change the following lines near the end of the script:
change the line 'set visible to true' to 'set visible to false'
change the line 'save' to 'send'
property defaultFolder : ""
property msgSubject : ""
property theRecipient : ""
property theWeeklyname : ""
property outputFile : ""
getInfo()
mergePDFS()
sendMail()
on getInfo()
          display dialog "Type the recipient's email address: " default answer theRecipient
          set theRecipient to the text returned of the result
          delay 0.25
          display dialog "Set the subject of the message: " default answer msgSubject
          set msgSubject to the text returned of the result
end getInfo
on mergePDFS()
          display dialog "Please choose the files to merge…" default button "OK"
          set inputFiles to choose file of type "PDF" with multiple selections allowed without invisibles
          delay 0.25
          display dialog "Please choose a folder to save the merged PDF…" default button "OK"
          set outputFolder to choose folder
          delay 0.25
          display dialog "Type the name of the combined pdf (without the .pdf extension): " default answer theWeeklyname
          set theWeeklyname to text returned of the result
          set outputFile to (outputFolder as text) & theWeeklyname & "(" & (count of inputFiles) & ").pdf"
          set pdfFiles to ""
          repeat with p in inputFiles
                    set pdfFiles to pdfFiles & " " & quoted form of POSIX path of p
          end repeat
          do shell script "/System/Library/Automator/Combine\\ PDF\\ Pages.action/Contents/Resources/join.py " & "-o " & quoted form of POSIX path of outputFile & pdfFiles
          return outputFile as alias
end mergePDFS
on sendMail()
          tell application "Finder"
                    set theAttachment to outputFile as alias
          end tell
          tell application "Mail"
                    set newMessage to make new outgoing message with properties {subject:msgSubject, content:"" & return & return}
                    tell newMessage
                              set visible to true
  make new to recipient at end of to recipients with properties {address:theRecipient}
                              tell content
  make new attachment with properties {file name:theAttachment} at after the last paragraph
                              end tell
  save
                    end tell
          end tell
end sendMail