Converting Word Templates from 2003 to 2013 Version

Question

Hello.  I work at a school environment and most of our secretaries had been running Office 2003.  They have a lot of Word templates.  Recently, as we have decided to upgrade Office to 2013, we have the problem of hundreds of old templates
that need to be converted over to the 2013 version.
Is there a quick and efficient way to do this?  Instead of manual converting each file, one by one.
Thanks in advance!

Answer 1

In addition to the answer of Edward I would add the following line of code:
Sub Convert2003To2013()
' Convert2003To2013 Macro
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document
strFolder = "D:\Sample\OfficeDev\Word\OldFolder"
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
If InStrRev(strFile, ".docx") = 0 Then
Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, _
AddToRecentFiles:=False, Visible:=False)
wdDoc.Convert
wdDoc.SaveAs2 FileName:=strFolder & "\" & Left(strFile, InStrRev(strFile, ".doc")) & "docx", _
Fileformat:=wdFormatXMLDocument, AddToRecentFiles:=False
wdDoc.Close SaveChanges:=False
End If
strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub
I added the wdDoc.Convert because otherwise you are not explicitly converting documents but only renaming them to .docx
The additional functionality of Office 2013 comes available when the document is actually converted. You can test this by opening the document after het has been really converted, you should be able to see the SmartArt options. If you only rename them to
.docx you will see that the 'new' smart art functionality is not available.
Doesn't mean that the provided code block by Edward doesn't work, it does a great job. My advice would be to add the convert line if you really want 'converted' files.
Last thing you have to think about is these code snippets use SaveAs2, that means that you will get two instances of your document. If you choose convert you are actually converting the original document. In that case you do not choose SaveAs2
but you use Save.
Maurice
When you see answers and helpful posts, please click Vote As Helpful, Propose As Answer, and/or Mark As Answer. Thank You