Calling selection screen depends on radio buttion selection

Question

I need to call two selection screens (not radio buttons selection screens) depends on radio buttion selection
Eg :
   R1-radio button
  R2- radio button
if we select R1- we should get selection screen to enter input values like parameters, select options
   PARAMETERS:     p_abc TYPE    MARA-matnr OBLIGATORY
  SELECT-OPTIONS: s_mno  FOR   MARC- chngr OBLIGATORY.
  PARAMETERS:     p_xyz TYPE     MARA - amktxOBLIGATORY.  (just example)
If we select R2, we should get selection screen to enter input values like parameters, select options
PARAMETERS:         p_abcd TYPE    KNA1-matnr OBLIGATORY
  SELECT-OPTIONS:  s_mnop  FOR   VBAK- chngr OBLIGATORY.
  PARAMETERS:        p_xyza TYPE     VBAP - amktxOBLIGATORY  (just example)
if we select 1 , other should be hide
Madhu

Answer 1

Hi,
this is an example:
SELECTION-SCREEN BEGIN OF BLOCK B2 WITH FRAME TITLE TEXT-002.
PARAMETER R1 RADIOBUTTON GROUP G1 DEFAULT 'X' USER-COMMAND SET1.
PARAMETER R2 RADIOBUTTON GROUP G1 .
SELECTION-SCREEN BEGIN OF BLOCK B21 WITH FRAME TITLE TEXT-004.
PARAMETER: P1 LIKE IBIPPARMS-PATH MODIF ID FPA.
SELECTION-SCREEN END OF BLOCK B21.
SELECTION-SCREEN BEGIN OF BLOCK B22 WITH FRAME TITLE TEXT-004.
PARAMETER: P2 LIKE IBIPPARMS-PATH MODIF ID FPB.
SELECTION-SCREEN END OF BLOCK B22.
SELECTION-SCREEN END OF BLOCK B2.
DATA: P_CHECK.
AT SELECTION-SCREEN OUTPUT.
  IF P_CHECK <> 'X'.
    LOOP AT SCREEN.
      IF SCREEN-GROUP1 = 'FPA' OR
         SCREEN-GROUP1 = 'FPB'.
        SCREEN-INPUT = '0'.
        SCREEN-INVISIBLE = '1'.
        MODIFY SCREEN.
      ENDIF.
    ENDLOOP.
    P_CHECK = 'X'.
  ENDIF.
  IF R1 = 'X'.
    LOOP AT SCREEN.
      IF SCREEN-GROUP1 = 'FPA'.
        SCREEN-INVISIBLE = '0'.
        SCREEN-INPUT = '1'.
        MODIFY SCREEN.
      ENDIF.
      IF SCREEN-GROUP1 = 'FPB'.
        SCREEN-INVISIBLE = '1'.
        SCREEN-INPUT = '0'.
        MODIFY SCREEN.
      ENDIF.
    ENDLOOP.
  ENDIF.
  IF R2 = 'X'.
    LOOP AT SCREEN.
      IF SCREEN-GROUP1 = 'FPB'.
        SCREEN-INVISIBLE = '0'.
        SCREEN-INPUT = '1'.
        MODIFY SCREEN.
      ENDIF.
      IF SCREEN-GROUP1 = 'FPA'.
        SCREEN-INVISIBLE = '1'.
        SCREEN-INPUT = '0'.
        MODIFY SCREEN.
      ENDIF.
    ENDLOOP.
  ENDIF.
Angelo.