Can I control an image position with Scripting?

Question

hello --
i find myself doing a lot of repetitive tasks in keynote, such as creating dozens of slides with an image in a specific position (x-y position). is there a way to automate this using applescript or automator?
so far, i am able to create the empty slides with the images in a specified folder, but they always just get centered. it's a good start, but the next time suck is to position them by hand.
any ideas?
thanks in advance.

Answer 1

Hello,
It's not possible without the help of the GUI Scripting.
This implies that you should not use the mouse or the keyboard during the execution of the script, but it's better than doing it manually on several images.
You must enable the GUI Scripting by clicking the checkbox labeled "Enable access for assistive devices" in the Universal Access System Preference pane.
Here is the script : this script create a slide of each image (your selection in the Choose file dialog), and it set the position of the image in each added slide to (40, 60)
---------------------Beginning ot the Script
set tFiles to choose file of type "public.image" with multiple selections allowed
tell application "Keynote"
    activate
    tell front slideshow
        set nSlides to count slides
        make image slides paths tFiles without set titles
        set nSlides2 to count slides
        set firstTime to true
        if nSlides2 > nSlides then repeat with i from (nSlides + 1) to nSlides2
            show slide i
            my setImageposition(40, 60, firstTime) -- set image position to (40, 60)  
            set firstTime to false
        end repeat
    end tell
    display dialog "Done"
end tell
on setImageposition(posX, posY, firstTime)
    tell application "System Events"
        tell process "Keynote"
            if firstTime then (* initialization so that the script works correctly.
                   Show the Inspector window, click on "Metrics" tab.
                   Set the View to "Slide Only" *)
                set frontmost to true
                delay 0.3
                click menu item "Slide Only" of menu "View" of menu bar item "View" of menu bar 1
                set inspectorWindow to missing value
                set tWindows to windows whose subrole is "AXFloatingWindow"
                repeat with i in tWindows
                    if exists radio group 1 of i then
                        set inspectorWindow to i
                        exit repeat
                    end if
                end repeat
                if inspectorWindow is missing value then
                    keystroke "i" using {option down, command down} -- Show Inspector
                    delay 0.2
                end if
                tell window 1 to if name is not "Metrics" then -- size and position
                    click radio button 6 of radio group 1 -- the "Metrics" tab
                    delay 0.2
                end if
            end if -- end initialization
            keystroke "a" using command down -- select image
            perform action "AXRaise" of window 1 -- set the focus to  the Inspector window
            delay 0.1
            tell group 1 of window 1
                set focused of text field "X" to true -- left position
                delay 0.1
                keystroke ("" & posX & tab & posY & tab) -- set image position,
            end tell
        end tell
    end tell
end setImageposition
--------------------- End Script
Important : You must localize the titles (depending on the language used in your system) in these two lines:
click menu item "Slide Only" of menu "View" of menu bar item "View" of menu bar 1
tell window 1 to if name is not "Metrics" then -- size and position