Boolean type

Question

I'm trying to create a new table as follows:
create table enderecos
(trabalhador number primary key,
Rua varchar2(50),
numero number,
Bairro varchar2(50),
Cidade varchar2(40),
uf varchar2(2),
casa BOOLEAN,
num_apt number);
And when I try to run this statement I get the error: Invalid datatype.
My question is, I have never done this before in pl/sql, but isn't it possible to define boolean variables in pl/sql? If it is, what might be happening?

Answer 1

I use the following boolean utility functions quite a bit.
   *  FUNCTION to_boolean
  FUNCTION to_boolean (p_char IN VARCHAR2)
    RETURN BOOLEAN
  IS
  BEGIN
    IF UPPER (p_char) NOT IN ('Y', 'N', 'T', 'F', '0', '1')
    THEN
      raise_application_error
                       (-20000,
                        'Only Y/N or T/F or 0/1 may be converted to Boolean.');
    END IF;
    RETURN UPPER (p_char) IN ('Y', 'T', '1');
  END to_boolean;
   *  FUNCTION to_01
  FUNCTION to_01 (p_boolean IN BOOLEAN)
    RETURN NUMBER
  IS
  BEGIN
    IF p_boolean
    THEN
      RETURN 1;
    ELSIF NOT p_boolean
    THEN
      RETURN 0;
    ELSE
      RETURN NULL;
    END IF;
  END to_01;
   *  FUNCTION to_01
  FUNCTION to_01 (p_char IN VARCHAR2)
    RETURN NUMBER
  IS
  BEGIN
    RETURN to_01 (to_boolean (p_char));
  END to_01;
   *  FUNCTION to_yn
  FUNCTION to_yn (p_boolean IN BOOLEAN)
    RETURN VARCHAR2
  IS
  BEGIN
    IF p_boolean
    THEN
      RETURN 'Y';
    ELSIF NOT p_boolean
    THEN
      RETURN 'N';
    ELSE
      RETURN NULL;
    END IF;
  END to_yn;
   *  FUNCTION to_yn
  FUNCTION to_yn (p_char IN VARCHAR2)
    RETURN VARCHAR2
  IS
  BEGIN
    RETURN to_yn (to_boolean (p_char));
  END to_yn;
   *  FUNCTION to_tf
  FUNCTION to_tf (p_boolean IN BOOLEAN)
    RETURN VARCHAR2
  IS
  BEGIN
    IF p_boolean
    THEN
      RETURN 'T';
    ELSIF NOT p_boolean
    THEN
      RETURN 'F';
    ELSE
      RETURN NULL;
    END IF;
  END to_tf;
   *  FUNCTION to_tf
  FUNCTION to_tf (p_char IN VARCHAR2)
    RETURN VARCHAR2
  IS
  BEGIN
    RETURN to_tf (to_boolean (p_char));
  END to_tf;