Event for dropdown selection

Question

Hi.
I am working on CRM 2007 icwebclient. My requirement is for BP creation either individual or organisation depending on ROLE select mandatory fields are changed.
If role 'Prospect' is selected then few fields are mandatory or if 'sold-to-party' is selected more fields are madatory..
Now which event is working behind this dropdown selection. where i have to write my code. How to set fields 'mandatory' at design time. soon reply would be appreciate.

Answer 1

Hello,
as this really seems to be a big Issue for people. Thought as developers you might explore my hints on your own.
For switching the configuration:
Implement the P-Getter for the attribute on the context node with the following code:
CASE iv_property.
    WHEN if_bsp_wd_model_setter_getter=>fp_server_event.
      rv_value = 'my_event'.
  endcase
This will trigger a roundtrip. We do not need to handle the event.
In your view controller implementation class redefine the method DO_CONFIG_DETERMINATION:
METHOD do_config_determination.
* Switch configuration that is used based on field value.
  DATA:
    lv_value         TYPE              char2,
    lv_object_type      TYPE              bsp_dlc_object_type       VALUE '<DEFAULT>',
    lv_object_subtype   TYPE              BSP_DLC_OBJECT_SUB_TYPE   value '<DEFAULT>',
    lr_node        TYPE REF TO       if_bol_bo_property_access.
  CALL METHOD super->do_config_determination
    EXPORTING
      iv_first_time = abap_false.
  lr_node = typed_context->some_node->collection_wrapper->get_current( ).
  CHECK lr_node IS BOUND.
  lr_node->get_property_as_value(
    EXPORTING
      iv_attr_name = 'SOME_ATTRIBUTE'
    IMPORTING
      ev_result    = lv_value ).
  lv_object_type = 'MY_UI_OBJECT_TYPE'.
  CASE lv_value .
    WHEN 'SOME_VALUE1'.
      lv_object_subtype = 'JIMBOB'.
    WHEN 'SOME_VALUE2'.
      lv_object_subtype = 'BUBBA'.
  ENDCASE.
  me->set_config_keys( iv_object_type          = lv_object_type
                       iv_object_sub_type      = lv_object_subtype
                       iv_propagate_2_children = abap_true ).
ENDMETHOD.
Just paste the above coding into the method.
What it does:
1. Get the value you want to check from one of the context nodes.
2. Switch the UI Object type (Yes you have to define it in customizing)
3. Switch the UI Sub Object type on base of the field value. (Yes you have to define your own sub object type, this is done via a class that is assigned to your UI Object type in customizing)
For the other solution: As mentioned I have not tried it myself.
The variable on the view controller I am talking about is CONFIGURATION_DESCR of interface IF_BSP_DLC_CONFIGURATION. It has got a method GET_CONFIG_DATA that will give you the XML stream and a method SET_CONFIG_DATA. Putting the changed XML back.
If you had done a were used list for at least one of these methods you would have seen how SAP uses them.
One example: CL_BSP_WD_OVW_VIEWSET->DO_INIT_CONFIG() however this will not help you on your problem.
I know there is a method that will decode the XML stream in the single fields with their properties and there is also a counter part to it. I am afraid that many people will use it to bypass the configurations. This will make it very hard to debug the coding. Thus I will not name the class/method here!
For the sake of maintainability please stick to the first method.
I have seen people getting the XML and then hardcoding another part into it. Then someone changed the config and an error occurs. You try to find out why, but the original developer is no longer there and has not documented anything...
cheers Carsten