Creating users and adding them to groups programmatically in Portal 902

Question

What is the correct process and code needed to create a user and add it to a group programmatically in Portal 9.0.2 and how is it different from what it used to be in 309.
If anyone has an answer, please let me know and all contributions are really appreciated.
Thanks

Answer 1

You can use these procedures.
procedure Create_User(first_name IN VARCHAR2
,last_name IN VARCHAR2
,password IN VARCHAR2
,email IN VARCHAR2
,employeenumber IN VARCHAR2
,description IN VARCHAR2
is
retval PLS_INTEGER;
emp_session DBMS_LDAP.session;
emp_dn VARCHAR2(256);
emp_rdn VARCHAR2(256);
emp_array DBMS_LDAP.MOD_ARRAY;
emp_vals DBMS_LDAP.STRING_COLLECTION ;
ldap_host VARCHAR2(256);
ldap_port VARCHAR2(256);
ldap_user VARCHAR2(256);
ldap_passwd VARCHAR2(256);
ldap_base VARCHAR2(256);
BEGIN
retval := -1;
ldap_host := '<you_host>';
ldap_port := '4032';
ldap_user := 'cn=orcladmin';
ldap_passwd:= '<orcladmin_password>';
ldap_base := 'cn=users,dc=<your_compani_name>,dc=com';
DBMS_LDAP.USE_EXCEPTION := TRUE;
emp_session := DBMS_LDAP.init(ldap_host, ldap_port);
-- Bind to the directory
retval := DBMS_LDAP.simple_bind_s(emp_session,ldap_user, ldap_passwd);
emp_array := DBMS_LDAP.create_mod_array(14);
emp_vals(1) := first_name;
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'cn',emp_vals);
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'givenname',emp_vals);
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'uid',emp_vals);
emp_vals(1) := last_name;
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'sn',emp_vals);
emp_vals(1) := employeenumber;
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'employeenumber',emp_vals);
emp_vals(1) := description;
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'description',emp_vals);
emp_vals(1) := 'top';
emp_vals(2) := 'person';
emp_vals(3) := 'organizationalPerson';
emp_vals(4) := 'inetOrgPerson';
emp_vals(5) := 'orcluser';
emp_vals(6) := 'orcluserv2';
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'objectclass',emp_vals);
emp_vals.DELETE;
emp_vals(1) := email;
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'mail',emp_vals);
emp_vals(1) := password;
DBMS_LDAP.populate_mod_array(emp_array,DBMS_LDAP.MOD_ADD,'userPassword',emp_vals);
emp_dn := 'cn=' || first_name || ',' || ldap_base ;
retval := DBMS_LDAP.add_s(emp_session,emp_dn,emp_array);
DBMS_LDAP.free_mod_array(emp_array);
retval := DBMS_LDAP.unbind_s(emp_session);
-- Handle Exceptions
EXCEPTION
WHEN OTHERS THEN
DBMS_OUTPUT.PUT_LINE(' Error code : ' || TO_CHAR(SQLCODE));
DBMS_OUTPUT.PUT_LINE(' Error Message : ' || SQLERRM);
DBMS_OUTPUT.PUT_LINE(' Exception encountered .. exiting');
end Create_User;
create or replace
procedure Add_User_To_Group(user_name IN VARCHAR2
,group_name IN VARCHAR2
is
retval PLS_INTEGER;
ldap_host VARCHAR2(256);
ldap_port VARCHAR2(256);
ldap_user VARCHAR2(256);
ldap_passwd VARCHAR2(256);
ldap_base VARCHAR2(256);
my_session DBMS_LDAP.session;
my_message DBMS_LDAP.message;
my_entry DBMS_LDAP.message;
my_array DBMS_LDAP.MOD_ARRAY;
my_vals DBMS_LDAP.STRING_COLLECTION ;
group_dn VARCHAR2(256);
user_dn VARCHAR2(256);
BEGIN
retval := -1;
ldap_host := '<you_host>';
ldap_port := '4032';
ldap_user := 'cn=orcladmin';
ldap_passwd:= '<orcladmin_password>';
ldap_base := 'cn=users,dc=<your_compani_name>,dc=com';
DBMS_LDAP.USE_EXCEPTION := TRUE;
my_session := DBMS_LDAP.init(ldap_host, ldap_port);
-- Bind to the directory
retval := DBMS_LDAP.simple_bind_s(my_session,ldap_user, ldap_passwd);
--Find the user
my_vals(1) := '1.1';
retval := DBMS_LDAP.search_s(my_session,
ldap_base,
DBMS_LDAP.SCOPE_SUBTREE,
'(&(objectClass=person)(cn=' || user_name || '))',
my_vals,
0,
my_message);
my_entry := DBMS_LDAP.first_entry(my_session, my_message);
IF my_entry IS NOT NULL THEN
user_dn := DBMS_LDAP.get_dn(my_session, my_entry);
retval := DBMS_LDAP.search_s(my_session,
ldap_base,
DBMS_LDAP.SCOPE_SUBTREE,
'(&(objectClass=orclGroup)(cn=' || group_name ||'))',
my_vals,
0,
my_message);
my_entry := DBMS_LDAP.first_entry(my_session, my_message);
IF my_entry IS NOT NULL THEN
group_dn := DBMS_LDAP.get_dn(my_session, my_entry);
my_array := DBMS_LDAP.create_mod_array(1);
my_vals(1) := user_dn;
DBMS_LDAP.populate_mod_array(my_array, DBMS_LDAP.MOD_ADD, 'uniqueMember', my_vals);
retval := DBMS_LDAP.modify_s(my_session, group_dn, my_array);
DBMS_OUTPUT.PUT_LINE(RPAD('modify_s Returns ',25,' ') || ': '|| TO_CHAR(retval));
DBMS_LDAP.free_mod_array(my_array);
END IF;
END IF;
my_vals.DELETE;
retval := DBMS_LDAP.unbind_s(my_session);
-- Handle Exceptions
EXCEPTION
WHEN OTHERS THEN
DBMS_OUTPUT.PUT_LINE(' Error code : ' || TO_CHAR(SQLCODE));
DBMS_OUTPUT.PUT_LINE(' Error Message : ' || SQLERRM);
DBMS_OUTPUT.PUT_LINE(' Exception encountered .. exiting');
end Add_User_To_Group;