Delta extraction for a generic datasource

Question

Hi BWers,
I want put in Delta the extraction of a generic datasource.
Currently this generic datasource is based on the table VBPA (Sales Document: Partner). Any time field exists.
We need a time field in order to converse to a Delta extraction. This time field exists in the table VBAP (Sales Document: Item data). In fact two time fields exist: one which is filled at the creation of the sales order (ERDAT), another at the change of the sales order (AEDAT).
The fields VBELN, POSNR and MANDT are keys in the tables VBAP and VBPA.
The table VBAP changes when partner functions is created or changed in a sales order (VBELN) :
- When it is a creation of a new sales order (with new partner functions), a new record is created in VBAP and the field ERDAT (Created on) is filled. The field AEDAT (Changed on) is empty.
- When is a change of an existing sales order, the corresponding record in VBAP changed, and the field AEDAT is filled. ERDAT stays unchanged.
In order to converse to the Delta extraction, i need a only one time-field (calendar day) in RSO2 / Generic Delta.
But there is 2 time-fields ERDAT and AEDAT. So i just need to get AEDAT if it is filled, else if AEDAT is empty I will get ERDAT.
I would base my datasource on a view between VBPA and VBAP with one field which will be filled by AEDAT or ERDAT (with the conditions below). But it seems it is not possible.
Can you give me other ideas ?
Thanks a lot.
Cheers,
Vince.

Answer 1

In order to create a generic delta from two source fields, ERDAT and AEDAT in this case, you're going to have to create your generic extractor from a Function Module. Otherwise you'll only have the standard functionality available to you for creating the generic delta, which allows you to base it on only one column.
Here's a sample you can use, that was created for VBFA, and change for your DataSource.
FUNCTION y_docu_flow.
*"*"Local interface:
*"  IMPORTING
*"     VALUE(I_REQUNR) TYPE  SRSC_S_IF_SIMPLE-REQUNR
*"     VALUE(I_DSOURCE) TYPE  SRSC_S_IF_SIMPLE-DSOURCE OPTIONAL
*"     VALUE(I_MAXSIZE) TYPE  SRSC_S_IF_SIMPLE-MAXSIZE OPTIONAL
*"     VALUE(I_INITFLAG) TYPE  SRSC_S_IF_SIMPLE-INITFLAG OPTIONAL
*"     VALUE(I_READ_ONLY) TYPE  SRSC_S_IF_SIMPLE-READONLY OPTIONAL
*"     VALUE(I_REMOTE_CALL) TYPE  SBIWA_FLAG DEFAULT SBIWA_C_FLAG_OFF
*"  TABLES
*"      I_T_SELECT TYPE  SRSC_S_IF_SIMPLE-T_SELECT OPTIONAL
*"      I_T_FIELDS TYPE  SRSC_S_IF_SIMPLE-T_FIELDS OPTIONAL
*"      E_T_DATA STRUCTURE  YSDS_DOCU_FLOW OPTIONAL
*"  EXCEPTIONS
*"      NO_MORE_DATA
*"      ERROR_PASSED_TO_MESS_HANDLER
*& Global Data Declarations
* Type for VBFA Data
  TYPES : BEGIN OF ty_vbfa            ,
            mandt   TYPE vbfa-mandt   ,
            vbelv   TYPE vbfa-vbelv   ,
            posnv   TYPE vbfa-posnv   ,
            vbeln   TYPE vbfa-vbeln   ,
            posnn   TYPE vbfa-posnn   ,
            vbtyp_n TYPE vbfa-vbtyp_n ,
            rfmng   TYPE vbfa-rfmng   ,
            meins   TYPE vbfa-meins   ,
            rfwrt   TYPE vbfa-rfwrt   ,
            waers   TYPE vbfa-waers   ,
            vbtyp_v TYPE vbfa-vbtyp_v ,
            plmin   TYPE vbfa-plmin   ,
            erdat   TYPE vbfa-erdat   ,
            aedat   TYPE vbfa-aedat   ,
          END   OF ty_vbfa            .
* Internal Tables and Selection Criteria Structure
  DATA : t_vbfa     TYPE STANDARD TABLE OF ty_vbfa ,
         l_s_select TYPE srsc_s_select             .
* Field Symbols
  FIELD-SYMBOLS : <fs_fields> TYPE rsfieldsel.
