Change abesnt to leave in ESS portal 7.3

Question

Hi Experts,
We are using Portal 7,3 version,my requirment is we need to change the absent to leave in Working Time ->create leave request-
>Calender tab. here we need to change absent to leave.
we know the followning information.
Component: HRESS_C_LEA_EMP_CALENDAR
Window: W_MAIN
View: V_EMP_CALENDAR
Application Component: PA-ESS-XX-WDA
Please help me where can i modify name in ESS.
Thanks in advance.
Thanks and Regards,
Vanitha

Answer 1

Hi,
enhance the above mentioned method, in Overwrite exit paste the below code.
method _OVR_9PSJM003IJB4KOVKXYXOVKO32 . "Exit of LOAD_CALENDAR_DATA (in ZHR_TEST )
* Call the function module and read the calendar data for the user
  DATA: lt_eecale_data  TYPE ptarq_uia_eecale_tab,
        lv_begda        TYPE sy-datum,
        lv_month_x      TYPE i,
        lv_month_y      TYPE i,
        lt_legend       TYPE ptreq_uia_legend_tab,
        lt_commands     TYPE ptarq_uia_command_tab,
        lt_messages     TYPE ptarq_uia_messages_tab.
  DATA: ls_eecale_data  LIKE LINE OF lt_eecale_data,
        ls_legend       LIKE LINE OF lt_legend.
  DATA  lv_application_mode TYPE pt_arq_mode.
  CALL METHOD wd_comp_controller->go_communicator->ret_application_mode
    RECEIVING
      rv_pt_arq_mode = lv_application_mode.
  IF lv_application_mode IS INITIAL. " Fallback implementation:
    lv_application_mode = cl_pt_req_const=>c_role_employee.
  ENDIF.
*  Begin of Jain_1661953
DATA: wda_ec TYPE flag.
      wda_ec = 'x'.
     EXPORT wda_ec FROM wda_ec TO MEMORY ID 'WDA_EC_FLG'.
*  End of Jain_1661953
* Call the function module to Read the Employee data in a particular period
  CALL FUNCTION 'PT_ARQ_EECALE_GET'
    EXPORTING
      im_command           = iv_command
      im_pernr             = wd_this->gv_pernr
      im_time_format       = '1'
      im_modus             = lv_application_mode
      im_eecale_start_date = iv_start_date
      im_deactivate_check  = abap_true
*     IM_DEBUG             =
    IMPORTING
      ex_eecale_data       = lt_eecale_data
      ex_begda             = lv_begda
      ex_month_x           = lv_month_x
      ex_month_y           = lv_month_y
    TABLES
      ex_legend            = lt_legend
      ex_commands          = lt_commands
      ex_messages          = lt_messages.
************ To Change the legend text *************
  LOOP AT lt_legend INTO ls_legend where TEXT = 'Absent'.
    ls_legend-text = 'Leave'.
    modify lt_legend from ls_legend transporting text.
  endloop.
* Update the data returned by the FM into the corresponding Context nodes:
* Update the markings in the Calendar:
  DATA: BEGIN OF ls_calemarking,
          date      TYPE d,
          semantics TYPE wdui_table_cell_design,
          tooltip   TYPE string,
        END OF ls_calemarking.
  DATA lt_calemarking     LIKE TABLE OF ls_calemarking.
  DATA lo_nd_calemarking  TYPE REF TO if_wd_context_node.    "Ref to series_node
  DATA lt_request         TYPE ptreq_uia_request_id_tab.
  DATA ls_request         TYPE ptreq_uia_request_id_struc.
  LOOP AT lt_eecale_data INTO ls_eecale_data.
    ls_calemarking-date = ls_eecale_data-reqdate.
    ls_calemarking-semantics = wd_this->conv_table_cell_design( iv_legendid = ls_eecale_data-legendid ).
*   Read tooltip information
    lt_request = ls_eecale_data-request[].
    CLEAR ls_calemarking-tooltip.
    LOOP AT lt_request INTO ls_request.
      IF ls_calemarking-tooltip IS INITIAL. " First loop execution
        ls_calemarking-tooltip   = ls_request-tooltip.
      ELSE.
        CONDENSE ls_calemarking-tooltip.
        CONCATENATE ls_calemarking-tooltip ls_request-tooltip INTO ls_calemarking-tooltip SEPARATED BY ', '.
      ENDIF.
    ENDLOOP.
    APPEND ls_calemarking TO lt_calemarking.
  ENDLOOP.
* Read the personal work schedule and mark the Off Days and Public Holidays in the calendar.
  DATA: lv_begin_date TYPE datum,
        lt_psp TYPE ptpsp_tab,
        ls_psp TYPE ptpsp.
  lv_begin_date = iv_start_date.
  lv_begin_date+6(2) = '01'.
