Download clob contents from function instead of a blob column in a table

Question

I found some examples how to create a download link for data stored in a blob column. However my data is not stored in a blob column but is created in a function returning a clob. Obviously this function can be used to fill a blob column that can then be downloaded but maybe there is a more direct route.

Answer 1

Hello Rene,
I adapted one of my snippets for download-links for your case. The procedure is pretty much the same like the one concerning an existing blob. To provide the download, you need to convert your clob into a blob, which can be done easily by using the corresponding function provided by the [url http://download.oracle.com/docs/cd/B19306_01/appdev.102/b14258/d_lob.htm]DBMS_LOB-API.
The result might look like the following (untested) code snippet:
CREATE OR REPLACE procedure download_from_function (p_func_argument IN VARCHAR2, p_filename IN VARCHAR2)
AS
  l_http_response  UTL_HTTP.resp;
  l_blob           BLOB;
  l_raw            RAW(32767);
  l_length         INTEGER;
  l_dest_offset    INTEGER := 1;
  l_src_offset     INTEGER := 1;
  l_lang_context   INTGER := DBMS_LOB.DEFAULT_LANG_CTX;
  l_warning        INTEGER;
BEGIN
  -- Initialize the BLOB.
  DBMS_LOB.createtemporary(l_blob, FALSE);
  -- replace the function call for src_clob
  DBMS_LOB.convertToBlob( dest_lob     => l_blob,
                          src_clob     => your_clob_function(p_func_argument),
                          amount       => DBMS_LOB.LOBMAXSIZE,
                          dest_offset  => l_dest_offset,
                          src_offset   => l_src_offset,
                          blob_csid    => DBMS_LOB.DEFAULT_CSID,
                          lang_context => l_lang_context,
                          warning      => l_warning);
  l_length := DBMS_LOB.getlength(l_blob);
  -- create response header
  OWA_UTIL.mime_header('text/plain', false);
  -- add furhter header attributes
  htp.p('Content-length: ' || l_length);
  htp.p('Content-Disposition: attachment; filename="' || p_filename || '"');
  -- close the headers
  OWA_UTIL.http_header_close;
  -- download the BLOB
  WPG_DOCLOAD.download_file( l_blob );
  -- release BLOB from memory
  DBMS_LOB.freetemporary(l_blob);
EXCEPTION
  WHEN OTHERS THEN
    DBMS_LOB.freetemporary(l_blob);
    RAISE;
END download_from_function;
-- Page process before header on blank page
BEGIN
  download_from_function (p_func_argument => 'your_argument_for_your_clob_returning_function',
                          p_filename => 'filename_for_download.txt');
END;You should change function name and arguments to fit your clob-function's signature. You may also want to add a characterset conversion if needed. See the [url http://download.oracle.com/docs/cd/B19306_01/appdev.102/b14258/d_lob.htm]API-doc for details.
-Udo