Display in Vertical Lines

Question

HI FRIENDS
BY USING SY-VLINE HOW THE OUTPUT WILL
DISPLAYI N VERTICAL LINES
Edited by: Alvaro Tejada Galindo on Feb 26, 2008 11:09 AM

Answer 1

Hi,
Find the below report so that u will get clear cut idea on SY-VLINE.
REPORT ZCUSTDUN
        MESSAGE-ID ZZ
           LINE-SIZE 145
             LINE-COUNT 65
                NO STANDARD PAGE HEADING.
*                               TABLES                                *
TABLES: VBAK,                          " SALES DOCUMENT: HEADER DATA
        VBEP,                       " SALES DOCUMENT: SCHEDULE LINE DATA
        KNA1,                          " GENERAL DATA IN CUSTOMER MASTER
        VBAP,                          " SALES DOCUMENT: ITEM DATA
        T001W,
        MARC.                   " Koti
DATA Z_EXCEL_FILE LIKE  RLGRAP-FILENAME.    "Excel file name
* SELECTION-SCREEN : PARAMETERS AND SELECT-OPTIONS                    *
SELECTION-SCREEN BEGIN OF BLOCK BLOCK1 WITH FRAME TITLE TEXT-010.
SELECT-OPTIONS : S_KUNNR FOR VBAK-KUNNR.
PARAMETERS     : PLANT LIKE VBAP-WERKS OBLIGATORY.
SELECT-OPTIONS : S_MATNR FOR VBAP-MATNR,
                 S_EDATU FOR VBEP-EDATU.
SELECTION-SCREEN END OF BLOCK BLOCK1.
* ******* EXCEL DOWNLOAD ******* *
SELECTION-SCREEN BEGIN OF BLOCK BLOCK2 WITH FRAME TITLE TEXT-011.
PARAMETERS P_DOWN AS CHECKBOX.
PARAMETER: P_PFILE LIKE RLGRAP-FILENAME.
SELECTION-SCREEN END OF BLOCK BLOCK2.
*                                DATA                                 *
* Internal table for Sales Document: Header Data
DATA: BEGIN OF TBL_VBAK OCCURS 0 ,
      VBELN LIKE VBAK-VBELN,
      KUNNR LIKE KNA1-KUNNR,
      END OF TBL_VBAK.
* Internal table for Cutsomer table.
DATA: BEGIN OF TBL_KNA1 OCCURS 0 ,
      KUNNR LIKE KNA1-KUNNR,
      ORT01 LIKE KNA1-ORT01,        " KOTI
      SORTL LIKE KNA1-SORTL,
      END OF TBL_KNA1.
* Internal table for Sales Document: Schedule Line Data
DATA: BEGIN OF TBL_VBEP OCCURS 0 ,
      VBELN LIKE VBAK-VBELN,
      POSNR LIKE VBEP-POSNR,        "Koti
      ETENR LIKE VBEP-ETENR,
      ETTYP LIKE VBEP-ETTYP,
      EDATU LIKE VBEP-EDATU ,
      WMENG LIKE VBEP-WMENG,
      END OF TBL_VBEP.
* Internal table for Sales Document: Item Data
DATA: BEGIN OF TBL_VBAP OCCURS 0,
      VBELN LIKE VBAP-VBELN,
      POSNR LIKE VBAP-POSNR,
      MATNR LIKE VBAP-MATNR,
      WERKS LIKE VBAP-WERKS,
      END OF TBL_VBAP.
* Internal table for output
DATA: BEGIN OF TBL_FINAL OCCURS 0,
     ETTYP LIKE VBEP-ETTYP,
     MATNR LIKE VBAP-MATNR,
     KUNNR LIKE KNA1-KUNNR,
     SORTL LIKE KNA1-SORTL,
     ORT01 LIKE KNA1-ORT01,
     EDATU LIKE VBEP-EDATU,
     WMENG LIKE VBEP-WMENG,
     END OF TBL_FINAL.
