Best choice for a date column in forms

Question

Hello,
I want to know what is the best choice for a date field that the user have to enter manually. I read on a other post that a calender control is not directly implemented in forms 9i. So what is the best choice to be "user friendly" with a date field in a form?
thanks in advance.

Answer 1

Hi
Don't know if this would be much use to you, but I wrote this function 'Check_Date' a while back to check whether the user had typed something which could be interpreted as a date. You'd make your date field into a Text Item, and include a call to this function (which could be in your form, or in a library) in the WHEN-VALIDATE-ITEM trigger on the item, ie:
IF NOT check_date(:ITEMS.date_item1, NULL, NULL) THEN
    RAISE FORM_TRIGGER_FAILURE;
END IF;This would mean that the user could type 'T' or '*' for today, '+1' for tomorrow, '-7' for one week ago, or the date in a variety of formats. When they leave the field, the function tries to resolve what they've typed into a date, and sets the field to a date in the correct format.
('Display_Alert' is just a function to display a named alert with a message.) It can also be used to check that the date entered doesn't fall outside upper and lower bounds. Code follows:
FUNCTION Check_Date (text_in        IN OUT VARCHAR2,
                     lower_bound_in IN DATE,
                     upper_bound_in IN DATE)
RETURN BOOLEAN IS
first_letter      VARCHAR2(1)  := SUBSTR(text_in, 1, 1);
date_ok           BOOLEAN;
this_date         DATE;
date_diff         NUMBER(8);
output_format     VARCHAR2(12) := Get_Application_Property(BUILTIN_DATE_FORMAT);
TYPE date_format_table_type IS TABLE OF VARCHAR2(12)
INDEX BY BINARY_INTEGER;
date_format_table    date_format_table_type;
BEGIN
    --Set up table of date formats in order they'll be tested for
    date_format_table(1)  := 'DD-MON-RRRR';
    date_format_table(2)  := 'DD-MM-RRRR';
    date_format_table(3)  := 'DD-MM';
    date_format_table(4)  := 'DD-MON';
    date_format_table(5)  := 'YYYY-MM-DD';
    date_format_table(6)  := 'YYYY-MON-DD';
    --Use of T, or * for today's date...
    IF UPPER(text_in) IN ('T', '*') THEN
           this_date := SYSDATE;
           date_ok := TRUE;
    --Look for use of +x/-x for number of days different from today
    ELSIF first_letter IN ('+', '-') THEN
           BEGIN
               date_diff := TO_NUMBER(SUBSTR(text_in, 2));
               IF first_letter = '+' THEN
                   this_date := SYSDATE + date_diff;
               ELSE
                      this_date := SYSDATE - date_diff;
               END IF;
               date_ok := TRUE;              
           EXCEPTION
                  WHEN VALUE_ERROR THEN
                      --User has entered something like '+X', so not valid
                      date_ok := FALSE;
           END;
    ELSE
        --Go through all the possible formats for date entry,
        --if any give a valid date, then return that.
        FOR ix IN date_format_table.FIRST..date_format_table.LAST LOOP
               EXIT WHEN date_ok;
            BEGIN
                   --Try creating a date using the format masks in the local
                   --table.  If no good, this will throw an INVALID_DATE exception
                   this_date := TO_DATE(text_in, date_format_table(ix));
                   date_ok := TRUE;
               EXCEPTION
                   WHEN OTHERS THEN
                       date_ok := FALSE;
               END;
        END LOOP;
    END IF;
    IF date_ok THEN         
           --Check for violation of lower/upper bounds on date
           IF (lower_bound_in IS NOT NULL AND this_date < lower_bound_in) THEN
               Display_Alert('info_alert', 'Date cannot be before '||TO_CHAR(lower_bound_in, output_format));
               date_ok := FALSE;
           ELSIF (upper_bound_in IS NOT NULL AND this_date > upper_bound_in) THEN
               Display_Alert('info_alert', 'Date cannot be after '||TO_CHAR(upper_bound_in, output_format));
               date_ok := FALSE;
           ELSE
                  text_in := TO_CHAR(this_date, output_format);
           END IF;
    ELSE
        Display_Alert('INFO_ALERT', text_in||' is not a valid date !!');
    END IF;
    RETURN date_ok;
END;Hope this is useful.
regards
Andrew
UK