Dynamic html table

Question

Hi,
I try to do a dynamic table which will return headings, all rows from emp table. Let say I've done process on page which return simple table contect.
----------------------------Process on load after region----------------------------------------------------------
DECLARE
totalrows INT;
str VARCHAR2 (300);
CURSOR c_emp
IS
SELECT empno, ename, mgr
FROM emp;
BEGIN
HTP.p ('<table style="border:1px solid;">');
FOR i IN c_emp
LOOP
HTP.p ('<tr >');
HTP.p ('<td style="border:1px solid black;">' || i.empno || '</td>');
HTP.p ('<td style="border:1px solid black;">' || i.ename || '</td>');
HTP.p ('<td style="border:1px solid black;">' || i.mgr || '</td>');
HTP.p ('</tr>');
END LOOP;
HTP.p ('</table>');
END;
How to include headings of columns dynamically? And how to make it more sensible?
Thx for help and some good ideas !

Answer 1

Hi,
yes true.
We can apply class e.g. if using standard theme 14
DECLARE
  l_cursor  INTEGER := dbms_sql.open_cursor;
  l_qry     VARCHAR2(32000);
  l_status  NUMBER;
  l_cvalue  VARCHAR2(32000);
  l_col_cnt NUMBER;
  l_desc_t  dbms_sql.desc_tab2;
  l_desc_c  dbms_sql.desc_tab;
  l_table   VARCHAR2(32000) := '<table class="t14Standard">';
  l_th      VARCHAR2(32000) := '<th class="t14ReportHeader">';
  l_td      VARCHAR2(32000) := '<td class="t14data">';
BEGIN
  l_qry := 'SELECT * FROM emp';
  dbms_sql.parse (l_cursor, l_qry, dbms_sql.native);
  dbms_sql.describe_columns( l_cursor, l_col_cnt, l_desc_c );
  htp.p(l_table);
  htp.p('<tr>');
  htp.p('<thead>');
  FOR i IN 1 .. l_desc_c.count
  LOOP
    htp.prn(l_th || l_desc_c(i).col_name || '</th>');
  END LOOP;
  htp.p('</thead>');
  htp.p('</tr>');
  htp.p('<tbody>');
  dbms_sql.describe_columns2( l_cursor, l_col_cnt, l_desc_t );
  FOR i IN 1 .. l_desc_t.count
  LOOP
    dbms_sql.define_column( l_cursor, i, l_cvalue, 32765);
  END LOOP;
  l_status := dbms_sql.execute( l_cursor );
  LOOP
    EXIT
  WHEN (dbms_sql.fetch_rows( l_cursor ) <= 0 );
    --l_row_cnt      := l_row_cnt + 1;
    htp.p('<tr>');
    FOR i IN 1 .. l_desc_t.count
    LOOP
      dbms_sql.column_value( l_cursor, i, l_cvalue );
      htp.prn(l_td || l_cvalue || '</td>');
    END LOOP;
    htp.p('</tr>');
  END LOOP;
  htp.p('</<tbody>');
  htp.p('</table>');
  IF dbms_sql.is_open(l_cursor) THEN
    dbms_sql.close_cursor(l_cursor);
  END IF;
EXCEPTION WHEN OTHERS THEN
  IF dbms_sql.is_open(l_cursor) THEN
    dbms_sql.close_cursor(l_cursor);
  END IF;
  RAISE;
END;Br, Jari