* Internal table for customerno validation
DATA: BEGIN OF IT_KNA1 OCCURS 0,
KUNNR LIKE KNA1-KUNNR,
END OF IT_KNA1.
* Internal table for plant validation
DATA: BEGIN OF IT_T001W OCCURS 0,
WERKS LIKE VBAP-WERKS,
END OF IT_T001W.
* Internal table for material no validation
DATA: BEGIN OF IT_VBAP OCCURS 0,
MATNR LIKE VBAP-MATNR,
END OF IT_VBAP.
* Internal table for date validation
DATA: BEGIN OF IT_VBEP OCCURS 0,
EDATU LIKE VBEP-EDATU,
END OF IT_VBEP.
DATA: BEGIN OF IT_MARC OCCURS 0,   " Koti
MATNR LIKE MARC-MATNR,
END OF IT_MARC.
*               A T   S E L E C T I O N - S C R E E N                  *
AT SELECTION-SCREEN ON VALUE-REQUEST FOR P_PFILE.
  CALL FUNCTION 'KD_GET_FILENAME_ON_F4'
       EXPORTING
            MASK      = ',Text files, *.txt'
            STATIC    = 'X'
       CHANGING
            FILE_NAME = P_PFILE.
* Validation on customer no.
AT SELECTION-SCREEN ON S_KUNNR.
  SELECT KUNNR INTO TABLE IT_KNA1 FROM KNA1
                                    WHERE KUNNR IN S_KUNNR.
  IF SY-SUBRC NE 0.
    MESSAGE E000 WITH TEXT-E01.
    EXIT.
  ENDIF.
* Validation on plant.
AT SELECTION-SCREEN ON PLANT.
*  select werks from t001w into table it_t001w
SELECT WERKS INTO TABLE IT_T001W FROM T001W           " Koti
                                    WHERE WERKS = PLANT.
  IF SY-SUBRC NE 0.
    MESSAGE E000 WITH TEXT-E02.
    EXIT.
  ENDIF.
* Validation on material no.
AT SELECTION-SCREEN ON S_MATNR.
*  select matnr from vbap into table it_vbap    " Koti
   SELECT MATNR INTO TABLE IT_MARC FROM MARC     " Koti
                                    WHERE MATNR IN S_MATNR
                                    AND WERKS EQ PLANT.
  IF SY-SUBRC NE 0.
    MESSAGE E000 WITH TEXT-E03.
    EXIT.
  ENDIF.
* Validation on date.
*AT SELECTION-SCREEN ON S_EDATU.
*  SELECT EDATU INTO TABLE IT_VBEP FROM VBEP            " Koti
*                                    WHERE EDATU IN S_EDATU.
*  IF SY-SUBRC NE 0.
*    MESSAGE E000 WITH TEXT-E04.
*    EXIT.
*  ENDIF.
*                         START-OF-SELECTION                          *
START-OF-SELECTION.
* selecting fields from VBAK
  SELECT VBELN KUNNR
                   INTO TABLE TBL_VBAK FROM VBAK      " Koti
                                WHERE KUNNR IN S_KUNNR.
* Begin of insertion by Kreddy
IF SYST-SUBRC = 0.
  SORT TBL_VBAK.
  DELETE ADJACENT DUPLICATES FROM TBL_VBAK.
ENDIF.
* End of insertion by Kreddy
* selecting fields from KNA1
  IF NOT TBL_VBAK[] IS INITIAL.
    SELECT KUNNR ORT01 SORTL
                   INTO TABLE TBL_KNA1
                         FROM KNA1
                             FOR ALL ENTRIES IN TBL_VBAK
                                   WHERE KUNNR = TBL_VBAK-KUNNR.
* Begin of insertion by Kreddy
    IF SY-SUBRC = 0.
     SORT TBL_KNA1.
    ENDIF.
* End of insertion by Kreddy
  ENDIF.
* selecting fields from VBEP
  IF NOT TBL_VBAK[] IS INITIAL.
    SELECT VBELN POSNR ETENR ETTYP EDATU WMENG      " Koti
                                  INTO TABLE TBL_VBEP
                                  FROM VBEP
                                   FOR ALL ENTRIES IN TBL_VBAK
                                        WHERE VBELN = TBL_VBAK-VBELN
                                              AND EDATU IN S_EDATU
                                    AND ETTYP IN ('L1','L2','CN','E4').
  ENDIF.
* selecting fields from VBAP
  IF NOT TBL_VBEP[] IS INITIAL.
    SELECT VBELN POSNR MATNR WERKS           " Koti
         INTO TABLE TBL_VBAP FROM VBAP
                             FOR ALL ENTRIES IN TBL_VBEP
                     WHERE
                         VBELN = TBL_VBEP-VBELN
                     AND POSNR = TBL_VBEP-POSNR       "Koti
                                 AND
                                 MATNR IN S_MATNR
                                 AND
                                 WERKS = PLANT.
