Error occurs during select-options

Question

hi friends,
i am developed a report for extracting data from vbap using select-options
i am using feilds,
vbeln erdat ernam vbtyp vkorg vtweg feilds
and vbeln vkorg vbtyp erdat as selection screen feilds.
i got selection screen screen with required feilds well .
but problem is with method onactiondisplay
the coding like this
method ONACTIONDISPLAY .
TYPES: lty_r_vbeln TYPE RANGE OF vbeln,
       lty_r_erdat TYPE RANGE OF erdat,
        lty_R_VKORG TYPE RANGE OF VKORG,
        lty_r_vbtyp type range of vbtyp.
DATA: lo_customer TYPE REF TO if_wd_context_node.
Variables used to retrieve the values of select-options fields
  DATA: lt_sel_item TYPE if_wd_select_options=>tt_selection_screen_item.
  FIELD-SYMBOLS:
    <fs_sel_item> LIKE LINE OF lt_sel_item,
    <fs_vbeln>   TYPE lty_r_vbeln,
    <fs_vkorg>   TYPE lty_r_vkorg,
    <fs_vbtyp>   TYPE lty_r_vbtyp,
    <fs_erdat>   TYPE lty_r_erdat.
Get the selection-screen items
  wd_this->m_handler->get_selection_screen_items(
    IMPORTING et_selection_screen_items = lt_sel_item ).
Retrieve the values from the select-options items
  LOOP AT lt_sel_item ASSIGNING <fs_sel_item>.
    CASE <fs_sel_item>-m_id.
      WHEN `VBELN`.
        ASSIGN <fs_sel_item>-m_value->* TO <fs_vbeln>.
      WHEN `VKORG`.
        ASSIGN <fs_sel_item>-mt_range_table->* TO <fs_vkorg>.
      WHEN `VBTYP`.
        ASSIGN <fs_sel_item>-mt_range_table->* TO <fs_vbtyp>.
      WHEN `ERDAT`.
        ASSIGN <fs_sel_item>-mt_range_table->* TO <fs_erdat>.
    ENDCASE.
  ENDLOOP.
Retrieve the data from the database, for simplicity, the
SELECT statement has been implemented here.
  SELECT * FROM vbak
    INTO TABLE wd_this->customer
    WHERE vbeln = <fs_vbeln>
      AND vkorg IN <fs_vkorg>
      AND vbtyp IN <fs_vbtyp>
      AND erdat IN <fs_erdat>.
Bind the data to the context
  lo_customer = wd_context->get_child_node( name = `customer`).
  lo_customer->bind_table( wd_this->vbak ).
ENDMETHOD.
here customer is the node
and i refer attributes
m_handler = IF_WD_SELECT_OPTIONS
M_SELECT_OPTIONS = IWCI_WDR_SELECT_OPTIONS
and i defined vbeln as parameter only.
and i got error as
the feild customer is unknown but there is a feild with similar name wdctx_customer
can any one explain clearly to extracts the data by using select options ..?

Answer 1

Hello Karunakar,
Since your problem was not getting solved, I took sometime to try this program on my own and figured out that getting value of parameter field is not same like selection field. we need to change only that part. anyhow since I tried this I;m sharing the complete code.
code for creating the selection fields and parameter fields. verify whether you are doing the same in INIT method
  data lt_range type ref to data.
  data lr_vbeln type ref to vbeln.
  create data lr_vbeln.
  wd_this->m_handler->add_parameter_field(
      i_id    = 'VBELN'
      i_value = lr_vbeln ).
  lt_range = wd_this->m_handler->create_range_table( 'VKORG' ).
  wd_this->m_handler->add_selection_field(
      i_id                         = 'VKORG'
      it_result                    = lt_range ).
  lt_range = wd_this->m_handler->create_range_table( 'VBTYP' ).
  wd_this->m_handler->add_selection_field(
      i_id                         = 'VBTYP'
      it_result                    = lt_range ).
  lt_range = wd_this->m_handler->create_range_table( 'ERDAT' ).
  wd_this->m_handler->add_selection_field(
      i_id                         = 'ERDAT'
      it_result                    = lt_range ).
and code the action method
  data:
        lt_sel_item type if_wd_select_options=>tt_selection_screen_item,
        lt_parameters type if_wd_select_options=>tt_selection_screen_item,
        lt_r_vkorg type range of vkorg,
        lt_r_vbtyp type range of vbtyp,
        lt_r_erdat type range of erdat,
        lv_condition type string,
        lt_customer type wd_this->elements_customer,
        lo_nd_customer type ref to if_wd_context_node.
  field-symbols:
        <fs_sel_item> like line of lt_sel_item,
        <fv_vbeln> type vbeln,
        <ft_r_vkorg> like lt_r_vkorg,
        <ft_r_vbtyp> like lt_r_vbtyp,
        <ft_r_erdat> like lt_r_erdat.
  wd_this->m_handler->get_parameter_fields( importing et_fields = lt_parameters ).
  wd_this->m_handler->get_selection_screen_items( importing et_selection_screen_items = lt_sel_item ).
  loop at lt_parameters assigning <fs_sel_item>.
    case <fs_sel_item>-m_id.
      when `VBELN`.
        assign <fs_sel_item>-m_value->* to <fv_vbeln>.
        if <fv_vbeln> is assigned and <fv_vbeln> is not initial.
          if lv_condition is not initial.
            concatenate lv_condition 'AND' into lv_condition separated by space.
          endif.
          concatenate lv_condition 'VBELN = <FV_VBELN>' into lv_condition separated by space.
        endif.
    endcase.
  endloop.
  loop at lt_sel_item assigning <fs_sel_item>.
    case <fs_sel_item>-m_id.
      when `VKORG`.
        assign <fs_sel_item>-mt_range_table->* to <ft_r_vkorg>.
        if <ft_r_vkorg> is assigned and <ft_r_vkorg> is not initial.
          if lv_condition is not initial.
            concatenate lv_condition 'AND' into lv_condition separated by space.
          endif.
          concatenate lv_condition 'VKORG IN <FT_R_VKORG>' into lv_condition separated by space.
        endif.
      when `VBTYP`.
        assign <fs_sel_item>-mt_range_table->* to <ft_r_vbtyp>.
        if <ft_r_vbtyp> is assigned and <ft_r_vbtyp> is not initial.
          if lv_condition is not initial.
            concatenate lv_condition 'AND' into lv_condition separated by space.
          endif.
          concatenate lv_condition 'VBTYP IN <FT_R_VBTYP>' into lv_condition separated by space.
        endif.
      when `ERDAT`.
        assign <fs_sel_item>-mt_range_table->* to <ft_r_erdat>.
        if <ft_r_erdat> is assigned and <ft_r_erdat> is not initial.
          if lv_condition is not initial.
            concatenate lv_condition 'AND' into lv_condition separated by space.
          endif.
          concatenate lv_condition 'ERDAT IN <FT_R_ERDAT>' into lv_condition separated by space.
        endif.
    endcase.
  endloop.
  select * from vbak into table  lt_customer where (lv_condition).
  lo_nd_customer = wd_context->get_child_node( name = wd_this->wdctx_customer ).
  lo_nd_customer->bind_table( lt_customer ).
this is working as expected. hope this works for you as well
BR, Saravanan