E-Recruiting: Posting and Requisition relationship

Question

Greetings,
My  question has a couple layers to it.  An internal audit dictates a review of job posting for a particular work location in a given time frame.
I have requisition (NB) IDs for that site.
First question: Is there a relationship between req (NB) and posting (NC)?  I need to identify the posting for each req ID that I have but was unable to do so through table 1001.  Is there a roundabout way to get to the NC object from NB?
Second question: Once I've identified posting (NC), how might I produce the text objects associated with each posting ID en masse.  Table 5121 points to text objects, but I do not know of how to get to them.  I would like to avoid having to go through the posting text individually through the front end.  I've seen a couple posts regarding this topic, but I'm uncertain of the mechanics discussed.  The posts I've seen are:
/community [original link is broken]
Description of requirements field in e recruitment
Thank you in advance for any assistance.
Regards,
Brad

Answer 1

REPORT  zrwe_0001.
*  Declarations
*-- Type Pools --------------------------------------------------------*
TYPE-POOLS:
  abap.
*-- Types -------------------------------------------------------------*
TYPES:
  BEGIN OF __ls_result,
    requ_key         TYPE hrobject,
    requ_header      TYPE rcf_requisition_header,
    post_key         TYPE hrobject,
    post_header      TYPE string,
    post_company     TYPE string,
    post_department  TYPE string,
    post_project     TYPE string,
    post_task        TYPE string,
    post_requirement TYPE string,
    pinst_guid       TYPE rcf_pinst_guid,
    pinst_start      TYPE rcf_posting_start_date,
    pinst_end        TYPE rcf_posting_end_date,
    pinst_chan       TYPE rcf_posting_channel,
    pinst_chan_txt   TYPE rcf_posting_channel_txt,
  END   OF __ls_result,
  __lt_result TYPE STANDARD TABLE OF __ls_result.
*-- Field symbols -
FIELD-SYMBOLS:
  <lv_any>      TYPE                   ANY.
*-- Variables -
DATA:
  lr_pins_hdl   TYPE REF TO            cl_hrrcf_posting_inst_bl,
  lv_plvar      TYPE                   plvar,
  lv_channel    TYPE                   rcf_posting_channel,
  lt_5122       TYPE STANDARD TABLE OF hrp5122,
  ls_5122       TYPE                   hrp5122,
  ls_requ       TYPE                   rcf_s_requisition_info_text,
  lt_result     TYPE                   __lt_result,
  ls_result     TYPE                   __ls_result,
  ls_chan       TYPE                   t77rcf_postchn_t,
  ln_count      TYPE                   i,
  lv_str_trick  TYPE                   string,
  lr_exc        TYPE REF TO            cx_hrrcf.
Selection Screen
*-- Selection Screen Definition -
SELECTION-SCREEN BEGIN OF BLOCK b01 WITH FRAME TITLE text-001.
SELECT-OPTIONS:
  o_chan FOR lv_channel.
PARAMETERS:
  p_from TYPE rcf_posting_start_date,
  p_to   TYPE rcf_posting_end_date.
SELECTION-SCREEN END   OF BLOCK b01.
*-- Selection Screen Processing -
AT SELECTION-SCREEN ON p_from.
  IF p_from IS INITIAL.
    MESSAGE e001(00) WITH 'Enter a from date'.
  ENDIF.
AT SELECTION-SCREEN ON p_to.
  IF p_to IS INITIAL.
    MESSAGE e001(00) WITH 'Enter a to date'.
  ELSEIF p_to LT p_from.
    MESSAGE e001(00) WITH 'To date has to be greater or equal from date'.
  ENDIF.
Processing
-- Init the runtime -
INITIALIZATION.
get handler class instance
  lr_pins_hdl = cl_hrrcf_posting_inst_bl=>get_instance( ).
get the active plan
  CALL FUNCTION 'RH_GET_PLVAR'
    EXPORTING
      no_message = abap_true
    IMPORTING
      plvar      = lv_plvar
    EXCEPTIONS
      OTHERS     = 0.
make a 1 space string
  lv_str_trick = ' a'.                                      "#EC NOTEXT
  lv_str_trick = lv_str_trick(1).