* Begin of insertion by Kreddy
    IF SY-SUBRC = 0.
     SORT TBL_VBAP.
    ENDIF.
* End of insertion by Kreddy
  ENDIF.
END-OF-SELECTION.
*               E N D - O F - S E L E C T I O N                        *
  SORT TBL_VBEP BY VBELN.
  LOOP AT TBL_VBEP.
* Begin of modifications by Kreddy
    CLEAR TBL_VBAK.                                   "Koti
*    loop at tbl_vbak where vbeln = tbl_vbep-vbeln.   " Koti
    READ TABLE TBL_VBAK WITH KEY VBELN = TBL_VBEP-VBELN   " Koti
                                  BINARY SEARCH.
* End of modifications by Kreddy
      IF SY-SUBRC = 0.
        TBL_FINAL-KUNNR = TBL_VBAK-KUNNR.
       CLEAR TBL_KNA1.
        READ TABLE TBL_KNA1 WITH KEY KUNNR = TBL_VBAK-KUNNR
                                             BINARY SEARCH .
        IF SY-SUBRC = 0.
          TBL_FINAL-SORTL = TBL_KNA1-SORTL .
          TBL_FINAL-ORT01 = TBL_KNA1-ORT01 .
        ENDIF.
        CLEAR TBL_VBAP.
        READ TABLE TBL_VBAP WITH KEY VBELN = TBL_VBEP-VBELN
                                     POSNR = TBL_VBEP-POSNR
                                               BINARY SEARCH.
        IF SY-SUBRC = 0.
          TBL_FINAL-MATNR  = TBL_VBAP-MATNR.
        ENDIF.
        TBL_FINAL-WMENG = TBL_VBEP-WMENG.
        TBL_FINAL-EDATU = TBL_VBEP-EDATU.
        TBL_FINAL-ETTYP = TBL_VBEP-ETTYP.
        IF NOT TBL_FINAL-MATNR IS INITIAL.
          APPEND TBL_FINAL.
          CLEAR : TBL_FINAL.
        ENDIF.
      ENDIF.
*    endloop.                             " Koti
    CLEAR : TBL_FINAL.
  ENDLOOP.
*                                OUTPUT                                *
  IF NOT TBL_FINAL[] IS INITIAL.
    DELETE ADJACENT DUPLICATES FROM TBL_FINAL COMPARING ALL FIELDS.
    ULINE.
    FORMAT COLOR COL_HEADING ON.
    WRITE:/01 SY-VLINE,
           04 'SCHEDULING CATEGORY',
           24 SY-VLINE,
           26 'DELPHI MATERIAL',
           44 SY-VLINE,
           46 'DUNNS',
           56 SY-VLINE,
           57 'CUSTOMER NAME1',
           75 SY-VLINE,
           79 'CUSTOMER NAME2',
           112 SY-VLINE,
           113 'REQUEST DATE',
           126 SY-VLINE,
           132 'QUANTITY',
           145 SY-VLINE.
    ULINE.
    FORMAT COLOR OFF.
    SORT TBL_FINAL BY ETTYP.
    LOOP AT TBL_FINAL.
      FORMAT COLOR COL_NORMAL ON.
      WRITE:/01 SY-VLINE,
             10  TBL_FINAL-ETTYP,
             24 SY-VLINE,
             29  TBL_FINAL-MATNR,
             44 SY-VLINE,
             45  TBL_FINAL-KUNNR,
             56 SY-VLINE,
             59  TBL_FINAL-SORTL,
             75 SY-VLINE,
             77  TBL_FINAL-ORT01,
             112 SY-VLINE,
             113  TBL_FINAL-EDATU,
             126 SY-VLINE,
             127 TBL_FINAL-WMENG,
             145 SY-VLINE.
      FORMAT COLOR OFF.
    ENDLOOP.
   ULINE.
  ELSE.
    MESSAGE I000 WITH TEXT-I05.
  ENDIF.
*                 Download in to Excel                                *
  IF P_DOWN = 'X'.
    MOVE P_PFILE TO Z_EXCEL_FILE.
    CALL FUNCTION 'WS_DOWNLOAD'
         EXPORTING
              FILENAME = Z_EXCEL_FILE
              FILETYPE = 'DAT'
         TABLES
              DATA_TAB = TBL_FINAL.
  ENDIF.
*                            END REPORT                               *
<REMOVED BY MODERATOR>
REGARDS,
SUNIL.
Edited by: Alvaro Tejada Galindo on Feb 26, 2008 11:09 AM