Bulk Fetch stored procedure.

Question

I am new to the oracle world.
Does any one have a very good, but simple example of a bulk fetch that show the creation of the container variable?

Answer 1

SQL> declare
  2   /* Declare index-by table of records type */
  3   type emp_rec_tab is table of emp%rowtype index by binary_integer;
  4 
  5   /* Declare table variable*/
  6   emptab emp_rec_tab;
  7 
  8   /* Declare REF CURSOR variable using SYS_REFCURSOR declaration
  9   in 9i and above */
10   rcur sys_refcursor;
11 
12   /* Declare ordinar cursor */
13   cursor ocur is select * from emp;
14 
15  begin
16 
17   /* bulk fetch using implicit cursor */
18   select * bulk collect into emptab from emp;
19   dbms_output.put_line( SQL%ROWCOUNT || ' rows fetched at once from implicit cursor');
20   dbms_output.put_line('---------------------------------------------');
21 
22   /* bulk fetch from Ordinar cursor */
23   open ocur;
24   fetch ocur bulk collect into emptab;
25   dbms_output.put_line( ocur%ROWCOUNT || ' rows fetched at once from ordinar cursor');
26   dbms_output.put_line('---------------------------------------------');
27   close ocur;
28 
29   /* bulk fetch from Ordinar cursor using LIMIT clause */
30   open ocur;
31   loop
32    fetch ocur bulk collect into emptab limit 4;
33    dbms_output.put_line(
34      emptab.count ||
35      ' rows fetched at one iteration from ordinar cursor using limit');
36    exit when ocur%notfound;
37   end loop;
38   close ocur;
39   dbms_output.put_line('---------------------------------------------');
40 
41   /* bulk fetch from ref cursor */
42   open rcur for select * from emp;
43   fetch rcur bulk collect into emptab;
44   dbms_output.put_line( rcur%ROWCOUNT || ' rows fetched at once from ref cursor');
45   dbms_output.put_line('---------------------------------------------');
46   close rcur;
47 
48   /* bulk fetch from ref cursor using LIMIT clause */
49   open rcur for select * from emp;
50   loop
51    fetch rcur bulk collect into emptab limit 4;
52    dbms_output.put_line( emptab.count ||
53    ' rows fetched at one iteration from ref cursor using limit');
54    exit when rcur%notfound;
55   end loop;
56   close rcur;
57   dbms_output.put_line('---------------------------------------------');
58 
59   /* bulk fetch using execute immediate */
60   execute immediate 'select * from emp' bulk collect into emptab;
61   dbms_output.put_line( SQL%ROWCOUNT || ' rows fetched using execute immediate');
62   dbms_output.put_line('---------------------------------------------');
63 
64  end;
65  /
14 rows fetched at once from implicit cursor
14 rows fetched at once from ordinar cursor
4 rows fetched at one iteration from ordinar cursor using limit
4 rows fetched at one iteration from ordinar cursor using limit
4 rows fetched at one iteration from ordinar cursor using limit
2 rows fetched at one iteration from ordinar cursor using limit
14 rows fetched at once from ref cursor
4 rows fetched at one iteration from ref cursor using limit
4 rows fetched at one iteration from ref cursor using limit
4 rows fetched at one iteration from ref cursor using limit
2 rows fetched at one iteration from ref cursor using limit
14 rows fetched using execute immediate
&nbsp
PL/SQL procedure successfully completed.Rgds.