Debugging PL/SQL

Question

I am using Toad for Oracle. Is there any way within PL/SQL code to define a section or block of code as code that should only run when you are debugging PL/SQL procedures/functions?

Answer 1

I think the OP wants something more like this (tested in 11g, should work from 10.2 onwards if I remember correctly):
Connected to:
Oracle Database 11g Enterprise Edition Release 11.1.0.6.0 - Production
With the Partitioning, OLAP, Data Mining and Real Application Testing options
SQL> create or replace procedure procedurewithdebug
  2  as
  3  begin
  4      dbms_output.put_line('Start of procedure');
  5
  6      $if $$debug $then
  7          dbms_output.put_line('Extra code section only called when $$debug is TRUE');
  8      $end
  9
10      dbms_output.put_line('End of procedure');
11  end procedurewithdebug;
12  /
Procedure created.
SQL> set serverout on
SQL> exec procedurewithdebug
Start of procedure
End of procedure
PL/SQL procedure successfully completed.
SQL> call dbms_preprocessor.print_post_processed_source('PROCEDURE','WILLIAM','PROCEDUREWITHDEBUG');
procedure procedurewithdebug
as
begin
dbms_output.put_line('Start of procedure');
dbms_output.put_line('End of procedure');
end procedurewithdebug;
Call completed.
SQL> alter session set plsql_ccflags = 'debug:true';
Session altered.
SQL> alter procedure procedurewithdebug compile;
Procedure altered.
SQL> exec procedurewithdebug
Start of procedure
Extra code section only called when $$debug is TRUE
End of procedure
PL/SQL procedure successfully completed.
SQL> call dbms_preprocessor.print_post_processed_source('PROCEDURE','WILLIAM','PROCEDUREWITHDEBUG');
procedure procedurewithdebug
as
begin
dbms_output.put_line('Start of procedure');
dbms_output.put_line('Extra code section only called when $$debug is TRUE');
dbms_output.put_line('End of procedure');
end procedurewithdebug;
Call completed.
SQL> alter session set plsql_ccflags = 'debug:false';
Session altered.
SQL>
SQL> alter procedure procedurewithdebug compile;
Procedure altered.
SQL> exec procedurewithdebug
Start of procedure
End of procedure
PL/SQL procedure successfully completed.Note this does not automatically detect whether a procedure is compiled for debug - you have to set a compilation directive explicitly. (There is nothing special about '$$debug' either - I could have used '$$banana'.)
As a variation, you can also use package constants:
SQL> create or replace package environment_settings
  2  as
  3      debug constant boolean := TRUE;
  4  end environment_settings;
  5  /
Package created.
SQL> create or replace procedure procedurewithdebug
  2  as
  3  begin
  4      dbms_output.put_line('Start of procedure');
  5
  6      $if environment_settings.debug $then
  7          dbms_output.put_line('Extra code section only called when environment_settings.debug is TRUE');
  8      $end
  9
10      dbms_output.put_line('End of procedure');
11  end procedurewithdebug;
12  /
Procedure created.
SQL> exec procedurewithdebug
Start of procedure
Extra code section only called when environment_settings.debug is TRUE
End of procedure
PL/SQL procedure successfully completed.
SQL> create or replace package environment_settings
  2  as
  3      debug constant boolean := FALSE;
  4  end environment_settings;
  5  /
Package created.
SQL> exec procedurewithdebug
Start of procedure
End of procedure
PL/SQL procedure successfully completed.Note that PL/SQL isn't just skipping the line like an ordinary IF statement, the PL/SQL compiler is actually excluding the section at compile time:
SQL> call dbms_preprocessor.print_post_processed_source('PROCEDURE','WILLIAM','PROCEDUREWITHDEBUG');
procedure procedurewithdebug
as
begin
dbms_output.put_line('Start of procedure');
dbms_output.put_line('End of procedure');
end procedurewithdebug;
Call completed.Edited by: William Robertson on Mar 26, 2009 7:18 AM