* Constants
  CONSTANTS : c_error_msgty TYPE rslogparms-msgty VALUE 'E'            ,
              c_error_msgid TYPE rslogparms-msgid VALUE 'YAERO_WTY_VSR',
              c_error_msgv1 TYPE rslogparms-msgv1 VALUE ' MESSAGE_V1 ' ,
              c_error_msgv2 TYPE rslogparms-msgv1 VALUE ' MESSAGE_V2 ' ,
              c_error_msgv3 TYPE rslogparms-msgv1 VALUE ' MESSAGE_V3 ' ,
              c_error_msgv4 TYPE rslogparms-msgv1 VALUE ' MESSAGE_V4 ' ,
              c_error_msgno TYPE rslogparms-msgno VALUE 999            ,
              c_alias(2)    TYPE c                VALUE 'A~'           ,
              c_vbfa        TYPE dntab-tabname    VALUE 'VBFA'         .
* Maximum Database Lines, Data Package Counter and Cursor
  STATICS : s_s_if              TYPE srsc_s_if_simple ,
            s_counter_datapakid TYPE sy-tabix         ,
            s_cursor            TYPE cursor           .
* Select Ranges
  RANGES : r_erdat FOR vbfa-erdat ,
           r_aedat FOR vbfa-aedat ,
           r_vbelv FOR vbfa-vbelv ,
           r_posnv FOR vbfa-posnv ,
           r_vbeln FOR vbfa-vbeln ,
           r_posnn FOR vbfa-posnn .
*& Processing Logic
* Refresh Internal Table and Clear work area
  REFRESH: t_vbfa   ,
           e_t_data .
* Check the Extraction Mode (Delta Initialization Or Delta)
  IF i_initflag EQ sbiwa_c_flag_on.
*   Determine DataSource Validity
    IF i_dsource NE 'YSDDS_DOCU_FLOW'.
*     Call Function to Write Log
      CALL FUNCTION 'RSAL_LOG_WRITE'
        EXPORTING
          i_msgty = c_error_msgty
          i_msgid = c_error_msgid
          i_msgno = c_error_msgno
          i_msgv1 = c_error_msgv1
          i_msgv2 = c_error_msgv2
          i_msgv3 = c_error_msgv3
          i_msgv4 = c_error_msgv4.
*     Raise Exception
      RAISE error_passed_to_mess_handler.
    ENDIF.                  " IF i_dsource NE 'YSDDS_DOCU_FLOW'.
*   Append the Selection Criteria
    APPEND LINES OF i_t_select TO s_s_if-t_select.
*   Fill parameter buffer for data extraction calls
    MOVE : i_requnr  TO s_s_if-requnr  ,
           i_dsource TO s_s_if-dsource ,
           i_maxsize TO s_s_if-maxsize .
*   Append Fields to be Selected
    APPEND LINES OF i_t_fields TO s_s_if-t_fields.
*   Add the Alias to Fields
    LOOP AT s_s_if-t_fields
      ASSIGNING <fs_fields>.
      CONCATENATE c_alias
                  <fs_fields>-fieldnm
             INTO <fs_fields>-fieldnm.
      CONDENSE <fs_fields>-fieldnm NO-GAPS.
    ENDLOOP.                " LOOP AT s_s_if-t_fields..
  ELSE.                     " IF i_initflag EQ sbiwa_c_flag_on
*   For First Data Package, Open Cursor
    IF s_counter_datapakid EQ 0.
*     Clear Ranges
      CLEAR : r_erdat ,
              r_aedat ,
              r_vbelv ,
              r_posnv ,
              r_vbeln ,
              r_posnn .
*     Fill Selection Ranges
      LOOP AT s_s_if-t_select
        INTO l_s_select.
*       Determine Selection Range Field Name
        CASE l_s_select-fieldnm.
*         Created On Date
          WHEN 'ERDAT'.
            MOVE : l_s_select-sign   TO r_erdat-sign   ,
                   l_s_select-option TO r_erdat-option ,
                   l_s_select-low    TO r_erdat-low    ,
                   l_s_select-high   TO r_erdat-high   .
            APPEND r_erdat.
*           Fill the change date too
            MOVE r_erdat[] TO r_aedat[].
