Error with AppleScript - integer?

Question

Hello, I have been making a simple script for my sister, but it does not work. It calls for an integer? I did not specify it in my program, but it calls it anyway...?
My Script:
activate
display dialog "Click Start to start importing your own kindle books!" with title "Kindle Book Uploader by Jeremy Zhang" buttons {"Cancel", "Start"} default button "Start"
property documentFolder : "documents"
tell application "Finder" to (get name of every disk whose ejectable is true)
try
          set kindleLocation to ¬
                    ((choose from list result with prompt "Select your Kindle from the list:") as text)
end try
try
          set bookFiles to ¬
                    ((choose file with prompt ¬
                              "Select kindle files to import:" of type {"public.html", "public.rtf", "com.microsoft.word.doc", "public.data.mobi", "public.plain-text", "com.adobe.pdf"} with multiple selections allowed) as text)
end try
display dialog "Please wait while the application copies the kindle books..." with title "Kindle Book Uploader by Jeremy Zhang"
tell application "Finder"
          if not (exists folder documentFolder of kindleLocation) then
  make new folder at kindleLocation with properties {name:documentFolder}
          end if
end tell
set fullKindlePath to POSIX path of (kindleLocation as alias) & "documents"
tell application "Finder"
move (bookFiles) to fullKindlePath
end tell
display dialog "Process has been done! Please eject your kindle and the files will be on the home screen of your Kindle." with title "Kindle Book Uploader by Jeremy Zhang"
And the result from running it:
tell current application
activate
end tell
tell application "AppleScript Editor"
display dialog "Click Start to start importing your own kindle books!" with title "Kindle Book Uploader by Jeremy Zhang" buttons {"Cancel", "Start"} default button "Start"
  --> {button returned:"Start"}
end tell
tell application "Finder"
get name of every disk whose ejectable = true
  --> {"JEREMY DISK"}
end tell
tell application "AppleScript Editor"
choose from list {"JEREMY DISK"} with prompt "Select your Kindle from the list:"
  --> {"JEREMY DISK"}
choose file with prompt "Select kindle files to import:" of type {"public.html", "public.rtf", "com.microsoft.word.doc", "public.data.mobi", "public.plain-text", "com.adobe.pdf"} with multiple selections allowed
  --> {alias "Macintosh HD:Users:JeremyZhang:Downloads:5 ETS SAT S.pdf"}
display dialog "Please wait while the application copies the kindle books..." with title "Kindle Book Uploader by Jeremy Zhang"
  --> {button returned:"OK"}
Result:
error "Can’t make \"documents\" into type integer." number -1700 from "documents" to integer
What am I doing wrong? Can you please correct me?
AppleScript Editor V: 2.5 (138)
AppleScript 2.2.3

Answer 1

Hello
Immediate cause of the error is that you're using kindleLocation, which is string, as a Finder object.
Replace this block:
tell application "Finder"
    if not (exists folder documentFolder of kindleLocation) then
        make new folder at kindleLocation with properties {name:documentFolder}
    end if
end tell
with this:
tell application "Finder"
    if not (exists folder documentFolder of disk kindleLocation) then
        make new folder at disk kindleLocation with properties {name:documentFolder}
    end if
end tell
Other than that,
- bookFiles must be list of aliases but you're coercing it to text,
- you should use "duplicate" instead of "move" to copy files,
- inadvertent try blocks will make it hard to debug the script,
- you need special code to handle user cancel in "choose from list" command.
Here's a cleanup version of your original script:
property documentFolder : "documents"
activate
display dialog "Click Start to start importing your own kindle books!" with title "Kindle Book Uploader by Jeremy Zhang" buttons {"Cancel", "Start"} default button "Start"
tell application "System Events" to set edisks to name of disks whose ejectable is true
set kindle to choose from list edisks with prompt "Select your Kindle from the list:"
if kindle = false then error number -128 -- user cancel
set kindle to kindle's item 1
set bookFiles to choose file with prompt ("Select kindle files to import:") ¬
    of type {"public.html", "public.rtf", "com.microsoft.word.doc", "public.data.mobi", "public.plain-text", "com.adobe.pdf"} ¬
    with multiple selections allowed
display dialog "Please wait while the application copies the kindle books..." with title "Kindle Book Uploader by Jeremy Zhang"
tell application "Finder"
    if not (exists folder documentFolder of disk kindle) then
        make new folder at disk kindle with properties {name:documentFolder}
    end if
    duplicate bookFiles to (kindle & ":" & documentFolder) as alias --with replacing
end tell
display dialog "Process has been done! Please eject your kindle and the files will be on the home screen of your Kindle." with title "Kindle Book Uploader by Jeremy Zhang"
Cheers,
H