Download and upload bsp application

Question

Hi All,
Pl. guide me with my requirement. I have a bsp application in one server and for some reasons the same bsp application is required in another server but these two servers are not in land scape and hence i cannot transport. Is there any way to download the whole application and upload it into the target server. I feel this approach is silly but is there any other way or should i create it again fron the scratch in the new server.Pl. guide me.
thanks & regards,
jeeva.

Answer 1

Hi Jeeva
   Why dont you try the above link given by Raja..
It works fine .... You will get the sourcecode downloaded in a .bsp extension file for each page....But the only major problem is ... It doesnot talk about anything related to How to upload those files in the application....For that you had to take the help of BASIS ..
But if your problem get solved by just getting the source code downloaded then try this code...This is the same code that RAJA has linked to...Just paste the code in a report program...and execute it...
type-pools: SO2.
types: t_page_list type standard table of o2pagkey.
parameters: g_appl type O2APPLNAME.
constants: c_separator_line type string value
perform main.
form main.
  data: l_pages type t_page_list,
  l_ref_page type ref to cl_o2_api_pages,
  l_table type o2pageline_table,
  l_folder type string,
  l_lower type string,
  l_filename type string.
  field-symbols: <f_page> type o2pagkey.
* get local directory path
  call method CL_GUI_FRONTEND_SERVICES=>DIRECTORY_BROWSE
* EXPORTING
* WINDOW_TITLE =
* INITIAL_FOLDER =
  CHANGING
  SELECTED_FOLDER = l_folder
  EXCEPTIONS
  CNTL_ERROR = 1
  ERROR_NO_GUI = 2
  NOT_SUPPORTED_BY_GUI = 3
  others = 4.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
    WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    return.
  ENDIF.
  if l_folder is initial. return. endif.
* get all pages of selected BSP application
  perform get_all_pages changing l_pages.
* perform each page
  loop at l_pages assigning <f_page>.
* load page data
    perform load_page using <f_page>
    changing l_ref_page.
    if l_ref_page is bound.
* collect the content of the page in an internal table
      perform print using l_ref_page
      changing l_table.
      if not l_table is initial.
        l_lower = <f_page>-pagekey.
        translate l_lower to lower case.
* determine file path for the page
        concatenate l_folder '' l_lower into l_filename.
* download the content of the page to file
        perform download using l_filename l_table.
      endif.
    endif.
  endloop.
endform.                    "main
form download using p_filename type string
p_table type standard table.
* download the content of an internal table to a local file
  call method CL_GUI_FRONTEND_SERVICES=>GUI_DOWNLOAD
    EXPORTING
      FILENAME                = p_filename
    CHANGING
      DATA_TAB                = p_table
    EXCEPTIONS
      FILE_WRITE_ERROR        = 1
      NO_BATCH                = 2
      GUI_REFUSE_FILETRANSFER = 3
      INVALID_TYPE            = 4
      NO_AUTHORITY            = 5
      UNKNOWN_ERROR           = 6
      HEADER_NOT_ALLOWED      = 7
      SEPARATOR_NOT_ALLOWED   = 8
      FILESIZE_NOT_ALLOWED    = 9
      HEADER_TOO_LONG         = 10
      DP_ERROR_CREATE         = 11
      DP_ERROR_SEND           = 12
      DP_ERROR_WRITE          = 13
      UNKNOWN_DP_ERROR        = 14
      ACCESS_DENIED           = 15
      DP_OUT_OF_MEMORY        = 16
      DISK_FULL               = 17
      DP_TIMEOUT              = 18
      FILE_NOT_FOUND          = 19
      DATAPROVIDER_EXCEPTION  = 20
      CONTROL_FLUSH_ERROR     = 21
      NOT_SUPPORTED_BY_GUI    = 22
      ERROR_NO_GUI            = 23
      others                  = 24.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
    WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
endform.                    "download
form get_all_pages changing p_pages type t_page_list.
* get all pages of the application
  select applname pagekey from o2pagdir into table p_pages
  where applname = g_appl and
  pagetype <> so2_controller.