*         Predecessor Document Number
          WHEN 'VBELV'.
            MOVE : l_s_select-sign   TO r_vbelv-sign   ,
                   l_s_select-option TO r_vbelv-option ,
                   l_s_select-low    TO r_vbelv-low    ,
                   l_s_select-high   TO r_vbelv-high   .
            APPEND r_vbelv.
*         Predecessor Document Line Item
          WHEN 'POSNV'.
            MOVE : l_s_select-sign   TO r_posnv-sign   ,
                   l_s_select-option TO r_posnv-option ,
                   l_s_select-low    TO r_posnv-low    ,
                   l_s_select-high   TO r_posnv-high   .
            APPEND r_posnv.
*         Successor Document Number
          WHEN 'VBELN'.
            MOVE : l_s_select-sign   TO r_vbeln-sign   ,
                   l_s_select-option TO r_vbeln-option ,
                   l_s_select-low    TO r_vbeln-low    ,
                   l_s_select-high   TO r_vbeln-high   .
            APPEND r_vbeln.
*         Successor Document Line Item
          WHEN 'POSNN'.
            MOVE : l_s_select-sign   TO r_posnn-sign   ,
                   l_s_select-option TO r_posnn-option ,
                   l_s_select-low    TO r_posnn-low    ,
                   l_s_select-high   TO r_posnn-high   .
            APPEND r_posnn.
        ENDCASE.            " CASE l_s_select-fieldnm.
      ENDLOOP.              " LOOP AT s_s_if-t_select..
*     Open Cursor on View to Fetch data
*     If full load with Selection on Fiscal Year
      IF r_aedat[] IS INITIAL.
*       Full Extraction
        OPEN CURSOR
        WITH HOLD s_cursor FOR
      SELECT (s_s_if-t_fields)
        FROM vbfa      AS a
        JOIN pnwtyv    AS b
          ON a~vbelv   EQ b~sdvbeln
       WHERE a~vbelv   IN r_vbelv
         AND a~posnv   IN r_posnv
         AND a~vbeln   IN r_vbeln
         AND a~posnn   IN r_posnn
         AND a~rfmng   NE 0
         AND a~erdat   IN r_erdat
         AND b~sdvbeln NE space.
      ELSE.
*       Delta Extraction Using ERDAT and AEDAT
        OPEN   CURSOR
        WITH   HOLD s_cursor FOR
      SELECT   (s_s_if-t_fields)
        FROM   vbfa      AS a
        JOIN   pnwtyv    AS b
          ON   a~vbelv   EQ b~sdvbeln
       WHERE   a~vbelv   IN r_vbelv
         AND   a~posnv   IN r_posnv
         AND   a~vbeln   IN r_vbeln
         AND   a~posnn   IN r_posnn
         AND   a~rfmng   NE 0
         AND ( a~erdat   IN r_erdat
          OR   a~aedat   IN r_aedat )
         AND   b~sdvbeln NE space.
      ENDIF.                " IF r_aedat[] IS INITIAL
    ENDIF.                  " IF s_counter_datapakid..
*   Fetch Records into Interface Table
    FETCH NEXT CURSOR s_cursor
         APPENDING CORRESPONDING FIELDS
          OF TABLE t_vbfa
      PACKAGE SIZE s_s_if-maxsize.
*   No More Data, Raise Exception
    IF sy-subrc NE 0.
*     Close the Cursor
      CLOSE CURSOR s_cursor.
*     Raise Exception
      RAISE no_more_data.
    ELSE.
*     Move Extracted Data to Output Structure
      MOVE t_vbfa[] TO e_t_data[].
*     Release Memory
      FREE t_vbfa.
*     Sort Output Structure
      SORT e_t_data BY vbelv
                       posnv
                       vbeln
                       posnn
                       vbtyp_n.
*     Delete Duplicate Records from Output Structure
      DELETE ADJACENT DUPLICATES
        FROM e_t_data
   COMPARING vbelv
             posnv
             vbeln
             posnn
             vbtyp_n.
*     Increment Data Package Number
      s_counter_datapakid = s_counter_datapakid + 1.
    ENDIF.                  " IF sy-subrc NE 0
  ENDIF.                    " IF i_initflag EQ sbiwa_c_flag_on
ENDFUNCTION.              
Edited by: Dennis Scoville on Jul 16, 2009 8:29 AM
Edited by: Dennis Scoville on Jul 16, 2009 8:29 AM