-- Processing -
START-OF-SELECTION.
get all publications which were really published (PUBLISHED_DOC <> 0)
and which were published in the date borders
  SELECT * FROM hrp5122 INTO TABLE lt_5122
    WHERE
      plvar           =  lv_plvar                             AND
      otype           =  cl_hrrcf_posting_bl=>c_otype_posting AND
      subty           =  '    '                               AND "#EC NOTEXT
      istat           =  '1'                                  AND "#EC NOTEXT
      endda           =  '99991231'                           AND "#EC NOTEXT
      posting_channel IN o_chan                               AND
      published_doc   <> '000000'                             AND "#EC NOTEXT
      start_date      <= p_to                                 AND
      end_date        >= p_from.
gather the posting texts and requisition information
  LOOP AT lt_5122 INTO ls_5122.
    CLEAR:
      ls_result,
      ls_chan.
  read the frozen doc
    TRY.
        ls_result-pinst_guid       = ls_5122-pinst_guid.
        ls_result-pinst_start      = ls_5122-start_date.
        ls_result-pinst_end        = ls_5122-end_date.
        ls_result-pinst_chan       = ls_5122-posting_channel.
        ls_result-post_key-plvar   = ls_5122-plvar.
        ls_result-post_key-otype   = ls_5122-otype.
        ls_result-post_key-objid   = ls_5122-objid.
        lr_pins_hdl->get_frozen_post_inst_data(
          EXPORTING
            p_pinst_guid               = ls_5122-pinst_guid
          IMPORTING
            p_post_header              = ls_result-post_header
            p_post_company_desc        = ls_result-post_company
            p_post_department_desc     = ls_result-post_department
            p_post_project_desc        = ls_result-post_project
            p_post_task_desc           = ls_result-post_task
            p_post_requirement_desc    = ls_result-post_requirement
            ps_requisition_info_text   = ls_requ ).
        ls_result-requ_key-plvar   = ls_requ-plvar.
        ls_result-requ_key-otype   = ls_requ-otype.
        ls_result-requ_key-objid   = ls_requ-objid.
        ls_result-requ_header      = ls_requ-header.
        " Channel Text
        cl_hrrcf_t77rcf_postchn=>read_description(
          EXPORTING
            langu            = sy-langu
            posting_channel  = ls_result-pinst_chan
          IMPORTING
            t77rcf_postchn_t = ls_chan ).
        ls_result-pinst_chan_txt   = ls_chan-description.
        APPEND ls_result TO lt_result.
      CATCH cx_hrrcf INTO lr_exc.
        cl_hrrcf_exception_handler=>write_exception_log( ex = lr_exc ).
    ENDTRY.
  ENDLOOP.
excel download
  " replace all Tabs and CT/LF or the excel will be messed up
  LOOP AT lt_result INTO ls_result.
    ln_count = 1.
    WHILE 1 = 1.
      ASSIGN COMPONENT ln_count OF STRUCTURE ls_result TO <lv_any>.
      IF sy-subrc NE 0.
        EXIT.
      ENDIF.
      REPLACE ALL OCCURRENCES OF cl_abap_char_utilities=>horizontal_tab
        IN <lv_any> WITH lv_str_trick.
      REPLACE ALL OCCURRENCES OF cl_abap_char_utilities=>cr_lf
        IN <lv_any> WITH lv_str_trick.
      REPLACE ALL OCCURRENCES OF cl_abap_char_utilities=>newline
        IN <lv_any> WITH lv_str_trick.
      ADD 1 TO ln_count.
    ENDWHILE.
    MODIFY lt_result FROM ls_result.
  ENDLOOP.
  cl_gui_frontend_services=>gui_download(
    EXPORTING
      filename                  = 'C:\myfile.csv'
      write_field_separator     = abap_true
    CHANGING
      data_tab                  = lt_result
    EXCEPTIONS
      OTHERS                    = 0 ).
simple list output
  LOOP AT lt_result INTO ls_result.
    WRITE: / 'Requisition:', ls_result-requ_header,
           / 'Posting    :', ls_result-post_header,
           / 'Channel    :', ls_result-pinst_chan_txt.
    SKIP.
    WRITE: / 'Company:', / ls_result-post_company. SKIP.
    WRITE: / 'Department:', / ls_result-post_department. SKIP.
    WRITE: / 'Project:', / ls_result-post_project. SKIP.
    WRITE: / 'Task:', / ls_result-post_task. SKIP.
    WRITE: / 'Requirement:', / ls_result-post_requirement. SKIP.
    ULINE. SKIP.
  ENDLOOP.