endform.                    "get_all_pages
form load_page using p_key type o2pagkey
changing p_data type ref to cl_o2_api_pages.
* load the data of one page
  clear p_data.
  call method cl_o2_api_pages=>load_with_access_permission
    EXPORTING
      p_mode    = 'SHOW'
      p_pagekey = p_key
      p_version = 'A' "'I' for inactive version
    IMPORTING
      p_page    = p_data
    EXCEPTIONS
      others    = 1.
endform.                    "load_page
form print using p_data type ref to cl_o2_api_pages
changing p_table type o2pageline_table.
* collect the content of a page into an internal table
  data: l_attrs type o2pagattr,
  l_params type o2pagpar_tabletype,
  l_source type rswsourcet,
  l_layout type o2pageline_table,
  l_ev_handlers type so2_ev_handler_list,
  l_typtyp(11) type c,
  l_line type string.
  field-symbols: <f_param> type o2pagpars,
  <f_evh_name> type so2_ev_handler_name.
  refresh p_table.
* get page properties
  CALL METHOD P_DATA->GET_ATTRS
    IMPORTING
      P_ATTRS = l_attrs
    EXCEPTIONS
      others  = 1.
  check l_attrs-pagetype <> so2_controller.
  append c_separator_line to p_table.
  concatenate '*' l_attrs-applname '/' l_attrs-pagekey into l_line.
  append l_line to p_table.
  append c_separator_line to p_table.
  append space to p_table.
* local types
  if l_attrs-pagetype = so2_full_page.
    CALL METHOD P_DATA->GET_TYPE_SOURCE
      IMPORTING
        P_SOURCE = l_source
      EXCEPTIONS
        others   = 1.
    if not l_source is initial.
      append c_separator_line to p_table.
      append '* local types' to p_table.
      append c_separator_line to p_table.
      append lines of l_source to p_table.
      do 3 times.
        append space to p_table.
      enddo.
    endif.
  endif.
* page attributes
  if l_attrs-pagetype = so2_full_page or
  l_attrs-pagetype = so2_view_page.
    CALL METHOD P_DATA->GET_PARAMETERS
      IMPORTING
        P_PARAMETERS = l_params
      EXCEPTIONS
        others       = 1.
    if not l_params is initial.
      append c_separator_line to p_table.
      append '* page attributes' to p_table.
      append c_separator_line to p_table.
      loop at l_params assigning <f_param>.
        if <f_param>-typtype = so2_paramtyp_type.
          l_typtyp = 'TYPE'.
        else.
          l_typtyp = 'TYPE REF TO'.
        endif.
        concatenate <f_param>-aliasname l_typtyp
        <f_param>-type into l_line
        separated by space.
        append l_line to p_table.
      endloop.
      do 3 times.
        append space to p_table.
      enddo.
    endif.
  endif.
* layout
  append c_separator_line to p_table.
  append '* layout' to p_table.
  append c_separator_line to p_table.
  CALL METHOD P_DATA->GET_PAGE
    IMPORTING
      P_CONTENT = l_layout
    EXCEPTIONS
      others    = 1.
  append lines of l_layout to p_table.
  do 3 times.
    append space to p_table.
  enddo.
* event handler
  if l_attrs-pagetype = so2_full_page.
    CALL METHOD P_DATA->GET_EVENT_HANDLER_LIST
      EXPORTING
        P_WITH_ALL_PREDEFINED = ' '
      IMPORTING
        P_EV_HANDLER_L        = l_ev_handlers
      EXCEPTIONS
        others                = 1.
    loop at l_ev_handlers assigning <f_evh_name>.
      append c_separator_line to p_table.
      concatenate '* eventhandler' <f_evh_name>-name into l_line
      separated by space.
      append l_line to p_table.
      append c_separator_line to p_table.
      clear l_source.
      CALL METHOD P_DATA->GET_EVENT_HANDLER
      EXPORTING
      P_NAME = <f_evh_name>-key
      IMPORTING
      P_SOURCE = l_source
* P_ATTRS =
      EXCEPTIONS
      others = 1.
      append lines of l_source to p_table.
      do 3 times.
        append space to p_table.
      enddo.
    endloop.
  endif.
endform.                    "print
RGDS
Mithlesh