Is It Possible To define a size of the Procedure Parametere?

Question

In Oracle Is It Possible To define a size of the Procedure Parametere?
If i have the procedure like
Test_sp(no int,name varchar2)
Is it possible to define a size
Test_sp(no int(5),name varchar2(255))
Thanks
Rangan S

Answer 1

As Anthony said - no, not in the parameter signature of a procedure or a function. Which could have unexpected run-time errors as one could wrongly assume that using a "derived" type will allow this.
The following example illustrates:
SQL> create table datatype(
2 varchar2_5 varchar2(5),
3 number1 number(1)
4 );
Table created.
SQL>
SQL>
SQL> create or replace procedure fooProc( s datatype.varchar2_5%TYPE, n datatype.number1%TYPE ) is
2 s1 datatype.varchar2_5%TYPE;
3 n1 datatype.number1%TYPE;
4 begin
5 begin
6 DBMS_OUTPUT.put_line( 'len='||length(s)||' value='||s );
7 DBMS_OUTPUT.put_line( 'value='||to_char(n) );
8 exception when OTHERS then
9 DBMS_OUTPUT.put_line( 'parameter display failed with error '||SQLERRM(SQLCODE) );
10 end;
11
12 begin
13 s1 := s;
14 DBMS_OUTPUT.put_line( 'string parameter assignment succeeded' );
15 exception when OTHERS then
16 DBMS_OUTPUT.put_line( 'string assignment failed with error '||SQLERRM(SQLCODE) );
17 end;
18
19 begin
20 n1 := n;
21 DBMS_OUTPUT.put_line( 'number parameter assignment succeeded' );
22 exception when OTHERS then
23 DBMS_OUTPUT.put_line( 'number assighment failed with error '||SQLERRM(SQLCODE) );
24 end;
25 end;
26 /
Procedure created.
SQL>
SQL> exec fooProc( 'test1', 1 );
len=5 value=test1
value=1
string parameter assignment succeeded
number parameter assignment succeeded
PL/SQL procedure successfully completed.
SQL>
SQL> exec fooProc( 'this should fail', 1 );
len=16 value=this should fail
value=1
string assignment failed with error ORA-06502: PL/SQL: numeric or value error: character string buffer too small
number parameter assignment succeeded
PL/SQL procedure successfully completed.
SQL>
SQL> exec fooProc( 'test', 1234 );
len=4 value=test
value=1234
string parameter assignment succeeded
number parameter assignment succeeded
PL/SQL procedure successfully completed.
SQL>
Note that only the string assignment fails. The string parameter works fine. And there is no impact at all on the number side, despite seemingly constraining it to a single digit.