Ensuring a task isn't interrupted

Question

I'm working on a project which has a block of time during which nothing can happen.  For all intents and purposes, it's a holiday block in the project calendar.
The problem is that some of my tasks cannot be "paused" or interrupted once they have begun.  Therefore, I need to either finish BEFORE the start of the holiday block, or start AFTER the end of the holiday block.  These are hard deadlines
(legal) -- it is NOT a project management issue of using resources overtime, and the task has 0% chance of success if it is spread across the non-working time (think: surgeries, baking cakes, etc).
I've been searching for solutions, and it appears there is one with a trick using 1 minute tasks
Here preceeding and following the uninterruptible tasks, but surely there is a built-in way to handle this in MS Project 2013?  What am I missing?  I'd love to use autoscheduling with this, but it's looking more and more unlikely.
Help is appreciated!
PTC

Answer 1

PTC,
Just for reference, this question has been asked multiple times over the years. There are basically two solutions, the one minute queueing as described by Mike and Julie in the reference you found, the other is a VBA solution that looks at all the tasks
in a schedule and those that are marked, say by a Flag field, are analyzed to determine whether or not they will be executed in continuous time. If not, the tasks are moved to the next working day. Herewith is that code:
'This macro ensures all selected tasks can be completed continuously once started.
'   Tasks are selected by setting Flag1. Note: this procedure does leave a
'   start-no-earlier-than constraint on all shifted tasks
'written by John 10/24/13 8:00 am
Dim t As Task
Dim EndTime As String, StartTime As String, ProjCal As String
Dim WkD As Integer
Dim DayDate As Date
Sub NextDayB()
'cycle through each task
ProjCal = ActiveProject.Calendar
For Each t In ActiveProject.Tasks
    'skip over blank lines
    If Not t Is Nothing Then
        'only look at Start time of non-summary tasks
        If t.Summary = False And t.Flag1 = True Then
            'find default start and end times for this task
            WkD = Weekday(t.Start)
            StartTime = ActiveProject.BaseCalendars(ProjCal).WeekDays(WkD).Shift1.Start
            EndTime = ActiveProject.BaseCalendars(ProjCal).WeekDays(WkD).Shift2.Finish
            'create faux end date & time if task ended the same date it started
            DayEnd = DateValue(t.Start) & " " & EndTime
            If Application.DateDifference(t.Start, DayEnd) < t.Duration Then
                'task won't finish the same day so move it to start first thing next working day
                t.Start = DateValue(Application.DateAdd(t.Start, "1d")) & " " & StartTime
            End If
        End If
    End If
Next t
End Sub
John