CROSS TABLE in APEX

Question

Hello!
I have to develop student attendance application in Oracle APEX.
I have 2 databases. First contain personal info of all the students and class ID (of each of them).
Second contains column for student_ID from first table (which is foreign key), the date and the comment, when combination of student_ID and date is set as unique, so no one can be attended at lecture twice a day.
(Of course both tables have their own ID primary key).
For example:
first table
ID | Name | Address | Class ID
1 | Alex | USA | Group A
2 | John | Canada | Group A
3 | Peter | France | Group B
second table
ID | first_table_ID | date | comment
1 | 1 | 1-aug-09 | attended
2 | 2 | 1-aug-09 | skipped
3 | 3 | 1-aug-09 | lateness
4 | 1 | 3-aug-09 | attended
5 | 2 | 3-aug-09 | attended
6 | 3 | 3-aug-09 | attended
So, what I need, is build report table for each of classes, i.e. lecturers choose the class (from list of values for example), and see table like this (for class A, in this case):
***** | 1-aug-09 | 3-aug-09
Alex | attended | attended
John | skipped | attended
How can I do it?
I experimented with PIVOT command and other stuff, but every time i get different errors in query builder.
Do I need build some data view or some new table from existing ones?
What will be query commands?
THANKS.
Edited by: mindhunter on Aug 9, 2009 4:32 AM
Edited by: mindhunter on Aug 9, 2009 4:34 AM

Answer 1

Hi Mindhunter - and, welcome!
I actually found the new PIVOT functionality annoying - as (A) you have to hardcode the column headings and (B) you have to use an aggregate function to populate the columns.
However, it is possible to handle this by using a "SQL Query (PL/SQL function body returning SQL query)" report. In this way, you can build up a SQL query as a string and then get Apex to run it for you.
To create this type of report, create a normal SQL Query report using SELECT 1 FROM DUAL. When the report has been created, edit it and change the type from "SQL Query" to "SQL Query (PL/SQL function body returning SQL query)".
Then, in the Region Source, you can enter in the PL/SQL that you need to construct the SQL statement. Here is an example using the DEPT and EMP tables:
DECLARE
vSQL VARCHAR2(1000);
vDEPT VARCHAR2(1000);
vSEP VARCHAR2(2);
BEGIN
vDEPT := '';
vSEP := '';
FOR d IN (SELECT DEPTNO, DNAME FROM DEPT ORDER BY DNAME)
LOOP
  vDEPT := vDEPT || vSEP || d.DEPTNO || ' as "' || d.DNAME || '"';
  vSEP := ', ';
END LOOP;
vSQL := 'SELECT * FROM (SELECT ENAME, ENAME ENAME2, DEPTNO FROM EMP) PIVOT (MIN(ENAME2) FOR DEPTNO IN (' || vDEPT || '))';
RETURN vSQL;
END;In this example, I have to loop through all the departments on the DEPT table and make a list of the DEPTNO and DNAME values. The DEPTNO value is the one also used on the EMP table, and the DNAME value is the one that I want as column headings. When the PIVOT is being performed, the DEPTNO values are the ones that are used to determine what appears in each column. Also note that I've had to duplicate the ENAME column (giving the second instance of this a column alias of ENAME2) - I need to do this to get the ENAME value as the first column of the report and the ENAME2 value as an entry in the appropriate column.
Once I had done this, I selected the "Use Generic Column Names (parse query at runtime only)" underneath the Region Source so that I don't have to specify the column names to Apex. It also allows the first ENAME value to appear as the first column in the first. If I ticked the "Use Query-Specific Column Names and Validate Query" option, for some reason, the ENAME column appears last.
OK, that's an example using data that most users here would have. Now for your data. This is actually more complicate as you are using dates as these have to be sorted in order AND converted into strings (for the headings).
Firstly, I would recommend that you create a view over the two tables (if you haven't already done so). Something like:
CREATE OR REPLACE FORCE VIEW STUDENT_ATTENDANCE
  STUDENT_ID,
  STUDENT_NAME,
  CLASS_DATE,
  CLASS_COMMENT
AS
SELECT
  S.ID STUDENT_ID,
  S.NAME STUDENT_NAME,
  C.DATE CLASS_DATE,
  C.COMMENT CLASS_COMMENT
FROM
  STUDENTS S
  INNER JOIN COMMENTS C ON S.ID = C.STUDENT_IDNow we can create a PL/SQL code:
DECLARE
vSQL VARCHAR2(1000);
vDATES VARCHAR2(1000);
vSEP VARCHAR2(2);
BEGIN
vDATES := '';
vSEP := '';
FOR d IN (SELECT DISTINCT TO_CHAR(CLASS_DATE,'YYYYMMDD') DATEVALUE, TO_CHAR(CLASS_DATE,'DD-MON-YY') HEADING, CLASS_DATE FROM STUDENT_ATTENDANCE WHERE CLASS_DATE IS NOT NULL ORDER BY CLASS_DATE)
LOOP
  vDATES := vDATES || vSEP || d.DATEVALUE || ' AS "' || d.HEADING || '"';
  vSEP := ', ';
END LOOP;
vSQL := 'SELECT * FROM (SELECT STUDENT_NAME, CLASS_COMMENT, TO_CHAR(CLASS_DATE,''YYYYMMDD'') DATEVALUE FROM STUDENT_ATTENDANCE WHERE CLASS_DATE IS NOT NULL) PIVOT (MIN(CLASS_COMMENT) FOR DATEVALUE IN (' || vDATES || '))';
RETURN vSQL;
END;You will see that I have two versions of the dates - one in YYYYMMDD format and one in DD-MON-YY. The first is to allow me to create a number that can be used to identify the column (this is easier that trying to compare dates) and the second is for the column heading. As we have to use an aggregate function in the PIVOT, I've just used MIN(CLASS_COMMENT) - assuming that the student can only attend (or not!) one class per date, then this should be ok as this could only return one value.
As I do not have your tables and data, I have created a sample page with a similar statement for the HIREDATE values on the EMP table: [http://apex.oracle.com/pls/otn/f?p=267:138]
The PL/SQL for the top report is my example above. The PL/SQL for the bottom report is:
DECLARE
vSQL VARCHAR2(1000);
vDATES VARCHAR2(1000);
vSEP VARCHAR2(2);
BEGIN
vDATES := '';
vSEP := '';
FOR d IN (SELECT DISTINCT TO_CHAR(HIREDATE,'YYYYMMDD') DATEVALUE, TO_CHAR(HIREDATE,'DD/MM/YYYY') HEADING, HIREDATE FROM EMP WHERE HIREDATE IS NOT NULL ORDER BY HIREDATE)
LOOP
  vDATES := vDATES || vSEP || d.DATEVALUE || ' AS "' || d.HEADING || '"';
  vSEP := ', ';
END LOOP;
vSQL := 'SELECT * FROM (SELECT ENAME, ENAME ENAME2, TO_CHAR(HIREDATE,''YYYYMMDD'') DATEVALUE FROM EMP WHERE HIREDATE IS NOT NULL) PIVOT (MIN(ENAME2) FOR DATEVALUE IN (' || vDATES || '))';
RETURN vSQL;
END;Andy