Cancel all items in the purchase order

Question

we need a program to cancel all items in the purchase order   .
exists any BAPI or funcion or metod to do this ?
becuase if we to do this for the TC ME22N we need to do this item by item.   
our programmer  suggest us an update of the table EKPO

Answer 1

Here is an example program using the BAPI to set the deletion indicator on all line items of a PO. 
report zrich_0001.
data:   return type table of bapiret2 with header line,
        poheader type bapimepoheader,
        poheaderx type bapimepoheaderx,
        poitem type table of  bapimepoitem with header line,
        poitemx type table of  bapimepoitemx with header line.
data: iekpo type table of ekpo with header line.
parameters: p_ebeln type ekpo-ebeln.
start-of-selection.
  poheader-po_number = p_ebeln.
clear iekpo.  refresh iekpo.
  select * into table iekpo from ekpo
                 where ebeln = p_ebeln.
  loop at iekpo.
    poitem-po_item = iekpo-ebelp.
    poitem-delete_ind = 'X'.
    append poitem.
    poitemx-po_item = iekpo-ebelp.
    poitemx-po_itemx   = 'X'.
    poitemx-delete_ind = 'X'.
    append poitemx.
  endloop.
  call function 'BAPI_PO_CHANGE'
       exporting
            purchaseorder = p_ebeln
            poheader      = poheader
            poheaderx     = poheaderx
       tables
            return        = return
            poitem        = poitem
            poitemx       = poitemx.
  commit work.
  loop at return.
    write:/ return.
  endloop.
Regards,
RIch Heilman