Call procedure via dynamic sql

Question

Dear Oracle experts,
I try to call several stored procedures from several packages within the function below.
These stored procedures all own a procedure returning a version string.
I would like to write a function which gets a schemaname (for the schema which contains the package), and a packagename which calls a procedure within that package (all packages have a procedure called sp_packageversion which returns a versionstring) and returns the received versionstring.
But my codes doesn't work because the dynamic sql doesn't call the procedure.
What am I doing the wrong way ?
function func_GetPackageVersion(prm_ecs_Schemaname varchar2, prm_objectname user_procedures.object_name%type
) return varchar2 is
sqlstmt varchar2(100);
objectversion varchar2(50);
begin
sqlstmt := prm_ecs_Schemaname || '.' || prm_objectname || '.sp_packageversion(objectversion)';
execute immediate sqlstmt;
return objectversion;
end func_GetECSPackageVersion;
Hope someone can help.
Best regards,
Daniel

Answer 1

test@ora>
test@ora>
test@ora> --
test@ora> -- the package
test@ora> --
test@ora> create or replace package my_pkg
  2  as
  3    procedure sp_packageversion (objectversion out varchar2);
  4  end;
  5  /
Package created.
test@ora>
test@ora> create or replace package body my_pkg
  2  as
  3    procedure sp_packageversion (objectversion out varchar2)
  4    is
  5    begin
  6      objectversion := 'VERSION IS 10.1.2.3';
  7    end;
  8  end;
  9  /
Package body created.
test@ora>
test@ora> --
test@ora> -- the function
test@ora> --
test@ora> create or replace function func_GetPackageVersion (
  2    prm_ecs_Schemaname varchar2,
  3    prm_objectname     user_procedures.object_name%type
  4  )
  5  return varchar2
  6  is
  7    sqlstmt varchar2(4000);
  8    objectversion varchar2(50);
  9  begin
10    execute immediate 'BEGIN '|| prm_ecs_Schemaname ||'.' || prm_objectname || '.sp_packageversion(:x); END; ' USING OUT objectversion;
11    return objectversion;
12  end;
13  /
Function created.
test@ora>
test@ora> --
test@ora> -- anonymous pl/sql block for the function
test@ora> --
test@ora> declare
  2    p_ecs_Schemaname  varchar2(30) := 'TEST';
  3    p_objectname      user_procedures.object_name%type := 'MY_PKG';
  4    v_return_str      varchar2(32767);
  5  begin
  6    v_return_str := func_GetPackageVersion (p_ecs_Schemaname, p_objectname);
  7    dbms_output.put_line(v_return_str);
  8  end;
  9  /
VERSION IS 10.1.2.3
PL/SQL procedure successfully completed.
test@ora>
test@ora>
test@ora>HTH
isotope