Date, File name, User Stamp

Question

I've looked for hours for a script that will work in Illustrator CS4 that will put a text block on the page identifying:
Date, File Name and the User's name on the document (art board)
I am not versed in scripting. Can anyone help me out?

Answer 1

Hi Y'all  This post is where scripting all started for me. At the time I didn't know anything and Muppet Mark kindly helped me out. Since then I have learned Applescript and written my slug script in that. This has the advantage of being able to access system information. Here it is:
-- captures the user's first name from the system for use in dialog boxes
set myName to (long user name of (system info))
set sp to (offset of " " in myName)
set myFirstName to text 1 thru (sp - 1) of myName
-- captures the user's short name from the system for use in the slug
set myShortName to (short user name of (system info))
set myInitials to text 1 thru 2 of myShortName
tell application "Adobe Illustrator" to set myDocCount to count of documents
if myDocCount > 0 then
    tell application "Adobe Illustrator"
        try
            set myPath to file path of document 1 as alias -- if the document is not saved this will cause an error
        on error
            display dialog "You haven't saved document yet " & myFirstName & "." buttons {"Cancel", "Save"} default button 2
            -- brings up Save As dialog box
            tell application "System Events" to tell process "Adobe Illustrator"
                click menu item "Save As..." of menu 1 of menu bar item "File" of menu bar 1
                tell application "Finder"
                    set filesavepath to "/Volumes/Server/Folder" -- put your own file path in here
                end tell
                delay 0.2
                tell window "Save As"
                    keystroke "g" using {command down, shift down}
                    repeat until exists sheet 1
                        delay 0.5
                    end repeat
                    tell sheet 1
                        keystroke filesavepath
                        click button "Go"
                    end tell
                end tell
            end tell
            -- end Save As dialog box
            return
        end try
        set myFile to name of document 1
        set myFolder to myPath as string
        -- this section looks at the file info to get the file version information
        set myFileVersion to my getVersion(myPath)
        set AppleScript's text item delimiters to "Created"
        set myFileVersion to text item 1 of myFileVersion
        if myFileVersion is "Saved As v.15 " then
            set myFileVersion to "Illustrator CS5"
        else if myFileVersion is "Saved As v.14 " then
            set myFileVersion to "Illustrator CS4"
        else if myFileVersion is "Saved As v.13 " then
            set myFileVersion to "Illustrator CS3"
        else if myFileVersion is "Saved As v.12 " then
            set myFileVersion to "Illustrator CS2"
        end if
        set AppleScript's text item delimiters to {""}
        -- end of file info
        set AppleScript's text item delimiters to ":"
        set clientFolder to text item 3 of myFolder -- always picks out the client folder on our server
        set AppleScript's text item delimiters to {""}
        if clientFolder contains "_" then
            set clientFolder to my cleanName(clientFolder) -- to format the client names properly
        else
            set clientFolder to clientFolder
        end if
        -- find the current date. This is the date when the file was last edited but this method enables you to run the script before saving
        tell application "Finder"
            set myDate to (current date) as string
        end tell
        set myDate to (word 2 of myDate) & " " & (text 1 thru 3 of word 3 of myDate) & " " & (word 4 of myDate) as string
        -- end find date
        -- checks for the correctly named frames and then populates with the correct information
        if exists (text frame "titleblock-software" of document 1) then
            set contents of text frame "titleblock-software" of document 1 to myFileVersion
        end if
        if exists (text frame "titleblock-client" of document 1) then
            set contents of text frame "titleblock-client" of document 1 to clientFolder
        end if
        if exists (text frame "titleblock-file" of document 1) then
            set contents of text frame "titleblock-file" of document 1 to myFile
        end if
        if exists (text frame "titleblock-path" of document 1) then
            set contents of text frame "titleblock-path" of document 1 to myPath as string
        end if
        if exists (text frame "titleblock-date" of document 1) then
            set contents of text frame "titleblock-date" of document 1 to myDate
        end if
        if exists (text frame "titleblock-editor" of document 1) then
            set contents of text frame "titleblock-editor" of document 1 to myInitials
        end if
        if exists (text frame "titleblock-version" of document 1) then
            set versionCount to get contents of text frame "titleblock-version" of document 1
            set versionCount to (versionCount + 1)
            set contents of text frame "titleblock-version" of document 1 to versionCount
        end if
        -- end populating named frames
    end tell
end if
-- this handler is to get the version of the file
on getVersion(added_item)
    set myFileVersion to long version of (info for added_item)
end getVersion
-- this handler converts every 'odd' character to an underscore, modify as needed
on cleanName(newName)
    set chars to every character of newName
    repeat with i from 1 to length of chars
        if item i of chars as text is equal to "_" then
            set item i of chars to " "
        end if
    end repeat
    return every item of chars as string
end cleanName