Drop down menu in alv toolbar?

Question

Hi,
is it possible to add a drop down menu to the toolbar in my alv?
I wanna assign 3 values to the toolbar, similar to a drop down menu in html?
Thanx

Answer 1

Hi,
Check the below code .......
*       CLASS lcl_event_handler DEFINITION
CLASS lcl_event_handler DEFINITION.
  PUBLIC SECTION.
    DATA: wa_toolbar   TYPE stb_button,
          utilities    TYPE REF   TO cl_gui_frontend_services.
    METHODS : toolbar_handle FOR EVENT toolbar      OF cl_gui_alv_grid
                                    IMPORTING e_object
                                              e_interactive,
              menu_bt_handle FOR EVENT menu_button  OF cl_gui_alv_grid
                                    IMPORTING e_object
                                              e_ucomm,
              ucomm_handle   FOR EVENT user_command OF cl_gui_alv_grid
                                    IMPORTING e_ucomm.
ENDCLASS.                    "lcl_event_handler DEFINITION
*       CLASS lcl_event_handler IMPLEMENTATION
CLASS lcl_event_handler IMPLEMENTATION.
  METHOD toolbar_handle.
    MOVE   3 TO  wa_toolbar-butn_type.
    APPEND wa_toolbar   TO e_object->mt_toolbar.
    MOVE : 2            TO wa_toolbar-butn_type,
           '$MENU'      TO wa_toolbar-function,
           '@6C@'       TO wa_toolbar-icon,
           'User menu'  TO wa_toolbar-quickinfo.
    APPEND wa_toolbar TO e_object->mt_toolbar.
  ENDMETHOD. "toolbar_handle
  METHOD menu_bt_handle .
IF e_ucomm = '$MENU'.
CALL METHOD e_object->add_function
  EXPORTING
    fcode       = 'CALC'
    text        = 'Calculator'.
CALL METHOD e_object->add_function
  EXPORTING
    fcode       = 'INT'
    text        = 'Internet Explorer'.
ENDIF.
  ENDMETHOD. "menu_bt_handle
  METHOD ucomm_handle.
    CASE  e_ucomm.
      WHEN 'CALC'.
        IF utilities IS INITIAL.
          CREATE OBJECT utilities.
        ENDIF.
        CALL METHOD cl_gui_frontend_services=>execute
          EXPORTING
            application = 'CALC'.
      WHEN 'INT'.
        IF utilities IS INITIAL.
          CREATE OBJECT utilities.
        ENDIF.
        CALL METHOD cl_gui_frontend_services=>execute
          EXPORTING
            application = 'IEXPLORE'.
    ENDCASE.
  ENDMETHOD. "ucomm_handle
ENDCLASS.                    "lcl_event_handler IMPLEMENTATION
DATA : container    TYPE REF   TO cl_gui_custom_container,
       grid         TYPE REF   TO cl_gui_alv_grid,
       event        TYPE REF   TO lcl_event_handler,
       it_display   TYPE TABLE OF mara,
       wa_display   TYPE mara.
START-OF-SELECTION.
  CALL SCREEN 100.
*&      Module  STATUS_0100  OUTPUT
*       text
MODULE status_0100 OUTPUT.
  SET PF-STATUS 'BASIC'.
  PERFORM build_it_display.
  PERFORM create_objects.
ENDMODULE.                 " STATUS_0100  OUTPUT
*&      Module  USER_COMMAND_0100  INPUT
*       text
MODULE user_command_0100 INPUT.
  CASE sy-ucomm.
    WHEN 'BACK'.
      SET SCREEN 0.
      LEAVE SCREEN.
    WHEN 'EXIT'.
      SET SCREEN 0.
      LEAVE SCREEN.
    WHEN 'CANC'.
      SET SCREEN 0.
      LEAVE SCREEN.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT
*&      Form  build_it_display
*       text
*  -->  p1        text
*  <--  p2        text
FORM build_it_display .
  SELECT * FROM mara UP TO 15 ROWS INTO TABLE it_display.
ENDFORM.                    " build_it_display
*&      Form  create_objects
*       text
*  -->  p1        text
*  <--  p2        text
FORM create_objects .
  IF container IS INITIAL.
    CREATE OBJECT container
    EXPORTING
      container_name     = 'CUSTOM'.
    CREATE OBJECT event.
    CREATE OBJECT grid
      EXPORTING
        i_parent         = container.
    SET HANDLER event->toolbar_handle FOR grid.
    SET HANDLER event->menu_bt_handle FOR grid.
    SET HANDLER event->ucomm_handle   FOR grid.
    CALL METHOD grid->set_table_for_first_display
      EXPORTING
        i_structure_name = 'MARA'
      CHANGING
        it_outtab        = it_display.
  ENDIF.
ENDFORM.                    " create_objects   
Cheers,
Jose