Deactivating/Activating Data Slice Function

Question

Hi, I'd also like a copy of the document of how to implement a Function to Activate or Deactivate a Data Slice.
Reward points guaranteed.

Answer 1

Hello Jesus,
Here is the Report Code.
<i>This code was written as Programm without involving the BPS planning functions, because it was meant to be included in the Process chains.
When you wish flexibility, for example to operate it in the Web using planning functions then, then you have to :</i>
<i>1) create a planing function of type exit.
2.a) You would then move the code in the "Init exit function". Fill the code mentioned below with necessary changes.
2.b) The second exit function would be then an empty function module.
3) In the Web Interface Builder you would create a Button component of type "Function Button" and set the properties to the planning function you created in steps 1-2.</i>
Thanks and Good Luck!
P.S.
When you require the screenshots, then let me know your mail id.
** Start of Code ***
DATA : ls_slice TYPE UPC_Y_DATASLICETXT.
DATA : lt_areas TYPE UPC_YTO_AREA_KEY,
       ls_areas TYPE UPC_YS_AREA_KEY,
       ls_type  TYPE UPC_Y_AREA_TYPE,
       ls_area  TYPE UPC_Y_AREA,
       ls_dataslice LIKE UPC_DATASLICE,
       lt_dataslice TYPE STANDARD TABLE OF UPC_DATASLICE,
       ls_action TYPE C.
**************** Selektionsbildschrim ***************************
SELECTION-SCREEN  BEGIN OF BLOCK basics WITH FRAME TITLE TEXT-004.
PARAMETERS:
      I_MANDT     TYPE     MANDT         DEFAULT SY-MANDT,
      I_LANGU     TYPE     LANGU         DEFAULT SY-LANGU,
      I_AREA     TYPE     UPC_Y_AREA OBLIGATORY.
SELECTION-SCREEN END   OF BLOCK basics.
SELECTION-SCREEN  BEGIN OF BLOCK slices WITH FRAME TITLE  TEXT-005.
  SELECT-OPTIONS IS_SLICE FOR ls_slice NO INTERVALS.
SELECTION-SCREEN END   OF BLOCK slices.
SELECTION-SCREEN BEGIN OF BLOCK action WITH FRAME TITLE TEXT-003.
PARAMETERS:
      I_ACTV RADIOBUTTON GROUP RAD1,
      I_DACT RADIOBUTTON GROUP RAD1 DEFAULT 'X'.
SELECTION-SCREEN END   OF BLOCK action.
SELECTION-SCREEN :
    BEGIN OF SCREEN 100 TITLE TEXT-001 AS WINDOW,
      INCLUDE BLOCKS basics,
      INCLUDE BLOCKS slices,
      INCLUDE BLOCKS action,
    END   OF SCREEN 100.
*****************  Ende *******************************************
START-OF-SELECTION.
  ls_area = I_AREA.
  CALL FUNCTION 'UPC_AREA_GET'
    EXPORTING
     I_AREA             = I_AREA
     I_ENQMODE          = 'E'
     I_LANGU            = I_LANGU
   IMPORTING
     E_TYPE             = ls_type
     ETO_AREAM          = lt_areas.
  IF SY-SUBRC NE 0.
*    RAISE EX_AREA_INVALID.
  ENDIF.
  IF LS_TYPE EQ 'M'.
    READ TABLE lt_areas INTO ls_areas index 1.
    IF ls_areas IS NOT INITIAL.
      ls_area = ls_areas-area.
    ELSE.
*      RAISE EX_AREA_INVALID.
    ENDIF.
  ENDIF.
  IF I_DACT EQ 'X'.
    ls_action = 'X'.
  ENDIF.
  LOOP AT IS_SLICE
       WHERE ( SIGN = 'I'
           AND OPTION = 'EQ' ).
    SELECT d~mandt d~area d~sort d~guid d~inactive
           INTO ls_dataslice
           FROM ( UPC_DATASLICE  AS d  INNER JOIN
                  UPC_DATASLICET AS t
                  ON  d~mandt = t~mandt
                  AND d~area  = t~area
                  AND d~sort  = t~sort
                  AND t~langu = I_LANGU
                  AND t~text  = IS_SLICE-LOW ).
      ls_dataslice-INACTIVE = ls_action.
      INSERT ls_dataslice INTO TABLE lt_dataslice.
    ENDSELECT.
  ENDLOOP.
  LOOP AT lt_dataslice INTO ls_dataslice.
    UPDATE UPC_DATASLICE FROM ls_dataslice.
  ENDLOOP.
*** End of code ***
Now use the function, Jump->Text symbols and enter these
Text defintions:
<b>1) Text Symbols:</b>
   001 - Activation/Deactivation of Planning Areas
   002 - Choose Action
   003 - Planning area details
   004 - Data Slice Details
<b>2) Selection Texts:</b>
   IS_SLICE - Data Slices
   I_ACTV - Activate
   I_AREA - Planning Area
   I_DACT - Deactivate
   I_LANGU - Language
   I_MANDT - Client