Create a Playlist from external folder with tracks already existing in iTunes

Question

I was just wondering if its possible to create a playlist from an external folder (on my desktop) with tracks that already exist in iTunes.
I basically have a folder on my desktop that i use with Serato, i was wondering if it'd be possible to sort a playlist in iTunes with the tracklist from the folder? I already have all the tracks on iTunes so i don't want to add them onto iTunes again just to put them into a playlist as i'd have to sort through all the duplicates to delete the non playlisted tracks (theres around 1500 so it wouldn't be a quick task).
Would be much appreciated if anybody can help!

Answer 1

Hi,
I have an AppleScript that does this.
This script need Spotlight metadata, all files in the folder that you use with Serato should be indexed.
Works well if the tags (name and artist) are defined
In this script :
it will display a dialog to select your folder
iTunes search track from the library playlist according to (artist, album and title in the Spotlight metadata of each file).
If iTunes found a track, iTunes will add this track to the new playlist.
The script takes 35 seconds for 1000 files on an old machine (PowerMac G5 2 X 1.8 GHz) .
This should take less than 100 seconds for 3500 files on the new machine
Here is the script :
-- this script need Spotlight metadata, files in the folder should be indexed
set folderPath to (choose folder with prompt "Select the  folder that you use with Serato")
set f to quoted form of POSIX path of folderPath
my makePlaylist(do shell script "/usr/bin/find " & f & " -type f \\! -name '.*' -print0 | /usr/bin/xargs -0 /usr/bin/mdls -name kMDItemTitle -name kMDItemAlbum -name kMDItemAuthors | /usr/bin/sed 'H;$!d;x;s/\\n[^k]//g'")
on makePlaylist(t)
      script o
            property L : paragraphs of t
      end script
      set tc to (count o's L)
      tell application "iTunes"
            set newPlaylist to make new playlist with properties {name:"Serato"}
            set masterLibr to (get first playlist whose special kind is Music)
      end tell
      repeat with i from 2 to tc by 3
            set {tAlbum, tArtist, tTitle} to my getvalue(items i thru (i + 2) of o's L)
            tell application "iTunes" to try
                  set t to (get first track of masterLibr whose name is tTitle and artist is tArtist and album is tAlbum)
                  duplicate t to newPlaylist -- add founded track from the library playlist to the  new playlist
            end try
      end repeat
end makePlaylist
on getvalue(tList)
      set oTID to text item delimiters
      set text item delimiters to "\""
      set {alb, aut, title} to {"", "", ""}
      try
            repeat with i in tList -- if line does not contains a double quote then the tag is  empty -->  = (null)
                  if i starts with "kMDItemAlbum" then
                        tell i to if it contains "\"" then set alb to text item 2
                  else if i starts with "kMDItemAuthors" then
                        set text item delimiters to "(   "
                        -- if artist contains one word, it doesn't contains double quote
                        tell i to if it does not contain "(null)" then
                              if last text item starts with "\"" then
                                    set aut to text 2 thru -2 of (last text item)
                              else
                                    set aut to (last text item)
                              end if
                        end if
                        set text item delimiters to "\""
                  else --kMDItemTitle
                        tell i to if it contains "\"" then set title to text item 2
                  end if
            end repeat
      end try
      set text item delimiters to oTID
      return {alb, aut, title}
end getvalue