Collections as function/procedure parameters

Question

Dear Oracle Gurus,
In Oracle documentation i have read that we can use a collection
as a parameter in a function or procedure.
I created a packaged procedure called collection_test with
single parameter whose type is nested table.
Bu when i call that packaged procedure from another stand alone procedure
it is giving error.
I ahve given the scripts below.
create or replace package test as
type emp_names is table of emp.ename%type;
procedure collection_test(names in emp_names) ;
end;
create or replace package body test
as
procedure collection_test(names in emp_names)
as
begin
for i in names.first.. names.last
loop
dbms_output.put_line('employee name'||names(i));
end loop;
end;
end test;
create or replace procedure test_proc
as
type emp_names is table of varchar2(10);
enames emp_names;
begin
select ename bulk collect into enames from emp;
test.collection_test(enames);
end test_proc;
8/2 PLS-00306: wrong number or types of arguments in call to
'COLLECTION_TEST'
any suggestions r most welcome
regads
RR

Answer 1

SQL> create or replace package test as
  2  type emp_names is table of emp.ename%type;
  3  procedure collection_test(names in emp_names) ;
  4  end;
  5  /
Package created.
SQL> create or replace package body test
  2  as
  3  procedure collection_test(names in emp_names)
  4  as
  5  begin
  6  for i in names.first.. names.last
  7  loop
  8  dbms_output.put_line('employee name'||names(i));
  9  end loop;
10  end;
11  end test;
12  /
Package body created.
SQL> create or replace procedure test_proc
  2  as
  3  enames test.emp_names; -- Changed the declaration of enames
  4  begin
  5  select ename bulk collect into enames from emp;
  6  test.collection_test(enames);
  7  end test_proc;
  8  /
Procedure created.
SQL> set serveroutput on
SQL> exec test_proc
employee nameSMITH
employee nameALLEN
employee nameWARD
employee nameJONES
employee nameMARTIN
employee nameBLAKE
employee nameCLARK
employee nameSCOTT
employee nameKING
employee nameTURNER
employee nameADAMS
employee nameJAMES
employee nameFORD
employee nameMILLER
PL/SQL procedure successfully completed.
SQL>