* Temporary buffering required for monthly navigation of the Datenavigator instead of the default quarterly:
  wd_this->gv_begin_date = lv_begin_date.
  lt_psp = wd_this->read_work_schedule(
      iv_begda = lv_begin_date ).
  LOOP AT lt_psp INTO ls_psp WHERE stdaz EQ 0.
    CLEAR ls_calemarking.
    ls_calemarking-date = ls_psp-datum.
    ls_calemarking-semantics = '20'. " CALENDARMETAL
    ls_calemarking-tooltip = cl_wd_utilities=>get_otr_text_by_alias( alias = 'PAOC_ESS_WDA_OTR/NON_WORKDAY' ).
    APPEND ls_calemarking TO lt_calemarking.
  ENDLOOP.
  LOOP AT lt_psp INTO ls_psp WHERE ftkla NE 0.
    CLEAR ls_calemarking.
    ls_calemarking-date = ls_psp-datum.
    ls_calemarking-semantics = '17'. " TWO.
*   Read Public Holiday information:
    ls_calemarking-tooltip = cl_hress_ptarq_tim_services=>get_public_holiday_description(
                                 iv_pernr = wd_this->gv_pernr
                                 iv_date = ls_psp-datum ).
    IF ls_calemarking-tooltip IS INITIAL.
      ls_calemarking-tooltip = cl_wd_utilities=>get_otr_text_by_alias( alias = 'PAOC_ESS_WDA_OTR/NON_WORKDAY' ).
      ls_calemarking-semantics = '20'.
    ENDIF.
    APPEND ls_calemarking TO lt_calemarking.
  ENDLOOP.
* Setting the value of Context CalenderMarking...
  lo_nd_calemarking = wd_context->get_child_node( name = 'CALENDARMARKINGS' ).
  CALL METHOD lo_nd_calemarking->bind_table
    EXPORTING
      new_items = lt_calemarking.
* Setting the value of Context CalendarData
  DATA: lo_nd_cale_data  TYPE REF TO if_wd_context_node.
  DATA: BEGIN OF ls_cale_data,
          selection_begda TYPE d,
          selection_endda TYPE d,
          startswith      TYPE d,
          monthspercol    TYPE i,
          monthsperrow    TYPE i,
        END OF ls_cale_data.
  lo_nd_cale_data = wd_context->get_child_node( name = 'CALENDARDATA' ).
  IF iv_selection_begda IS NOT INITIAL."IS SUPPLIED.
    ls_cale_data-selection_begda = iv_selection_begda.
  ELSE.
    ls_cale_data-selection_begda = sy-datum.
  ENDIF.
  IF iv_selection_endda IS NOT INITIAL. "IS SUPPLIED.
    ls_cale_data-selection_endda = iv_selection_endda.
  ELSE.
    ls_cale_data-selection_endda = sy-datum.
  ENDIF.
  ls_cale_data-startswith      = lv_begda.
  ls_cale_data-monthsperrow    = lv_month_x.
  ls_cale_data-monthspercol    = lv_month_y.
  lo_nd_cale_data->bind_structure( new_item = ls_cale_data ).
* Setting the Legend Context Node
  DATA lo_nd_calelegend  TYPE REF TO if_wd_context_node.
  DATA: BEGIN OF ls_calelegend,
          legendid    TYPE ptreq_uia_legend_struc-legendid,
          category    TYPE wdui_table_cell_design,
          legendtext  TYPE string,
        END OF ls_calelegend.
  DATA: lt_calelegend LIKE TABLE OF ls_calelegend,
        lv_legendid TYPE string.
  LOOP AT lt_legend INTO ls_legend.
    ls_calelegend-legendid   = ls_legend-legendid.
    ls_calelegend-legendtext = ls_legend-text.
    lv_legendid = ls_legend-legendid.
    ls_calelegend-category   = wd_this->conv_table_cell_design( iv_legendid = lv_legendid ).
    APPEND ls_calelegend TO lt_calelegend.
  ENDLOOP.
*  Append the legends for Non-Working days and Public Holidays:
  ls_calelegend-legendid   = 'CALENDARMETAL'.
  ls_calelegend-legendtext = cl_wd_utilities=>get_otr_text_by_alias( alias = 'PAOC_ESS_WDA_OTR/NON_WORKDAY' ).
  ls_calelegend-category   = '20'.
  APPEND ls_calelegend TO lt_calelegend.
  CLEAR ls_calelegend.
  ls_calelegend-legendid   = 'TWO'.
  ls_calelegend-legendtext = cl_wd_utilities=>get_otr_text_by_alias( alias = 'PAOC_ESS_WDA_OTR/PUBLIC_HOLIDAY' ).
  ls_calelegend-category   = '17'.
  APPEND ls_calelegend TO lt_calelegend.
  lo_nd_calelegend = wd_context->get_child_node( name = 'LEGEND' ).
  CALL METHOD lo_nd_calelegend->bind_table
    EXPORTING
      new_items = lt_calelegend.
endmethod.
Regards,
Jyothi